[gentoo-commits] repo/gentoo:master commit in: dev-python/spyder/

["Andrew Ammerlaan" <andrewammerlaan@gentoo.org>]

commit:     b6633b244c24391a30869340ddd8538f73a634f5
Author:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
AuthorDate: Sat Aug 10 08:41:32 2024 +0000
Commit:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
CommitDate: Sat Aug 10 08:45:33 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b6633b24

dev-python/spyder: drop 6.0.0_beta3

Signed-off-by: Andrew Ammerlaan <andrewammerlaan <AT> gentoo.org>

 dev-python/spyder/Manifest                  |   1 -
 dev-python/spyder/spyder-6.0.0_beta3.ebuild | 198 ----------------------------
 2 files changed, 199 deletions(-)

diff --git a/dev-python/spyder/Manifest b/dev-python/spyder/Manifest
index a802c5548796..761695c421c7 100644
--- a/dev-python/spyder/Manifest
+++ b/dev-python/spyder/Manifest
@@ -1,4 +1,3 @@
 DIST spyder-5.5.5.gh.tar.gz 16258487 BLAKE2B 3fa3ea611fc3267918e4314027c0825905f256a7fe070534c7608a4a42938c3934f34f4dc06fe0cfc0ac32e03fbdc294974672b010aaf9bc32512b817af62e6b SHA512 5f5d25822f20f8ae8767402b037cca78b760768b9bc53ef74ed95839aa59e1c24206457fd4c71003bb9ebffe8daf8ad3bda8dd40e71cc15d3d3ee2030b284b42
-DIST spyder-6.0.0_beta3.gh.tar.gz 15656243 BLAKE2B 7b958065d74aa58e8f34a530ae7a409d7680e55bf70ad0a4ee0a694bdc0239d32b2171c6cbeb97afc36d362860498cedf789ba5790ffdb4665c7414abc212c61 SHA512 d3ba805fd4a3fd03adde986e8c97e8e3fb3cfbcdba16487987f4b18bf7559b44a8f07106e138ab30aaa4e69db3c17d4bd80a1866baf2897a0b839c86d17a0073
 DIST spyder-6.0.0_rc1.gh.tar.gz 15673894 BLAKE2B a9cd90bb12ec4d11b6a92185b2ff115f9d94e015a354022452d3592c53170fa59826f95d33709041c947ce780fa5368cb45cda3e8e04900f2bcd235706456c8f SHA512 2870f12bd830d1f4e6ff5c8af3cfce670c7134ea975b7e09d6f1e69ec0ca32357150fc2da69fcc7ed29bd7bfc504b211bc9faaea0f7fdcbb161e528baf7c70f9
 DIST spyder-docs-32efdaebc11dab0b8e0767717342b7d306dc06ea.gh.tar.gz 94897009 BLAKE2B 30e0b42e34bddb60d8fc986183a363b71455067bc7f4411cb75a00c5758e87501ee07ad0b484caed2aa3cf91153be814c7faf935be8665b6984bce38ebcd0be2 SHA512 9f9aa56ab27aed8d27c3d653119d5c5454b4317a78a7ff27715d91cac9dec79143db85d4f1c87b10fa821eb33abc043912df308fa6c84ade59539bd633eefbd2

