[gentoo-commits] repo/gentoo:master commit in: dev-libs/libdex/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     c3e8a3f23bcfc277cb1ff8718ac25ad456d47f85
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Fri May 31 23:16:11 2024 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Mon Jul 15 19:21:44 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c3e8a3f2

dev-libs/libdex: Bump to 0.6.1

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/36935
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 dev-libs/libdex/Manifest            |  1 +
 dev-libs/libdex/libdex-0.6.1.ebuild | 70 +++++++++++++++++++++++++++++++++++++
 2 files changed, 71 insertions(+)

diff --git a/dev-libs/libdex/Manifest b/dev-libs/libdex/Manifest
index 873da4389984..cfaf8a8ff39f 100644
--- a/dev-libs/libdex/Manifest
+++ b/dev-libs/libdex/Manifest
@@ -1 +1,2 @@
 DIST libdex-0.4.3.tar.xz 96820 BLAKE2B 51f6c9a209d8ff19d7e97f4d8cbc9065739f08c555712076c9b6f4d345d56522f31afa1b8dffe8da2cfc128d368d7dc5f6a93757f0fe5cfd0a55de17587d776e SHA512 26691373d560d20cefa3a23e31677259b234cdf623b17b8fb2b6976b03768e86e458d2670aa3b260638b595994f278240e972bf3ff5b765013fb6d3114f46cef
+DIST libdex-0.6.1.tar.xz 99056 BLAKE2B 3899f89ac652c2790c93e2799a5b0d066c45ee314c6f773bb586e49c89a8a78e6a09ebf08263b88b25900a15ac736d2bd37590720e0ac0e074581342534eaba3 SHA512 36be15d2da9edeae195abcb6f97639dd7fdea74463cdfdf752293007e44ab41a5e5350a7005883f202d70f96047567fba6370f1a2c45a0f898c242bebc88e847

diff --git a/dev-libs/libdex/libdex-0.6.1.ebuild b/dev-libs/libdex/libdex-0.6.1.ebuild
new file mode 100644
index 000000000000..8da02332bd2d
--- /dev/null
+++ b/dev-libs/libdex/libdex-0.6.1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org linux-info meson vala
+
+DESCRIPTION="Dex provides Future-based programming for GLib-based applications"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/libdex"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+IUSE="+eventfd gtk-doc +introspection +liburing sysprof test vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.68:2
+	liburing? ( >=sys-libs/liburing-0.7:= )
+	introspection? ( dev-libs/gobject-introspection:= )
+	sysprof? ( dev-util/sysprof-capture:4 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	vala? ( $(vala_depend) )
+	dev-util/glib-utils
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gi-docgen )
+"
+
+pkg_setup() {
+	if use eventfd && linux_config_exists; then
+		if ! linux_chkconfig_present EVENTFD ; then
+			ewarn "CONFIG_EVENTFD must be enabled for USE=eventfd"
+		fi
+	fi
+}
+
+src_prepare() {
+	default
+	use vala && vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc docs)
+		-Dexamples=false
+		$(meson_use vala vapi)
+		$(meson_feature introspection)
+		$(meson_use sysprof)
+		$(meson_use test tests)
+		$(meson_feature liburing)
+		$(meson_feature eventfd)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/${PN}-1 "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}