[gentoo-commits] repo/gentoo:master commit in: gnome-extra/nautilus-dropbox/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     2edbadb4bc47a0bf31ade3943a250af5cea31aa4
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Tue Jul 30 08:37:03 2024 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Tue Jul 30 08:48:04 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2edbadb4

gnome-extra/nautilus-dropbox: add 2024.04.17

Closes: https://bugs.gentoo.org/935312
Closes: https://bugs.gentoo.org/929604
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 gnome-extra/nautilus-dropbox/Manifest              |  1 +
 .../nautilus-dropbox-2024.04.17.ebuild             | 65 ++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/gnome-extra/nautilus-dropbox/Manifest b/gnome-extra/nautilus-dropbox/Manifest
index 5586bc135884..2fa91c0255f3 100644
--- a/gnome-extra/nautilus-dropbox/Manifest
+++ b/gnome-extra/nautilus-dropbox/Manifest
@@ -1 +1,2 @@
 DIST nautilus-dropbox-2020.03.04.tar.bz2 387351 BLAKE2B ff25716ef10759e014cffec8a7e9b1a40931686d6de3c69e9060c77cbf3aee65ffeed91ba809ba8cffc372f284180c74a8cb5b0ca4b342aa137d9e574a2a1abf SHA512 8f26165a48d1767b3bccb34f95f19357e8fd209f383270ac2d40f773df139d640c3fb33db28cf1fa7e2d7063a7a37b15ed7f4f22f85019e05885c097cea39a48
+DIST nautilus-dropbox-2024.04.17.tar.bz2 394725 BLAKE2B e617f02fcb6c11fd6937a99c0e2faaebd564d533e6ed44fc0492504fb41612fb297b3c98c84b8c3ecc314e33b27a820e8b655bc6ae92de43ffbb2f4e4d370f9f SHA512 43b7a0eaf3b7ebc35fa21a5d11dc1089b62fd0a414079a55fbb4ef7cb8211923123c46bec06c3b73eacd5897b7b8b2ae336de7b15750f0802eb28a23ec9e56bd

diff --git a/gnome-extra/nautilus-dropbox/nautilus-dropbox-2024.04.17.ebuild b/gnome-extra/nautilus-dropbox/nautilus-dropbox-2024.04.17.ebuild
new file mode 100644
index 000000000000..b9be5584638e
--- /dev/null
+++ b/gnome-extra/nautilus-dropbox/nautilus-dropbox-2024.04.17.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit autotools python-single-r1 xdg
+
+DESCRIPTION="Dropbox Nautilus Extension"
+HOMEPAGE="https://github.com/dropbox/nautilus-dropbox"
+SRC_URI="https://linux.dropboxstatic.com/packages/${P}.tar.bz2"
+
+LICENSE="GPL-3 CC-BY-ND-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep 'dev-python/pygobject:3[${PYTHON_USEDEP}]' )
+	dev-libs/glib:2
+	gui-libs/gtk:4
+	>=gnome-base/nautilus-43
+	net-misc/dropbox
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	$(python_gen_cond_dep 'dev-python/docutils[${PYTHON_USEDEP}]' )
+	virtual/pkgconfig
+"
+
+# use system rst2man
+PATCHES=(
+	# use system rst2man
+	"${FILESDIR}/${PN}-2019-system-rst2man.patch"
+)
+
+src_prepare() {
+	default
+
+	# use system dropbox
+	sed \
+		-e "s|~/[.]dropbox-dist|${EPREFIX}/opt/dropbox|" \
+		-e "s|\(DROPBOXD_PATH = \).*|\1\"${EPREFIX}/opt/dropbox/dropboxd\"|" \
+		-i dropbox.in || die
+	AT_NOELIBTOOLIZE=yes eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable debug) \
+		--disable-static
+}
+
+src_install() {
+	default
+
+	# removes files which conflicts with system dropbox
+	rm -r "${ED}"/usr/share/applications || die
+	rm -r "${ED}"/usr/bin || die
+
+	find "${ED}" -type f -name '*.la' -delete || die
+}