[gentoo-commits] repo/gentoo:master commit in: dev-python/uvicorn/

["Michał Górny" <mgorny@gentoo.org>]

commit:     c7bacd1363625df0bc7a23b85f8d49079c48b5ce
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Aug 14 05:39:03 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Aug 14 06:05:23 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c7bacd13

dev-python/uvicorn: Bump to 0.30.6

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/uvicorn/Manifest              |  1 +
 dev-python/uvicorn/uvicorn-0.30.6.ebuild | 75 ++++++++++++++++++++++++++++++++
 2 files changed, 76 insertions(+)

diff --git a/dev-python/uvicorn/Manifest b/dev-python/uvicorn/Manifest
index f546ec9d45b2..79617b86cdd5 100644
--- a/dev-python/uvicorn/Manifest
+++ b/dev-python/uvicorn/Manifest
@@ -1,2 +1,3 @@
 DIST uvicorn-0.30.3.gh.tar.gz 723748 BLAKE2B 8191491ebbccf8586e668bc6c14ce0a526d958ee1bf618cbf714bcb0932c36e14bfa4365a3ce88129180dcb0a2ac62b65fd977262f936b31a84267e3d41a971e SHA512 de6299c4b93bb14ea5ef466d2ebb91e24c2b9ae3e47158e924ae8c1f1e58a3fffd39e3e001e647afa47512f9481f5a3e2cce613427600200bcf27c4143c4e608
 DIST uvicorn-0.30.5.gh.tar.gz 723960 BLAKE2B 462cdbe47f035a6b100908e5fa533a9afa7be3232ce79fda372686de54a14ca13771245a98c53b7ad729ba3119cd83b9d4acd5ab4069064f6c9fee3542f7b0be SHA512 9752b415159e152264d0d9a9a93cd82ec3b6ab08fe115698e54ecf5e2534c7c2368e05dfd21486c8711808482a85c563ecf1d5027c09587872aced4f7023a3dc
+DIST uvicorn-0.30.6.gh.tar.gz 724296 BLAKE2B c95ee6764947e51958da2e62627d20bfbef48f065832f6214c7c05b9daf344b76eb6b0ec4ccbc3ebc2502b9f2cc77157dcf90e824cec0a8adc62601ceb4abf0c SHA512 d4c4410648509b14e18c3c86a33df4152e951703d287153a26ad35f4dce35eb594b940d3773cb444119b9bfa72ae3885c54d84b1a09c0c6069b80941f453c2e8

diff --git a/dev-python/uvicorn/uvicorn-0.30.6.ebuild b/dev-python/uvicorn/uvicorn-0.30.6.ebuild
new file mode 100644
index 000000000000..9511a7d54223
--- /dev/null
+++ b/dev-python/uvicorn/uvicorn-0.30.6.ebuild
@@ -0,0 +1,75 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Lightning-fast ASGI server implementation"
+HOMEPAGE="
+	https://www.uvicorn.org/
+	https://github.com/encode/uvicorn/
+	https://pypi.org/project/uvicorn/
+"
+# as of 0.28.0, no tests in sdist
+SRC_URI="
+	https://github.com/encode/uvicorn/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="test-rust"
+
+RDEPEND="
+	>=dev-python/asgiref-3.4.0[${PYTHON_USEDEP}]
+	>=dev-python/click-7.0[${PYTHON_USEDEP}]
+	>=dev-python/h11-0.8[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/typing-extensions-4.0[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	test? (
+		dev-python/a2wsgi[${PYTHON_USEDEP}]
+		dev-python/httpx[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/python-dotenv[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		>=dev-python/websockets-10.4[${PYTHON_USEDEP}]
+		dev-python/wsproto[${PYTHON_USEDEP}]
+		test-rust? (
+			dev-python/cryptography[${PYTHON_USEDEP}]
+			dev-python/trustme[${PYTHON_USEDEP}]
+			dev-python/watchfiles[${PYTHON_USEDEP}]
+		)
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# too long path for unix socket
+		tests/test_config.py::test_bind_unix_socket_works_with_reload_or_workers
+	)
+	case ${EPYTHON} in
+		pypy3)
+			# TODO
+			EPYTEST_DESELECT+=(
+				tests/middleware/test_logging.py::test_running_log_using_fd
+			)
+			;;
+	esac
+
+	epytest
+}
+
+pkg_postinst() {
+	optfeature "auto reload on file changes" dev-python/watchfiles
+}