[gentoo-commits] repo/gentoo:master commit in: dev-libs/castxml/

["Thomas Beierlein" <tomjbe@gentoo.org>]

commit:     2fc367cc0aa13954de9c27f33e5b4ce46bad6d06
Author:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
AuthorDate: Mon Aug 19 14:15:51 2024 +0000
Commit:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
CommitDate: Mon Aug 19 14:18:00 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2fc367cc

dev-libs/castxml: add 0.6.8

Signed-off-by: Thomas Beierlein <tomjbe <AT> gentoo.org>

 dev-libs/castxml/Manifest             |  1 +
 dev-libs/castxml/castxml-0.6.8.ebuild | 62 +++++++++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/dev-libs/castxml/Manifest b/dev-libs/castxml/Manifest
index 2951f2f2ace7..4efa452541be 100644
--- a/dev-libs/castxml/Manifest
+++ b/dev-libs/castxml/Manifest
@@ -1 +1,2 @@
 DIST CastXML-0.6.7.tar.gz 122608 BLAKE2B 04d10c34131fac97382fe33b1cfd8e65d62ce1339cb8eb253d867500f777346f352dfb9ff061c8e18be961ea9b7aeb86aef1d9c35d8f7e78687124e560bef435 SHA512 31acd05e15e44f64a92c47bbef13115d26e17488a111e5b2bb32bf6191c4555e8f7e380489ab9d6e52060285e25088f41253ba46f4eb95b6ec11e5c63412442f
+DIST CastXML-0.6.8.tar.gz 122609 BLAKE2B 3266535a2f08e4aa3c344f2d26cb0b98ba5d3736036ba95face5a603bbc9547a53647892e1f11cf748d954c556bec2099a734a9b9e566254186e9765c0410413 SHA512 7645286ef7fe89ebd1d582a289f9446a96f9aa6db89539314cc2a77bd005ca203d0346f5b4f7d14b83baefc41e0a2a8e55585b429985777cff6c3c0ffc1ef6ce

diff --git a/dev-libs/castxml/castxml-0.6.8.ebuild b/dev-libs/castxml/castxml-0.6.8.ebuild
new file mode 100644
index 000000000000..894410252a94
--- /dev/null
+++ b/dev-libs/castxml/castxml-0.6.8.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LLVM_COMPAT=( {17..19} )
+
+inherit cmake llvm-r1
+
+MY_P=CastXML-${PV}
+DESCRIPTION="C-family abstract syntax tree XML output tool"
+HOMEPAGE="https://github.com/CastXML/CastXML"
+SRC_URI="
+	https://github.com/CastXML/CastXML/archive/v${PV}.tar.gz
+		-> ${MY_P}.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~riscv ~x86"
+IUSE="+man test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	$(llvm_gen_dep '
+		sys-devel/clang:${LLVM_SLOT}=
+	')
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	man? ( dev-python/sphinx )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCastXML_INSTALL_DOC_DIR="share/doc/${PF}"
+		-DCastXML_INSTALL_MAN_DIR="share/man"
+		-DSPHINX_MAN="$(usex man)"
+		-DSPHINX_HTML=OFF
+		-DBUILD_TESTING="$(usex test)"
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	local CMAKE_SKIP_TESTS=(
+		# Regex doesn't match the full build path
+		cmd.input-missing
+		cmd.rsp-missing
+
+		# Gets confused by extra #defines we set for hardening etc (bug #891813)
+		cmd.cc-gnu-src-cxx-E
+		cmd.cc-gnu-src-cxx-cmd
+		cmd.cc-gnu-c-src-c-E
+		cmd.cc-gnu-c-src-c-cmd
+	)
+
+	cmake_src_test
+}