[gentoo-commits] repo/gentoo:master commit in: www-client/opera-developer/

["Matt Jolly" <kangie@gentoo.org>]

commit:     e75c237f3f9031e8f9a84b6fc9895e86157c871c
Author:     Matt Jolly <kangie <AT> gentoo <DOT> org>
AuthorDate: Thu Jul 11 08:54:37 2024 +0000
Commit:     Matt Jolly <kangie <AT> gentoo <DOT> org>
CommitDate: Thu Jul 11 11:02:25 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e75c237f

www-client/opera-developer: automated bump (113.0.5222.0)

Signed-off-by: Matt Jolly <kangie <AT> gentoo.org>

 www-client/opera-developer/Manifest                |   1 +
 .../opera-developer-113.0.5222.0.ebuild            | 173 +++++++++++++++++++++
 2 files changed, 174 insertions(+)

diff --git a/www-client/opera-developer/Manifest b/www-client/opera-developer/Manifest
index 97b2d76c5ea6..e189fd25f326 100644
--- a/www-client/opera-developer/Manifest
+++ b/www-client/opera-developer/Manifest
@@ -1,3 +1,4 @@
 DIST opera-developer_113.0.5201.0_amd64.deb 112140276 BLAKE2B e97d40a3541d7e1847ede364b33b0670b977b32db575b25019901bac80a61c79c205f09a81b99023ad3697ce3fcb31ddfb465a1c86a2260feee75d77cf88d758 SHA512 d6b37c5612d211c125cc955842ff4195646257dc824871df5531e041c9c3cb83106744a1c121d1a31fd276bc65dbb41b5ad85a6695f0750807de45754b07ea9b
 DIST opera-developer_113.0.5210.0_amd64.deb 111403232 BLAKE2B 603b94351147f937898b9db752f4c942609ca28f56d1ff1cc234c10ac3bd29b9ec80bd6a017d237b575b47f38700467854de5f195e60b1362101b8c88688c54f SHA512 f8270863a4d4b0e29e67f4b741dcfd3cfdb373a0769059c861d508d8a02babf6851a38aab8e7be579b5d0604c7d2d1819c460e8a2f271532580f1e7836b85748
 DIST opera-developer_113.0.5215.0_amd64.deb 111400132 BLAKE2B 77d8c619831f98141e8817c8118807ff1e679c7883550bbc4c4eaddb833f58ac9fdba342bb0460788150a6cb5548f6f670f6ff43c705e6446f8ae087f418af21 SHA512 b87436a75e07c32a3b671b7c68fcc8b3e002835fb772dc238c64dcd21ddefa215c8051f534c97ad9db80ae296454fb3caf590bb183bdbb1137aa9c81a44be765
+DIST opera-developer_113.0.5222.0_amd64.deb 111175644 BLAKE2B 51a72409ba280bf1abd45963bd8f72bbe481700e3dc2d97d11d2d3e71dbb313acf18488e0b52cfd356fd2b27081119aed9f28bce3b605b630c35d08c855a7506 SHA512 a0a3787fb6278e60af1f32307ac3d1b868d45488659734e385bfda1b2bd776a01193c3e0dba5396e05fc37c05d46d9448ab77b0606819a255a3fedf6274ba4ab

diff --git a/www-client/opera-developer/opera-developer-113.0.5222.0.ebuild b/www-client/opera-developer/opera-developer-113.0.5222.0.ebuild
new file mode 100644
index 000000000000..0d49f3a56353
--- /dev/null
+++ b/www-client/opera-developer/opera-developer-113.0.5222.0.ebuild
@@ -0,0 +1,173 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CHROMIUM_LANGS="
+	bg bn ca cs da de el en-GB en-US es-419 es fil fi fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+
+# These are intended for ebuild maintainer use to force RPM if DEB is not available.
+: ${OPERA_FORCE_RPM=no}
+
+inherit chromium-2 pax-utils xdg
+
+if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+	inherit rpm
+	OPERA_ARCHIVE_EXT="rpm"
+else
+	inherit unpacker
+	OPERA_ARCHIVE_EXT="deb"
+fi
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+# Commit ref from `strings libffmpeg.so | grep -F "FFmpeg version"` matches this Chromium version
+# used to select the correct ffmpeg-chromium version (corresponds to a major version of Chromium)
+# Does not need to be updated for every new version of Opera, only when it breaks
+CHROMIUM_VERSION="125"
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}"
+S=${WORKDIR}
+
+LICENSE="OPERA-2018"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+IUSE="+ffmpeg-chromium +proprietary-codecs +suid qt5 qt6"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+	proprietary-codecs? (
+		!ffmpeg-chromium? ( >=media-video/ffmpeg-6.1-r1:0/58.60.60[chromium] )
+		ffmpeg-chromium? ( media-video/ffmpeg-chromium:${CHROMIUM_VERSION} )
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5[X]
+		dev-qt/qtwidgets:5
+	)
+	qt6? ( dev-qt/qtbase:6[gui,widgets] )
+"
+
+QA_PREBUILT="*"
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rpm_src_unpack "${A[0]}"
+	else
+		unpacker
+	fi
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
+	else
+		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	fi
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rm "${OPERA_HOME}/setup_repo.sh" || die
+	else
+		rm -r "usr/share/lintian" || die
+
+		# fix docs
+		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+		gzip -d usr/share/doc/${PF}/changelog.gz || die
+	fi
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		dosym ../../usr/$(get_libdir)/chromium/libffmpeg.so$(usex ffmpeg-chromium .${CHROMIUM_VERSION} "") \
+			  /${OPERA_HOME}/libffmpeg.so
+	fi
+
+	if ! use qt5; then
+		rm "${OPERA_HOME}/libqt5_shim.so" || die
+	fi
+	if ! use qt6; then
+		rm "${OPERA_HOME}/libqt6_shim.so" || die
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "/${OPERA_HOME}/opera_sandbox"
+}