[gentoo-commits] repo/gentoo:master commit in: net-misc/gnome-remote-desktop/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     ff99b885e97f9fbe1ca9b5261b7ed87db7dac653
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Sun Jan  7 16:06:56 2024 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Tue Jul 16 08:40:32 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ff99b885

net-misc/gnome-remote-desktop: Bump to 46.2

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 net-misc/gnome-remote-desktop/Manifest             |  1 +
 .../gnome-remote-desktop-46.2.ebuild               | 73 ++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/net-misc/gnome-remote-desktop/Manifest b/net-misc/gnome-remote-desktop/Manifest
index 8535efbfff27..f74d6f5767b4 100644
--- a/net-misc/gnome-remote-desktop/Manifest
+++ b/net-misc/gnome-remote-desktop/Manifest
@@ -1 +1,2 @@
 DIST gnome-remote-desktop-45.1.tar.xz 213504 BLAKE2B 78dd348cf15b677f52ca327ac824b2bd5276d53e7b6578bef0634e00e81993c1a1802ee861a31527af03351e6640cc9fcdc5f86fd44f20ec56138837dd9f05b6 SHA512 4572fefa03ee433783c822cf0405bd17b645f3aa08e8d88c04165859fd30643d612e5d7516a64ded8c1a0d2007026d6df877930b5ea127d7e1e939c1bb60f379
+DIST gnome-remote-desktop-46.2.tar.xz 272384 BLAKE2B 68b128e55e168d589652e3077a4abd585734837e501bcc1989ce634310f4ddcc7237a855b6bf669fd581c7b11c1ed62f92dfe567cad79929483541b196f4d8e9 SHA512 55e64cb4d9286a821916bf17c8997cb869a1e29a76098c058d293530773a4859acf67d2570136b0404dc9c2376a419f149e38a2a3fdabf82d8140689a074930e

diff --git a/net-misc/gnome-remote-desktop/gnome-remote-desktop-46.2.ebuild b/net-misc/gnome-remote-desktop/gnome-remote-desktop-46.2.ebuild
new file mode 100644
index 000000000000..3a7d27f8cee9
--- /dev/null
+++ b/net-misc/gnome-remote-desktop/gnome-remote-desktop-46.2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson systemd xdg
+
+DESCRIPTION="Remote desktop daemon for GNOME using pipewire"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-remote-desktop"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="doc +rdp systemd +vnc"
+REQUIRED_USE="|| ( rdp vnc )"
+RESTRICT="test" # Tests run xvfb-run directly
+
+DEPEND="
+	x11-libs/cairo
+	x11-libs/libdrm
+	>=media-libs/libepoxy-1.4
+	>=dev-libs/glib-2.75:2
+	>=dev-libs/libei-1.2.0
+	x11-libs/libnotify
+	app-crypt/libsecret
+	>=media-video/pipewire-0.3.49:=
+	app-crypt/tpm2-tss:=
+	rdp? (
+		>=media-libs/nv-codec-headers-11.1.5.0
+		>=net-misc/freerdp-3.1.0:=[server]
+		>=sys-fs/fuse-3.9.1:3
+		>=sys-auth/polkit-122
+		>=x11-libs/libxkbcommon-1.0.0
+		media-libs/fdk-aac:=
+	)
+	vnc? (
+		net-libs/libvncserver
+	)
+"
+RDEPEND="${DEPEND}
+	x11-wm/mutter[screencast]
+"
+BDEPEND="
+	dev-libs/glib
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	virtual/pkgconfig
+	doc? (
+		app-text/asciidoc
+	)
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use doc man)
+		$(meson_use rdp)
+		$(meson_use vnc)
+		$(meson_use systemd)
+		-Dsystemd_user_unit_dir="$(systemd_get_userunitdir)"
+		-Dtests=false  # Tests run xvfb-run directly
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}