[gentoo-commits] repo/gentoo:master commit in: dev-python/pikepdf/

["Michał Górny" <mgorny@gentoo.org>]

commit:     61854ffb95b24e75d3807158f76adda230bf037e
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Jul 23 19:50:09 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Jul 23 20:06:49 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=61854ffb

dev-python/pikepdf: Bump to 9.1.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pikepdf/Manifest             |  1 +
 dev-python/pikepdf/pikepdf-9.1.0.ebuild | 74 +++++++++++++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/dev-python/pikepdf/Manifest b/dev-python/pikepdf/Manifest
index e9702a644e0b..e120c95fd541 100644
--- a/dev-python/pikepdf/Manifest
+++ b/dev-python/pikepdf/Manifest
@@ -3,3 +3,4 @@ DIST pikepdf-8.14.0.tar.gz 2870612 BLAKE2B be0fd5a8d48fccc7695c45acc28cbda825252
 DIST pikepdf-8.15.1.tar.gz 2870723 BLAKE2B 958bb2a417e2f1c9e5e4448b47cdadffb10e82841cc8173503881a86e92e85c05f800a8ad6936f32ee53e6f7a8cd62ee9e28e251de1f32a7cdce055139ec5fa3 SHA512 ae6b0b8bdf7e395943caf503f1d498861bd2719185e6382a522b8c0d4e38413a1b070e912367852bc5735d29b8453d05c57ff384ede825830722470445a534f6
 DIST pikepdf-8.4.1.tar.gz 2853305 BLAKE2B 2298514159db17ba49b8e2fa2407d60de50273bea111ece704251d99193bdc4c8ed77f624237a49c3f4f129e3b14ac4ddd1006cf3024bcbf822bc5523e0fee35 SHA512 6989e8a3888f612e453ec1ea8425c0ca35ccfee19ae5e8c32df136ebc3fbb7728d9fe5beaacb4e392a20c9037a1009fc8f8d53d73634427fb0df9103626e34fa
 DIST pikepdf-9.0.0.tar.gz 2868331 BLAKE2B 6735938fd2c0e8bb6a5fb40896350a2caa2ee20f8982010574a4e682c8ff19d01bc6773d30f78e2d4a5d58496de9dfa8fe9584f1c954205ed4832753addbd373 SHA512 15248d523cebdfbfcd7a5f8b6144b7dc8371612bd77ba3847af1ce626b5d87780911346d3c61bfe7cef545a19f1863c1a4048b35ace56f2cb62dcb962272829d
+DIST pikepdf-9.1.0.tar.gz 2869103 BLAKE2B 39750e280caa2393b69a5c3c841afa9cbb0d5701a20ae9ca4e9a57088cae47e2dd33ca8b605b0b096df131b578a4cdc71eb8696d12b2817426b35a8b13668460 SHA512 0fbf1ca151b6a234cd23a5148c9e8e4e033c5da5c935b4786fe6167555da7016c55b124dd2f9e8dc414c9782829f38412227820229a8459cc9dbe03220620fae

diff --git a/dev-python/pikepdf/pikepdf-9.1.0.ebuild b/dev-python/pikepdf/pikepdf-9.1.0.ebuild
new file mode 100644
index 000000000000..83a7ea2c9370
--- /dev/null
+++ b/dev-python/pikepdf/pikepdf-9.1.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python library to work with pdf files based on qpdf"
+HOMEPAGE="
+	https://github.com/pikepdf/pikepdf/
+	https://pypi.org/project/pikepdf/
+"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="big-endian"
+
+# Check QPDF_MIN_VERSION in pyproject.toml on bumps, as well as
+# https://qpdf.readthedocs.io/en/stable/release-notes.html.
+DEPEND="
+	>=app-text/qpdf-11.5.0:0=
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/deprecated[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pillow-10.0.1[lcms,${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pybind11-2.10.1[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-scm-7.0.5[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/attrs-20.2.0[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-6.36[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.21.0[${PYTHON_USEDEP}]
+		>=dev-python/pillow-5.0.0[${PYTHON_USEDEP},jpeg,lcms,tiff]
+		>=dev-python/psutil-5.9[${PYTHON_USEDEP}]
+		>=dev-python/pytest-timeout-2.1.0[${PYTHON_USEDEP}]
+		>=dev-python/python-dateutil-2.8.1[${PYTHON_USEDEP}]
+		!big-endian? (
+			>=dev-python/python-xmp-toolkit-2.0.1[${PYTHON_USEDEP}]
+		)
+		$(python_gen_cond_dep '
+			dev-python/tomli[${PYTHON_USEDEP}]
+		' 3.10)
+		media-libs/tiff[zlib]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	sed -e '/-n auto/d' -i pyproject.toml || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# fragile to system load
+		tests/test_image_access.py::test_random_image
+		tests/test_image_access.py::test_image_save_compare
+		tests/test_image_access.py::test_palette_nonrgb
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p timeout
+}