[gentoo-commits] repo/gentoo:master commit in: gnome-extra/evolution-data-server/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     adb2ec815cb835ddc024d040d2a523fa62277975
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Tue Aug  6 09:27:13 2024 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Tue Aug  6 09:31:11 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=adb2ec81

gnome-extra/evolution-data-server: drop 3.52.1

Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 gnome-extra/evolution-data-server/Manifest         |   1 -
 .../evolution-data-server-3.52.1.ebuild            | 159 ---------------------
 2 files changed, 160 deletions(-)

diff --git a/gnome-extra/evolution-data-server/Manifest b/gnome-extra/evolution-data-server/Manifest
index 72f6217d137a..dc746d40d223 100644
--- a/gnome-extra/evolution-data-server/Manifest
+++ b/gnome-extra/evolution-data-server/Manifest
@@ -1,5 +1,4 @@
 DIST evolution-data-server-3.50.2.tar.xz 4964152 BLAKE2B 7279a5bcb0399fdcce723336a052dca13efa6f0af6ef7371b7cb8e76fbd7e1b0313e7f677cea530de62a93770c35887fd70bac551338f9a89860e2529b1f1519 SHA512 9e2a34e06a446ae142535072a3d6916e31b7be987b114c111fb0687fa32a3fe4085ba5a09ccd77fb395d107e5c673130dc770bae74a50fdb566c91cd9de85610
 DIST evolution-data-server-3.50.4.tar.xz 4964564 BLAKE2B 7e3cf51856a1b12fcbd7e0b6ab98b8616c6e6047afb7fc59f8366920177c30b4d18f58cdd11825e81054ef46d61d3addf9eb646310510ba44f60bc5a2c2abe50 SHA512 e83f4222615d518e536a622808896b1da7e425e90d9b3c3545c6b850f955bd6d4b4a6815904fcdcfa373b3c01a6ce61377e259bc740941fc3f641e60eddacaed
-DIST evolution-data-server-3.52.1.tar.xz 5048124 BLAKE2B 6dd6dc89c7efb7484c075cc51c5e2056ee62a50b810e479f39d04fe62f1a095e49783c20d23372efed954d7f9b78681b7af45389410f2cffb53af8ab2cd22bb3 SHA512 67f08fc3c8f7393fa66dc91f6fb33aa17644eb036d6c3552c3e7b30f128756b9e232cbf2a38eab43d0451699bb8799d9a869198bd9c293c0e2456b8e00339286
 DIST evolution-data-server-3.52.2.tar.xz 5051576 BLAKE2B f4c897fe533e5d8bf13f21e1964b4a300b55e2422b00a2e02e87a1e7a73e82012b7f7719f92a3a7d6e133de9270a776c4ce09ccf8d9cc55e27ee1cb298fa94d6 SHA512 31c0ae52bcf6a96b4d128e39c85a1f1f3cb29f1d7e2ffca3aa0dac95431830e38f2fb1dd3323e77e9e353d260f6681c7f8a55fff421336e152e0902f0085cd34
 DIST evolution-data-server-3.52.4.tar.xz 5055252 BLAKE2B e493f16700533e97440a13dead51bb4654fbbb0345718eeb91e1e052f9599ededacb6e6693fa9de3d68288a6472503ab3a01cab4ac27be8cfc2d693389021aa0 SHA512 2847a15f7cb5b41cce94565a06f7baa02d8dd40241d59029ccebeb21215500ca6f1ac978f1142bde9348917f0534e181e2f7011ed245b6e7a6b1afda9975cfef

