[gentoo-commits] repo/gentoo:master commit in: sys-apps/gnome-disk-utility/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     f69425fcc58b2207d860f2bf573cfe8a737a0f50
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Thu Feb  1 19:07:58 2024 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Mon Jul 15 20:29:08 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f69425fc

sys-apps/gnome-disk-utility: Bump to 46.0

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/35139
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 sys-apps/gnome-disk-utility/Manifest               |  1 +
 .../gnome-disk-utility-46.0.ebuild                 | 63 ++++++++++++++++++++++
 2 files changed, 64 insertions(+)

diff --git a/sys-apps/gnome-disk-utility/Manifest b/sys-apps/gnome-disk-utility/Manifest
index a5721cde5909..2327d3230c75 100644
--- a/sys-apps/gnome-disk-utility/Manifest
+++ b/sys-apps/gnome-disk-utility/Manifest
@@ -1 +1,2 @@
 DIST gnome-disk-utility-45.1.tar.xz 1774976 BLAKE2B cc7aa559acfec54df2adf725dc2c8e6918f148139fdc96d2378d178cb37a0cea1297a5db678c104cf7c103d7fc2e0d6e9dd965147a5afa10f217346ba5abe720 SHA512 30705f0b123738816e8f18c8951b1172f7b09b7c500aa8afa313b5bc1e7d2f248e086663dbe7ca4f44584bb8c2a09ca19ab6fbd11edabfc0f32a47dd939f2131
+DIST gnome-disk-utility-46.0.tar.xz 1775636 BLAKE2B c5cdb02dd90f842c312f48e5295252c8c0056bcb6e322924bab2b8736e80c2505894d35435fc9eedc6690be3cd3b6bf28ba40373cd6b023d19e328f8bb681254 SHA512 c2aa29de1c7f483602499edf127e71270b43c0a6c9241f4c62453f45c65aea500cb8fed7af4f70b7c53d07ac9de9866090e7403d9d523e49dd826361f8224769

diff --git a/sys-apps/gnome-disk-utility/gnome-disk-utility-46.0.ebuild b/sys-apps/gnome-disk-utility/gnome-disk-utility-46.0.ebuild
new file mode 100644
index 000000000000..a2f091de0634
--- /dev/null
+++ b/sys-apps/gnome-disk-utility/gnome-disk-utility-46.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="Disk Utility for GNOME using udisks"
+HOMEPAGE="https://wiki.gnome.org/Apps/Disks"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="fat elogind gnome systemd"
+REQUIRED_USE="?? ( elogind systemd )"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+DEPEND="
+	>=media-libs/libdvdread-4.2.0:0=
+	>=dev-libs/glib-2.31:2
+	>=x11-libs/gtk+-3.16.0:3
+	>=media-libs/libcanberra-0.1[gtk3]
+	>=gui-libs/libhandy-1.5.0:1
+	>=app-arch/xz-utils-5.0.5
+	>=x11-libs/libnotify-0.7
+	>=app-crypt/libsecret-0.7
+	>=dev-libs/libpwquality-1.0.0
+	>=sys-fs/udisks-2.7.6:2
+	elogind? ( >=sys-auth/elogind-209 )
+	systemd? ( >=sys-apps/systemd-209:0= )
+"
+RDEPEND="${DEPEND}
+	x11-themes/adwaita-icon-theme
+	fat? ( sys-fs/dosfstools )
+	gnome? ( >=gnome-base/gnome-settings-daemon-3.8 )
+"
+# libxml2 for xml-stripblanks in gresource
+BDEPEND="
+	dev-libs/libxml2:2
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dlogind=$(usex systemd libsystemd $(usex elogind libelogind none))
+		$(meson_use gnome gsd_plugin)
+		-Dman=true
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}