[gentoo-commits] repo/gentoo:master commit in: app-editors/gnome-text-editor/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     dc672a0fc77992ce7654847e52d4da108fbe6242
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Fri May 10 13:25:03 2024 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Tue Jul 16 08:40:31 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=dc672a0f

app-editors/gnome-text-editor: Bump to 46.3

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/34755
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 app-editors/gnome-text-editor/Manifest             |  1 +
 .../gnome-text-editor-46.3.ebuild                  | 57 ++++++++++++++++++++++
 2 files changed, 58 insertions(+)

diff --git a/app-editors/gnome-text-editor/Manifest b/app-editors/gnome-text-editor/Manifest
index 823994d035b3..1ba8576b18fc 100644
--- a/app-editors/gnome-text-editor/Manifest
+++ b/app-editors/gnome-text-editor/Manifest
@@ -1 +1,2 @@
 DIST gnome-text-editor-45.3.tar.xz 618756 BLAKE2B 45a6a78a665f833b0fb2e179125224e1d3757390deee5845b750bbc13368cd9b0b8521b290e42a2c5be82e2e7d78bab5e3aad256d1c87eade22547696807a8ba SHA512 d9fbdbb0dfbb5d10dc1b817f9ebf114a63e20724c3c230da683c8b7f1332371acf869c723a7067dbdafb5b4df23529944b40e5ec212e52a5a3220ca725388c95
+DIST gnome-text-editor-46.3.tar.xz 654128 BLAKE2B 42a3b89bfe977cb2160c390a0391da1634ae4b2490aaf2ba8dc3230695d6064aa5c3aa03596e3f3e075fef50bf4ed5890d52acfe053fe2e98e238c9a839e58b1 SHA512 576b60e3f005cefd9930838d12173609cf7a0e9f6cb16b91be0e68a215c5c814df67c18c8adcf5083b5e1a3280149ed4b0aa1d830ab367aa76949a9ce81efea4

diff --git a/app-editors/gnome-text-editor/gnome-text-editor-46.3.ebuild b/app-editors/gnome-text-editor/gnome-text-editor-46.3.ebuild
new file mode 100644
index 000000000000..817ed3c09384
--- /dev/null
+++ b/app-editors/gnome-text-editor/gnome-text-editor-46.3.ebuild
@@ -0,0 +1,57 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="A simple text editor for the GNOME desktop"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-text-editor"
+S="${WORKDIR}/gnome-text-editor-${PV/_/.}"
+
+LICENSE="GPL-3+ CC-BY-SA-3.0"
+SLOT="0"
+
+IUSE="spell"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+DEPEND="
+	>=dev-libs/glib-2.73.0:2
+	>=gui-libs/gtk-4.12:4
+	>=gui-libs/gtksourceview-5.10.0:5
+	>=gui-libs/libadwaita-1.5_alpha:1
+	app-text/editorconfig-core-c
+	x11-libs/cairo
+	spell? (
+		>=app-text/enchant-2.2.0:2
+		dev-libs/icu:=
+	)
+"
+RDEPEND="${DEPEND}
+	gnome-base/gsettings-desktop-schemas
+"
+BDEPEND="
+	dev-util/glib-utils
+	dev-util/itstool
+	>=sys-devel/gettext-0.21
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature spell enchant)
+		-Dbugreport_url="https://bugs.gentoo.org"
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}