diff --git a/gnome-extra/evolution-data-server/evolution-data-server-3.52.1.ebuild b/gnome-extra/evolution-data-server/evolution-data-server-3.52.1.ebuild
deleted file mode 100644
index 9782120ba5b7..000000000000
--- a/gnome-extra/evolution-data-server/evolution-data-server-3.52.1.ebuild
+++ /dev/null
@@ -1,159 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake db-use flag-o-matic gnome2 vala virtualx
-
-DESCRIPTION="Evolution groupware backend"
-HOMEPAGE="https://gitlab.gnome.org/GNOME/evolution/-/wikis/home https://gitlab.gnome.org/GNOME/evolution-data-server"
-
-# Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
-LICENSE="|| ( LGPL-2 LGPL-3 ) BSD Sleepycat"
-SLOT="0/64-11-21-4-3-27-2-27-4-0" # subslot = libcamel-1.2/libebackend-1.2/libebook-1.2/libebook-contacts-1.2/libecal-2.0/libedata-book-1.2/libedata-cal-2.0/libedataserver-1.2/libedataserverui-1.2/libedataserverui4-1.0 soname version
-
-IUSE="berkdb +gnome-online-accounts +gtk gtk-doc +introspection ldap kerberos oauth-gtk3 oauth-gtk4 vala +weather"
-REQUIRED_USE="
-	oauth-gtk3? ( gtk )
-	oauth-gtk4? ( gtk )
-	vala? ( introspection )
-"
-
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
-
-# berkdb needed only for migrating old addressbook data from <3.13 versions, bug #519512
-# glib-2.70 for build-time optional GPowerProfileMonitor
-RDEPEND="
-	>=app-crypt/libsecret-0.5[crypt]
-	>=dev-db/sqlite-3.7.17:3
-	>=dev-libs/glib-2.70:2
-	>=dev-libs/libical-3.0.8:=[glib,introspection?]
-	>=dev-libs/libxml2-2
-	>=dev-libs/nspr-4.4
-	>=dev-libs/nss-3.9
-	>=net-libs/libsoup-3.1.1:3.0
-	>=dev-libs/json-glib-1.0.4
-
-	dev-libs/icu:=
-	sys-libs/zlib:=
-	virtual/libiconv
-
-	berkdb? ( >=sys-libs/db-4:= )
-	gtk? (
-		>=x11-libs/gtk+-3.20:3
-		>=gui-libs/gtk-4.4:4
-		>=media-libs/libcanberra-0.25[gtk3]
-
-		oauth-gtk3? ( >=net-libs/webkit-gtk-2.34.0:4.1 )
-		oauth-gtk4? ( >=net-libs/webkit-gtk-2.39.90:6 )
-	)
-	gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.8:= )
-	introspection? ( >=dev-libs/gobject-introspection-0.9.12:= )
-	kerberos? ( virtual/krb5:= )
-	ldap? ( >=net-nds/openldap-2:= )
-	weather? ( >=dev-libs/libgweather-4.2.0:4= )
-"
-DEPEND="${RDEPEND}
-	vala? ( $(vala_depend)
-		>=net-libs/libsoup-3.1.1:3.0[vala]
-		dev-libs/libical[vala]
-	)
-"
-BDEPEND="
-	dev-util/gdbus-codegen
-	dev-util/glib-utils
-	dev-util/gperf
-	gtk-doc? (
-		>=dev-util/gtk-doc-1.14
-		dev-util/gi-docgen
-		app-text/docbook-xml-dtd:4.1.2
-	)
-	>=dev-util/intltool-0.35.5
-	>=sys-devel/gettext-0.18.3
-	virtual/pkgconfig
-"
-
-# Some tests fail due to missing locales.
-# Also, dbus tests are flaky, bugs #397975 #501834
-# It looks like a nightmare to disable those for now.
-RESTRICT="!test? ( test )"
-
-pkg_pretend() {
-	if has_version "gnome-extra/evolution-data-server[oauth(-)]" &&
-		! use oauth-gtk3 && ! use oauth-gtk4
-	then
-		ewarn "The previous installed version of gnome-extra/evolution-data-server"
-		ewarn "had USE=oauth enabled that is now split into USE=oauth-gtk3"
-		ewarn "and USE=oauth-gtk4.  Please consider enabling either (or both)"
-		ewarn "of these flags to preserve OAuth2 support."
-	fi
-}
-
-# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare call
-src_prepare() {
-	use vala && vala_setup
-	cmake_src_prepare
-	gnome2_src_prepare
-
-	eapply "${FILESDIR}"/3.36.5-gtk-doc-1.32-compat.patch
-
-	# Make CMakeLists versioned vala enabled
-	sed -e "s;\(find_program(VALAC\) valac);\1 ${VALAC});" \
-	  -e "s;\(find_program(VAPIGEN\) vapigen);\1 ${VAPIGEN});" \
-	  -i "${S}"/CMakeLists.txt || die
-}
-
-src_configure() {
-	# /usr/include/db.h is always db-1 on FreeBSD
-	# so include the right dir in CPPFLAGS
-	use berkdb && append-cppflags "-I$(db_includedir)"
-
-	# phonenumber does not exist in tree
-	local mycmakeargs=(
-		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
-#		-DENABLE_GI_DOCGEN=$(usex gtk-doc)
-		-DENABLE_GTK_DOC=$(usex gtk-doc)
-		-DWITH_PRIVATE_DOCS=$(usex gtk-doc)
-		-DENABLE_SCHEMAS_COMPILE=OFF
-		-DENABLE_INTROSPECTION=$(usex introspection)
-		-DWITH_KRB5=$(usex kerberos)
-		-DWITH_KRB5_INCLUDES=$(usex kerberos "${EPREFIX}"/usr "")
-		-DWITH_KRB5_LIBS=$(usex kerberos "${EPREFIX}"/usr/$(get_libdir) "")
-		-DWITH_OPENLDAP=$(usex ldap)
-		-DWITH_PHONENUMBER=OFF
-		-DENABLE_SMIME=ON
-		-DENABLE_GTK=$(usex gtk)
-		-DENABLE_GTK4=$(usex gtk)
-		-DENABLE_CANBERRA=$(usex gtk)
-		-DENABLE_OAUTH2_WEBKITGTK=$(usex oauth-gtk3)
-		-DENABLE_OAUTH2_WEBKITGTK4=$(usex oauth-gtk4)
-		-DENABLE_EXAMPLES=OFF
-		-DENABLE_GOA=$(usex gnome-online-accounts)
-		-DWITH_LIBDB=$(usex berkdb "${EPREFIX}"/usr OFF)
-		# ENABLE_BACKTRACES requires libdwarf ?
-		-DENABLE_IPV6=ON
-		-DENABLE_WEATHER=$(usex weather)
-		-DENABLE_LARGEFILE=ON
-		-DENABLE_VALA_BINDINGS=$(usex vala)
-		-DENABLE_TESTS=$(usex test)
-	)
-	cmake_src_configure
-}
-
-src_compile() {
-	cmake_src_compile
-}
-
-src_test() {
-	virtx cmake_src_test
-}
-
-src_install() {
-	cmake_src_install
-
-	if use ldap; then
-		insinto /etc/openldap/schema
-		doins "${FILESDIR}"/calentry.schema
-		dosym ../../../usr/share/${PN}/evolutionperson.schema /etc/openldap/schema/evolutionperson.schema
-	fi
-}