[gentoo-commits] repo/gentoo:master commit in: gui-wm/dwl/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     257a8d60336a8a028e981d53a95b3ede2eed8ef6
Author:     Leonardo Hernández Hernández <leohdz172 <AT> proton <DOT> me>
AuthorDate: Sat Jul 13 22:50:46 2024 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Mon Jul 29 07:33:49 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=257a8d60

gui-wm/dwl: drop 0.5

Signed-off-by: Leonardo Hernández Hernández <leohdz172 <AT> proton.me>
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 gui-wm/dwl/dwl-0.5.ebuild | 76 -----------------------------------------------
 1 file changed, 76 deletions(-)

diff --git a/gui-wm/dwl/dwl-0.5.ebuild b/gui-wm/dwl/dwl-0.5.ebuild
deleted file mode 100644
index d96014e0f6ec..000000000000
--- a/gui-wm/dwl/dwl-0.5.ebuild
+++ /dev/null
@@ -1,76 +0,0 @@
-# Copyright 2022-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit savedconfig toolchain-funcs
-
-MY_P="${PN}-v${PV}"
-WLROOTS_SLOT="0/17"
-if [[ ${PV} == *9999* ]]; then
-	EGIT_REPO_URI="https://codeberg.org/dwl/dwl.git"
-	inherit git-r3
-
-	# 9999-r0: main (latest stable wlroots release)
-	# 9999-r1: wlroots-next (wlroots-9999)
-	case ${PVR} in
-		9999)
-			EGIT_BRANCH=main
-			;;
-		9999-r1)
-			EGIT_BRANCH=wlroots-next
-			WLROOTS_SLOT="0/9999"
-			;;
-	esac
-else
-	SRC_URI="https://codeberg.org/${PN}/${PN}/releases/download/v${PV}/${MY_P}.tar.gz"
-	S="${WORKDIR}/${MY_P}"
-	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
-fi
-
-DESCRIPTION="dwm for Wayland"
-HOMEPAGE="https://codeberg.org/dwl/dwl"
-
-LICENSE="CC0-1.0 GPL-3+ MIT"
-SLOT="0"
-IUSE="X"
-
-RDEPEND="
-	dev-libs/libinput:=
-	dev-libs/wayland
-	gui-libs/wlroots:${WLROOTS_SLOT}[libinput,session,X?]
-	x11-libs/libxkbcommon
-	X? (
-		x11-libs/libxcb:=
-		x11-libs/xcb-util-wm
-	)
-"
-
-# uses <linux/input-event-codes.h>
-DEPEND="
-	${RDEPEND}
-	sys-kernel/linux-headers
-"
-BDEPEND="
-	>=dev-libs/wayland-protocols-1.32
-	dev-util/wayland-scanner
-	virtual/pkgconfig
-"
-
-src_prepare() {
-	restore_config config.h
-
-	default
-}
-
-src_compile() {
-	emake PKG_CONFIG="$(tc-getPKG_CONFIG)" CC="$(tc-getCC)" \
-		XWAYLAND="$(usev X -DXWAYLAND)" XLIBS="$(usev X "xcb xcb-icccm")" dwl
-}
-
-src_install() {
-	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
-	dodoc CHANGELOG.md README.md
-
-	save_config config.h
-}