[gentoo-commits] proj/kde:master commit in: media-gfx/kio-mobi-thumbnailer/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     8afd677b3adc5a303cb839fc8ad26a954c852d20
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu Aug 15 07:54:31 2024 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu Aug 15 08:10:28 2024 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=8afd677b

media-gfx/kio-mobi-thumbnailer: 24.07.90 version bump

Inherit KEYWORDS from kde-apps/thumbnailers.

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../kio-mobi-thumbnailer-24.07.90.ebuild           | 42 ++++++++++++++++++++++
 1 file changed, 42 insertions(+)

diff --git a/media-gfx/kio-mobi-thumbnailer/kio-mobi-thumbnailer-24.07.90.ebuild b/media-gfx/kio-mobi-thumbnailer/kio-mobi-thumbnailer-24.07.90.ebuild
new file mode 100644
index 0000000000..5333f1b823
--- /dev/null
+++ b/media-gfx/kio-mobi-thumbnailer/kio-mobi-thumbnailer-24.07.90.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_NAME="kdegraphics-thumbnailers"
+PVCUT=$(ver_cut 1-3)
+KFMIN=6.5.0
+QTMIN=6.7.2
+inherit ecm gear.kde.org
+
+DESCRIPTION="KIO thumbnail generator for Mobipocket files"
+HOMEPAGE="https://apps.kde.org/kdegraphics_thumbnailers/"
+
+LICENSE="GPL-2+"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+
+DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[gui]
+	>=kde-apps/kdegraphics-mobipocket-${PVCUT}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+"
+RDEPEND="${DEPEND}
+	!<kde-apps/thumbnailers-24.05.2-r1:6
+"
+
+src_prepare() {
+	ecm_src_prepare
+	ecm_punt_kf_module Archive
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_ps=OFF
+		-DBUILD_blend=OFF
+		-DCMAKE_DISABLE_FIND_PACKAGE_KExiv2Qt6=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_KDcrawQt6=ON
+	)
+
+	ecm_src_configure
+}