[gentoo-commits] repo/gentoo:master commit in: kde-misc/kio-gdrive/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     56a993c68da6be96c8556ecdb9aaea5570fd730b
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Aug 20 15:34:48 2024 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Aug 21 21:14:38 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=56a993c6

kde-misc/kio-gdrive: SLOT 5 shall RDEPEND on *-common too

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-misc/kio-gdrive/kio-gdrive-23.08.5-r2.ebuild | 69 ++++++++++++++++++++++++
 1 file changed, 69 insertions(+)

diff --git a/kde-misc/kio-gdrive/kio-gdrive-23.08.5-r2.ebuild b/kde-misc/kio-gdrive/kio-gdrive-23.08.5-r2.ebuild
new file mode 100644
index 000000000000..c91c6d257c47
--- /dev/null
+++ b/kde-misc/kio-gdrive/kio-gdrive-23.08.5-r2.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoff"
+ECM_TEST="optional"
+KDE_ORG_CATEGORY="network"
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm gear.kde.org
+
+DESCRIPTION="KIO worker for Google Drive service"
+HOMEPAGE="https://apps.kde.org/kio_gdrive/"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64"
+IUSE="kf6compat +share"
+
+COMMON_DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	kde-apps/kaccounts-integration:6[qt5]
+	kde-apps/libkgapi:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	share? ( >=kde-frameworks/purpose-${KFMIN}:5 )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtnetwork-${QTMIN}:5
+"
+RDEPEND="${COMMON_DEPEND}
+	kde-apps/kaccounts-providers:*
+	${CATEGORY}/${PN}-common
+"
+BDEPEND="dev-util/intltool"
+
+DOCS=( README.md )
+
+ECM_REMOVE_FROM_INSTALL=(
+	/usr/share/accounts/services/kde/google-drive.service
+	/usr/share/metainfo/org.kde.kio_gdrive.metainfo.xml
+	/usr/share/remoteview/gdrive-network.desktop
+)
+
+PATCHES=( "${FILESDIR}/${P}-kaccounts-integration-24.02.patch" )
+
+src_prepare() {
+	ecm_src_prepare
+	ecm_punt_po_install
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package share KF5Purpose)
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	if use kf6compat && use share; then
+		rm -r "${D}"/usr/share/purpose/purpose_gdrive_config.qml || die
+	fi
+}