[gentoo-commits] repo/gentoo:master commit in: app-misc/fastfetch/

["Viorel Munteanu" <ceamac@gentoo.org>]

commit:     f28f4b54e16ce907bbdb6d95664c6535044e3af8
Author:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
AuthorDate: Wed Aug 14 04:42:49 2024 +0000
Commit:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
CommitDate: Wed Aug 14 04:42:49 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f28f4b54

app-misc/fastfetch: add 2.21.2

Signed-off-by: Viorel Munteanu <ceamac <AT> gentoo.org>

 app-misc/fastfetch/Manifest                |   1 +
 app-misc/fastfetch/fastfetch-2.21.2.ebuild | 110 +++++++++++++++++++++++++++++
 2 files changed, 111 insertions(+)

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index 58589ea442e6..8a941666d328 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -4,3 +4,4 @@ DIST fastfetch-2.19.1.tar.gz 1075300 BLAKE2B 66cc78bdda56c59abf5adf626159493c0e3
 DIST fastfetch-2.20.0.tar.gz 1076860 BLAKE2B 61c50a4c96962063f18ae895d2f7cbe505c9276fcba8fb5a3d7e9cc6b6854709cdb955681a868b23421f172f5cecfa51fb526f17d6800e072d96698efe7758bb SHA512 96b02688d8817ef84bb926ffa3c77ee95c8d402a6f1e5daeb8170484e6092f953f05a5ab463cdce544adb052a1e89b4ee530cc9f09e54223d5f666099e0ad6dc
 DIST fastfetch-2.21.0.tar.gz 1086262 BLAKE2B 16412d690ea8843d58135674f3c1f0a6d7db95d400e3552769fc976a94c774a98765b0a0e36c4fb8c61083d779de6f56d09c423d35b8c00ac6287ab50aaa64c7 SHA512 e1c3cb7ddd879a577ce41adf43631f339fae65d313f1eb558972011006b639045d957cf700fcf07566743943c1374b8efb90f740ec578e47baee2cd44afab121
 DIST fastfetch-2.21.1.tar.gz 1089392 BLAKE2B 26dd4a7d97c47af7ba13c1cd2b9a9a97df7132d0da19986005e598b782d52fe19759f3af533b4ed7778bb655013fb02a6409f100980311d6decb2a6cb7311e84 SHA512 645830b3834c6308caf4b37b9b801a9b5ff963c14c5ca73decd4f8d1a3e1e3a678e86f81fe93f7f61b107e516a71c792a580f243b20763db1269769b89080b93
+DIST fastfetch-2.21.2.tar.gz 1093402 BLAKE2B ca9491203bd99f61718bdbddd495b372595b9923a151d10bb343a7358d41df6fc7f277fee87693acc5356e881195f365aeeae96d21e2008f66f0a2411cc3ed8e SHA512 7c238bf627f1de069cd1eb7f42bb70cd8b4ad7a09b8ab2e9a6d03c03cbece7042da160e39b185b58b8dfa2ca924b27d31d5c40584e5f5dea8df61e496fbd8b23

diff --git a/app-misc/fastfetch/fastfetch-2.21.2.ebuild b/app-misc/fastfetch/fastfetch-2.21.2.ebuild
new file mode 100644
index 000000000000..1172d42eb56e
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-2.21.2.ebuild
@@ -0,0 +1,110 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Fast neofetch-like system information tool"
+HOMEPAGE="https://github.com/fastfetch-cli/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/fastfetch-cli/fastfetch.git"
+	[[ ${PV} == *0.1.9999 ]] && EGIT_BRANCH=master
+	[[ ${PV} == *0.2.9999 ]] && EGIT_BRANCH=dev
+	[[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
+else
+	SRC_URI="https://github.com/fastfetch-cli/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="X chafa dbus ddcutil drm elf gnome imagemagick opencl opengl osmesa pulseaudio sqlite test vulkan wayland xcb xfce xrandr"
+RESTRICT="!test? ( test )"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+# make sure to crank yyjson minimum version to match bundled version
+RDEPEND="
+	>=dev-libs/yyjson-0.10.0
+	sys-libs/zlib
+	X? ( x11-libs/libX11 )
+	chafa? ( media-gfx/chafa )
+	dbus? ( sys-apps/dbus )
+	ddcutil? ( app-misc/ddcutil:= )
+	drm? ( x11-libs/libdrm )
+	elf? ( virtual/libelf:= )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	opencl? ( virtual/opencl )
+	opengl? ( media-libs/libglvnd[X] )
+	osmesa? ( media-libs/mesa[osmesa] )
+	pulseaudio? ( media-libs/libpulse )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? (
+		media-libs/vulkan-loader
+		sys-apps/pciutils
+	)
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="
+	${RDEPEND}
+	vulkan? ( dev-util/vulkan-headers )
+"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	xrandr? ( X )
+	chafa? ( imagemagick )
+"
+
+src_configure() {
+	local fastfetch_enable_imagemagick7=no
+	local fastfetch_enable_imagemagick6=no
+	if use imagemagick; then
+		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	fi
+
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_ZLIB=yes
+		-DENABLE_SYSTEM_YYJSON=yes
+		-DIS_MUSL=$(usex elibc_musl)
+		-DINSTALL_LICENSE=no
+
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_DDCUTIL=$(usex ddcutil)
+		-DENABLE_DRM=$(usex drm)
+		-DENABLE_ELF=$(usex elf)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_GLX=$(usex opengl)
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_OSMESA=$(usex osmesa)
+		-DENABLE_PULSE=$(usex pulseaudio)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_XCB=$(usex xcb)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DBUILD_TESTS=$(usex test)
+	)
+
+	append-cppflags -DNDEBUG
+
+	cmake_src_configure
+}