[gentoo-commits] repo/gentoo:master commit in: app-misc/fastfetch/

["Viorel Munteanu" <ceamac@gentoo.org>]

commit:     8c1f62244a4115b79a8a97fd3d0c1b4a85f34cfb
Author:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
AuthorDate: Mon Jul 22 10:52:50 2024 +0000
Commit:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
CommitDate: Mon Jul 22 10:54:50 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8c1f6224

app-misc/fastfetch: add 2.19.0

Signed-off-by: Viorel Munteanu <ceamac <AT> gentoo.org>

 app-misc/fastfetch/Manifest                |   1 +
 app-misc/fastfetch/fastfetch-2.19.0.ebuild | 110 +++++++++++++++++++++++++++++
 2 files changed, 111 insertions(+)

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index 873c6006a880..28b92fd184e8 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -2,3 +2,4 @@ DIST fastfetch-2.15.0.tar.gz 1031800 BLAKE2B df41750c2281fb46c594004156b886d0586
 DIST fastfetch-2.16.0.tar.gz 1044675 BLAKE2B 2c22fedef43155c71b3b0d4f590128699dc4d3f44211187f079e62baad338322bea60796bce8f6f23c1221174e1312d67c113b0ae3557a856b550756baebc077 SHA512 3a09e48775946876c69dfa8a739a090a18aa4598f455f6860d41962efeac2064127bf2a31d3a62ccc285682d12548402cf812eae01d56bc068b7855b0f00d4a7
 DIST fastfetch-2.17.2.tar.gz 1051381 BLAKE2B a7bc9e8d945690f10a22b7d1f4539dcc6b3c98549130cee2fe41406470a43d70e72564eeeb5bfb8fafd879c1da852f85b4d6f0b61190d93a1709eff8fcc805c5 SHA512 0f1075fa9b6e89668ef9ac05e5947332f925e49ce7b16e39fc04c510c8f152df12f0c18453724773a980aae65c3c085267beaeb4dcd15d45f560b6b7f6121e67
 DIST fastfetch-2.18.1.tar.gz 1067696 BLAKE2B 96d4ab7d1ee455029c846690eed65a2ae31f6e4f659c9e609c4c0f3cdd3703af0d8b45e1ce12d7399305f9c3a186958037adfbd9c52b399d15bc3bbb074a2cd5 SHA512 f30e2123cc1f98453bb01ae8291d57f8678a1cfd7348f3046de3735d214a7f965240d6e3cf4983c1933531e6bab1e35632af5399fcb6ca0ebf0592b7a929efba
+DIST fastfetch-2.19.0.tar.gz 1074885 BLAKE2B 7f25ec832156e3525a0c242df16a1776ab2c329830474255d96a0a590a16c3a646cd6eeb60b4f7edef54f0f6e79d28ea01b4c0a7f7100132d9003e4d9e5ccacf SHA512 348f314b3a75add6bdc124e496e1eecabba5a35974c9593a9645b5d7da75791f4b91a38dc31b408ca45f7e0054dace8b1076f008c93951178c45968f66274eb7

diff --git a/app-misc/fastfetch/fastfetch-2.19.0.ebuild b/app-misc/fastfetch/fastfetch-2.19.0.ebuild
new file mode 100644
index 000000000000..ffccfb73cae0
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-2.19.0.ebuild
@@ -0,0 +1,110 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Fast neofetch-like system information tool"
+HOMEPAGE="https://github.com/fastfetch-cli/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/fastfetch-cli/fastfetch.git"
+	[[ ${PV} == *0.1.9999 ]] && EGIT_BRANCH=master
+	[[ ${PV} == *0.2.9999 ]] && EGIT_BRANCH=dev
+	[[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
+else
+	SRC_URI="https://github.com/fastfetch-cli/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="X chafa dbus ddcutil drm gnome imagemagick networkmanager opencl opengl osmesa pulseaudio sqlite test vulkan wayland xcb xfce xrandr"
+RESTRICT="!test? ( test )"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+# make sure to crank yyjson minimum version to match bundled version
+RDEPEND="
+	>=dev-libs/yyjson-0.10.0
+	sys-libs/zlib
+	X? ( x11-libs/libX11 )
+	chafa? ( media-gfx/chafa )
+	dbus? ( sys-apps/dbus )
+	ddcutil? ( app-misc/ddcutil:= )
+	drm? ( x11-libs/libdrm )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	networkmanager? ( net-misc/networkmanager )
+	opencl? ( virtual/opencl )
+	opengl? ( media-libs/libglvnd[X] )
+	osmesa? ( media-libs/mesa[osmesa] )
+	pulseaudio? ( media-libs/libpulse )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? (
+		media-libs/vulkan-loader
+		sys-apps/pciutils
+	)
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="
+	${RDEPEND}
+	vulkan? ( dev-util/vulkan-headers )
+"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	xrandr? ( X )
+	chafa? ( imagemagick )
+"
+
+src_configure() {
+	local fastfetch_enable_imagemagick7=no
+	local fastfetch_enable_imagemagick6=no
+	if use imagemagick; then
+		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	fi
+
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_ZLIB=yes
+		-DENABLE_SYSTEM_YYJSON=yes
+		-DIS_MUSL=$(usex elibc_musl)
+		-DINSTALL_LICENSE=no
+
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_DDCUTIL=$(usex ddcutil)
+		-DENABLE_DRM=$(usex drm)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_GLX=$(usex opengl)
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_LIBNM=$(usex networkmanager)
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_OSMESA=$(usex osmesa)
+		-DENABLE_PULSE=$(usex pulseaudio)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_XCB=$(usex xcb)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DBUILD_TESTS=$(usex test)
+	)
+
+	append-cppflags -DNDEBUG
+
+	cmake_src_configure
+}