diff --git a/dev-python/spyder/spyder-6.0.0_beta3.ebuild b/dev-python/spyder/spyder-6.0.0_beta3.ebuild
deleted file mode 100644
index c67ff4355549..000000000000
--- a/dev-python/spyder/spyder-6.0.0_beta3.ebuild
+++ /dev/null
@@ -1,198 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{10..12} )
-DISTUTILS_USE_PEP517=setuptools
-
-inherit distutils-r1 optfeature virtualx xdg
-
-# Commit of documentation to fetch
-DOCS_PV="32efdaebc11dab0b8e0767717342b7d306dc06ea"
-
-DESCRIPTION="The Scientific Python Development Environment"
-HOMEPAGE="
-	https://www.spyder-ide.org/
-	https://github.com/spyder-ide/spyder/
-	https://pypi.org/project/spyder/
-"
-SRC_URI="
-	https://github.com/spyder-ide/${PN}/archive/v${PV//_beta/b}.tar.gz -> ${P}.gh.tar.gz
-	https://github.com/spyder-ide/${PN}-docs/archive/${DOCS_PV}.tar.gz -> ${PN}-docs-${DOCS_PV}.gh.tar.gz
-"
-S="${WORKDIR}/${PN}-${PV//_beta/b}"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS=""
-
-RDEPEND="
-	>=dev-python/aiohttp-3.9.3[${PYTHON_USEDEP}]
-	>=dev-python/asyncssh-2.0.0[${PYTHON_USEDEP}]
-	<dev-python/asyncssh-3.0.0[${PYTHON_USEDEP}]
-	>=dev-python/atomicwrites-1.2.0[${PYTHON_USEDEP}]
-	>=dev-python/chardet-2.0.0[${PYTHON_USEDEP}]
-	>=dev-util/cookiecutter-1.6.0[${PYTHON_USEDEP}]
-	>=dev-python/diff-match-patch-20181111[${PYTHON_USEDEP}]
-	>=dev-python/intervaltree-3.0.2[${PYTHON_USEDEP}]
-	>=dev-python/jellyfish-0.7[${PYTHON_USEDEP}]
-	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
-	>=dev-python/keyring-17.0.0[${PYTHON_USEDEP}]
-	>=dev-python/nbconvert-4.0[${PYTHON_USEDEP}]
-	>=dev-python/numpydoc-0.6.0[${PYTHON_USEDEP}]
-	>=dev-python/pexpect-4.4.0[${PYTHON_USEDEP}]
-	>=dev-python/pickleshare-0.4[${PYTHON_USEDEP}]
-	>=dev-python/psutil-5.3[${PYTHON_USEDEP}]
-	>=dev-python/PyGithub-2.3.0[${PYTHON_USEDEP}]
-	>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
-	>=dev-python/pylint-venv-3.0.2[${PYTHON_USEDEP}]
-	>=dev-python/python-lsp-black-2.0.0[${PYTHON_USEDEP}]
-	<dev-python/python-lsp-black-3.0.0[${PYTHON_USEDEP}]
-	>=dev-python/pyls-spyder-0.4.0[${PYTHON_USEDEP}]
-	>=dev-python/pyuca-1.2[${PYTHON_USEDEP}]
-	>=dev-python/pyxdg-0.26[${PYTHON_USEDEP}]
-	>=dev-python/pyzmq-24.0.0[${PYTHON_USEDEP}]
-	>=dev-python/qdarkstyle-3.2.0[${PYTHON_USEDEP}]
-	<dev-python/qdarkstyle-3.3.0[${PYTHON_USEDEP}]
-	>=dev-python/qstylizer-0.2.2[${PYTHON_USEDEP}]
-	>=dev-python/qtawesome-1.3.1[${PYTHON_USEDEP}]
-	<dev-python/qtawesome-1.4.0[${PYTHON_USEDEP}]
-	>=dev-python/qtconsole-5.5.1[${PYTHON_USEDEP}]
-	<dev-python/qtconsole-5.6.0[${PYTHON_USEDEP}]
-	>=dev-python/QtPy-2.4.0[${PYTHON_USEDEP},svg,webengine]
-	>=dev-python/rtree-0.9.7[${PYTHON_USEDEP}]
-	>=dev-python/sphinx-0.6.6[${PYTHON_USEDEP}]
-	>=dev-python/spyder-kernels-3.0.0_beta7[${PYTHON_USEDEP}]
-	<dev-python/spyder-kernels-3.0.0_beta8[${PYTHON_USEDEP}]
-	>=dev-python/superqt-0.6.2[${PYTHON_USEDEP}]
-	<dev-python/superqt-1.0.0[${PYTHON_USEDEP}]
-	>=dev-python/textdistance-4.2.0[${PYTHON_USEDEP}]
-	>=dev-python/three-merge-0.1.1[${PYTHON_USEDEP}]
-	>=dev-python/watchdog-0.10.3[${PYTHON_USEDEP}]
-	>=dev-python/yarl-1.9.4[${PYTHON_USEDEP}]
-"
-
-BDEPEND="
-	test? (
-		dev-python/cython[${PYTHON_USEDEP}]
-		dev-python/flaky[${PYTHON_USEDEP}]
-		dev-python/matplotlib[tk,${PYTHON_USEDEP}]
-		dev-python/pandas[${PYTHON_USEDEP}]
-		dev-python/pillow[${PYTHON_USEDEP}]
-		dev-python/pytest-lazy-fixture[${PYTHON_USEDEP}]
-		dev-python/pytest-mock[${PYTHON_USEDEP}]
-		dev-python/pytest-order[${PYTHON_USEDEP}]
-		dev-python/pytest-qt[${PYTHON_USEDEP}]
-		dev-python/pytest-timeout[${PYTHON_USEDEP}]
-		dev-python/pyyaml[${PYTHON_USEDEP}]
-		dev-python/QtPy[${PYTHON_USEDEP}]
-		dev-python/scipy[${PYTHON_USEDEP}]
-		dev-python/sympy[${PYTHON_USEDEP}]
-	)"
-
-# Based on the courtesy of Arfrever
-# This patch removes a call to update-desktop-database during build
-# This fails because access is denied to this command during build
-PATCHES=(
-	"${FILESDIR}/${PN}-5.0.0-build.patch"
-	"${FILESDIR}/${PN}-5.2.0-doc-theme-renamed.patch"
-)
-
-DOCS=(
-	"AUTHORS.txt"
-	"Announcements.md"
-	"CHANGELOG.md"
-	"CODE_OF_CONDUCT.md"
-	"CONTRIBUTING.md"
-	"NOTICE.txt"
-	"README.md"
-	"RELEASE.md"
-)
-
-distutils_enable_tests pytest
-distutils_enable_sphinx docs/doc \
-	dev-python/sphinx-panels \
-	dev-python/pydata-sphinx-theme \
-	dev-python/sphinx-multiversion
-
-python_prepare_all() {
-	# move docs into workdir
-	mv ../spyder-docs-${DOCS_PV}* docs || die
-
-	# these dependencies are packaged separately:
-	#    dev-python/spyder-kernels,
-	#    dev-python/python-lsp-server,
-	#    dev-python/qdarkstyle
-	rm -r external-deps/* || die
-	# runs against things packaged in external-deps dir
-	rm conftest.py || die
-
-	# Do not depend on pyqt5<5.16, this dependency is carried by QtPy[pyqt5]
-	# Do not depend on pyqtwebengine<5.16, this dependency is carried by QtPy[webengine]
-	# Do not depend on parso and jedi, this is dependency is carried in python-lsp-server
-	# Do not depend on python-lsp-server, this dependency is carried in pyls-spyder
-	# Do not depend on ipython, this dependency is carried in spyder-kernels
-	# The explicit version requirements only make things more complicated, if e.g.
-	# pyls-spyder gains compatibility with a newer version of python-lsp-server
-	# in a new release it will take time for this information to propagate into
-	# the next spyder release. So just remove the dependency and let the other
-	# ebuilds handle the version requirements to speed things up and prevent
-	# issues such as Bug 803269.
-	sed -i \
-		-e "/'pyqt5[ 0-9<=>.,]*',/d" \
-		-e "/'pyqtwebengine[ 0-9<=>.,]*',/d" \
-		-e "/'python-lsp-server\[all\][ 0-9<=>.,]*',/d" \
-		-e "/'parso[ 0-9<=>.,]*',/d" \
-		-e "/'jedi[ 0-9<=>.,]*',/d" \
-		-e "/'pylint[ 0-9<=>.,]*',/d" \
-			setup.py || die
-		# -e "/'ipython[ 0-9<=>.,]*',/d" \
-	sed -i \
-		-e "/^PYLS_REQVER/c\PYLS_REQVER = '>=0.0.1'" \
-		-e "/^PYLSP_REQVER/c\PYLSP_REQVER = '>=0.0.1'" \
-		-e "/^PARSO_REQVER/c\PARSO_REQVER = '>=0.0.1'" \
-		-e "/^JEDI_REQVER/c\JEDI_REQVER = '>=0.0.1'" \
-		-e "/^PYLINT_REQVER/c\PYLINT_REQVER = '>=0.0.1'" \
-			spyder/dependencies.py || die
-		# -e "/^IPYTHON_REQVER/c\IPYTHON_REQVER = '>=0.0.1'" \
-
-	# do not check deps, fails because we removed dependencies above
-	sed -i -e 's:test_dependencies_for_spyder_setup_install_requires_in_sync:_&:' \
-		spyder/tests/test_dependencies_in_sync.py || die
-
-	# skip online test
-	rm spyder/widgets/github/tests/test_github_backend.py || die
-
-	distutils-r1_python_prepare_all
-}
-
-# Calling pytest directly somehow passes the pytest arguments to spyder
-# causing an invalid argument error
-python_test() {
-	virtx "${EPYTHON}" runtests.py
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	optfeature "2D/3D plotting in the Python and IPython consoles" dev-python/matplotlib
-	optfeature "View and edit DataFrames and Series in the Variable Explorer" dev-python/pandas
-	optfeature "View and edit two or three dimensional arrays in the Variable Explorer" dev-python/numpy
-	optfeature "Symbolic mathematics in the IPython console" dev-python/sympy
-	optfeature "Import Matlab workspace files in the Variable Explorer" dev-python/scipy
-	optfeature "Run Cython files in the IPython console" dev-python/cython
-	optfeature "The hdf5/h5py plugin" dev-python/h5py
-	optfeature "The line profiler plugin" dev-python/spyder-line-profiler
-	optfeature "Vim key bindings" dev-python/spyder-vim
-	optfeature "Unittest support" dev-python/spyder-unittest
-	optfeature "System terminal inside spyder" dev-python/spyder-terminal
-	optfeature "Jupyter notebook support" dev-python/spyder-notebook
-	# spyder-memory-profiler is not compatible with spyder-5.2+ yet
-	# optfeature "The memory profiler plugin" dev-python/spyder-memory-profiler
-	# spyder-reports not yet updated to >=spyder-4.0.0
-	# optfeature "Markdown reports using Pweave" dev-python/spyder-reports
-	# Plugins with no release yet:
-	# optfeature "Manage virtual environments and packages" dev-python/spyder-env-manager
-	# optfeature "VCS (e.g. git) integration" dev-python/spyder-vcs
-}