[gentoo-commits] repo/gentoo:master commit in: games-board/gnome-chess/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     a38ee7d501e9f91309de84c1f89e1a8714576527
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Thu Feb 15 12:58:41 2024 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Tue Jul 16 08:40:31 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a38ee7d5

games-board/gnome-chess: Bump to 46.0

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/35345
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 games-board/gnome-chess/Manifest                |  1 +
 games-board/gnome-chess/gnome-chess-46.0.ebuild | 57 +++++++++++++++++++++++++
 2 files changed, 58 insertions(+)

diff --git a/games-board/gnome-chess/Manifest b/games-board/gnome-chess/Manifest
index b3c8ec60bfc8..af17d94f0862 100644
--- a/games-board/gnome-chess/Manifest
+++ b/games-board/gnome-chess/Manifest
@@ -1 +1,2 @@
 DIST gnome-chess-43.2.tar.xz 743344 BLAKE2B 755d70ef964f6337acf852edc6fdbe69fbf3b566dfc36fa697d4c4ecdeeae5df5d1979e54e3304e89963fab01655979a55ac4f827bb1f1b506ab3cea8d147117 SHA512 e10439dd39e61436e3174e1d599d30d06955e65b696b9c37a0e9a8f1a41d19f71f33cca83ec9cc8fe2d8b516c2ec113f22bf3ddd1f1f465286cbe5bde8bcc0a2
+DIST gnome-chess-46.0.tar.xz 782212 BLAKE2B dec141cac14b59b02a3c4e0f10b09e450bf962ff5b688a7cfb31b274e1b92bd0c09a6afa3a32bb21a137114edb349ff3ac7aa88918481374fe2d4baeeca7cef2 SHA512 e605b9750fdc77a0d2b6973f127fb2cf5fadb15080add728c80a8be5ce02035ff6cadb0351751a0612f09632602fe532405d62c68828fd0ec4bf83b9bd11301a

diff --git a/games-board/gnome-chess/gnome-chess-46.0.ebuild b/games-board/gnome-chess/gnome-chess-46.0.ebuild
new file mode 100644
index 000000000000..010d3b295173
--- /dev/null
+++ b/games-board/gnome-chess/gnome-chess-46.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson readme.gentoo-r1 vala xdg
+
+DESCRIPTION="Play the classic two-player boardgame of chess"
+HOMEPAGE="https://wiki.gnome.org/Apps/Chess https://gitlab.gnome.org/GNOME/gnome-chess"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~loong ~riscv ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	gui-libs/gtk:4
+	>=gui-libs/libadwaita-1.0.0:1
+	>=gnome-base/librsvg-2.46.0:2
+	x11-libs/pango
+"
+DEPEND="${RDEPEND}
+	gnome-base/librsvg:2[vala]
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	$(vala_depend)
+	dev-util/itstool
+	dev-libs/appstream-glib
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+DOC_CONTENTS="To be able to play against a computer you will need
+to install a chess engine package, for example games-board/gnuchess"
+
+src_prepare() {
+	default
+	vala_setup
+	xdg_environment_reset
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}