[gentoo-commits] repo/gentoo:master commit in: dev-libs/immer/

["Sam James" <sam@gentoo.org>]

commit:     0714fbf442a91ed7c66bbb9cc1fb0ded03bb1c3c
Author:     Sebastian Parborg <sebastian <AT> blender <DOT> org>
AuthorDate: Mon Jul 15 10:23:41 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Jul 16 07:04:02 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0714fbf4

dev-libs/immer: Add missing libfmt dep for tests

Closes: https://bugs.gentoo.org/936024
Signed-off-by: Sebastian Parborg <darkdefende <AT> gmail.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-libs/immer/immer-0.8.1-r1.ebuild | 51 ++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

diff --git a/dev-libs/immer/immer-0.8.1-r1.ebuild b/dev-libs/immer/immer-0.8.1-r1.ebuild
new file mode 100644
index 000000000000..65da2ecbf6f6
--- /dev/null
+++ b/dev-libs/immer/immer-0.8.1-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Library of persistent and immutable data structures written in C++"
+HOMEPAGE="https://sinusoid.es/immer/"
+SRC_URI="https://github.com/arximboldi/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Boost-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/boost:=
+	dev-libs/boehm-gc
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	test? (
+		<dev-cpp/catch-3:0
+		dev-libs/libfmt
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-fix-dvector-test.patch
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DCCACHE=no
+		-Dimmer_BUILD_DOCS=OFF # Recheck if documentation is in a better state when bumping
+		-Dimmer_BUILD_EXAMPLES=OFF
+		-Dimmer_BUILD_EXTRAS=OFF
+		-Dimmer_BUILD_TESTS=$(usex test)
+		-DDISABLE_WERROR=ON
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	if use test; then
+		cmake_build tests
+	fi
+}