[gentoo-commits] repo/proj/guru:dev commit in: app-text/komikku/

["Takuya Wakazono" <pastalian46@gmail.com>]

commit:     1b1b51902367f7004075f121c8eb3480bcf3674a
Author:     Takuya Wakazono <pastalian46 <AT> gmail <DOT> com>
AuthorDate: Sat Jul 13 12:17:43 2024 +0000
Commit:     Takuya Wakazono <pastalian46 <AT> gmail <DOT> com>
CommitDate: Sat Jul 13 12:55:14 2024 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=1b1b5190

app-text/komikku: add 1.51.1

Signed-off-by: Takuya Wakazono <pastalian46 <AT> gmail.com>

 app-text/komikku/Manifest              |  1 +
 app-text/komikku/komikku-1.51.1.ebuild | 94 ++++++++++++++++++++++++++++++++++
 2 files changed, 95 insertions(+)

diff --git a/app-text/komikku/Manifest b/app-text/komikku/Manifest
index 5020e36b2..988d55cee 100644
--- a/app-text/komikku/Manifest
+++ b/app-text/komikku/Manifest
@@ -1 +1,2 @@
 DIST komikku-1.50.0.tar.gz 4923523 BLAKE2B 5e39e9edc1f47054863c10c39fa7c953cfeca05d115f43600ec2d46f54b1d3b03b8fa9283c00a9a8096e3b32ad82ca5049c29ea7a6eff480e2e44ba7e83488ac SHA512 b62f93798f24b5e57709d4662d9ef7d3efb685ca1ff4c288bec99b8b57d5e20fdd7421d5f637d08cba395bcd6c8457f0e73233afb245e356ba525057b7e9c384
+DIST komikku-1.51.1.tar.gz 4937165 BLAKE2B 7819b176a6f6db2625a5cbfb7a487f58b79b43dab5e1bb24bdb95c7cd809ad1e5310b63cb21205125745d7d5286ebbdc35ecb9be80f59d3b5015b941e79fe7c1 SHA512 be91cf6b48f10063c027d6079a9addde87dea436215fc786cba9eb8e59aa11788485f2a3a1b5910a036e3b428d181892d81fa4c718ce79699a6a60b99d320778

diff --git a/app-text/komikku/komikku-1.51.1.ebuild b/app-text/komikku/komikku-1.51.1.ebuild
new file mode 100644
index 000000000..7af66f6f1
--- /dev/null
+++ b/app-text/komikku/komikku-1.51.1.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE="sqlite(+),ssl(+)"
+DISTUTILS_USE_PEP517=no
+DISTUTILS_SINGLE_IMPL=1
+inherit distutils-r1 meson gnome2-utils xdg
+
+DESCRIPTION="Manga reader for GNOME"
+HOMEPAGE="https://apps.gnome.org/Komikku/"
+SRC_URI="https://codeberg.org/valos/Komikku/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+
+RESTRICT="test"
+# Depend on a random server that may or may not be accessible.
+#PROPERTIES="test_network"
+
+DEPEND="
+	dev-libs/glib:2
+	dev-libs/gobject-introspection
+	>=gui-libs/gtk-4.12:4
+	>=gui-libs/libadwaita-1.5:1[introspection]
+	net-libs/webkit-gtk:6[introspection]
+"
+RDEPEND="
+	${DEPEND}
+	x11-libs/libnotify[introspection]
+	$(python_gen_cond_dep '
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/colorthief[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/dateparser[${PYTHON_USEDEP}]
+		dev-python/emoji[${PYTHON_USEDEP}]
+		dev-python/keyring[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/natsort[${PYTHON_USEDEP}]
+		dev-python/piexif[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pillow-heif[${PYTHON_USEDEP}]
+		dev-python/pygobject[${PYTHON_USEDEP}]
+		dev-python/python-magic[${PYTHON_USEDEP}]
+		dev-python/rarfile[compressed,${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/unidecode[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	dev-util/blueprint-compiler
+	sys-devel/gettext
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pytest-steps[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# fix broken shebang
+	sed "s|py_installation.full_path()|'${PYTHON}'|" -i bin/meson.build || die
+}
+
+src_test() {
+	emake setup
+	emake develop
+	emake test
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}