[gentoo-commits] repo/gentoo:master commit in: dev-python/nanobind/

["Sam James" <sam@gentoo.org>]

commit:     c6f59060bb672cd5a6be9c026885b4f24ae0167c
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Mon Jul  8 13:30:07 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon Jul  8 13:59:18 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c6f59060

dev-python/nanobind: new package, add 2.0.0

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-python/nanobind/Manifest              |  1 +
 dev-python/nanobind/metadata.xml          | 12 ++++++
 dev-python/nanobind/nanobind-2.0.0.ebuild | 63 +++++++++++++++++++++++++++++++
 3 files changed, 76 insertions(+)

diff --git a/dev-python/nanobind/Manifest b/dev-python/nanobind/Manifest
new file mode 100644
index 000000000000..779583f66f8b
--- /dev/null
+++ b/dev-python/nanobind/Manifest
@@ -0,0 +1 @@
+DIST nanobind-2.0.0.gh.tar.gz 842956 BLAKE2B 82a2b44d904a2bfc88538d3bac6d5d96b473bcca2ff98647f9edd656a1d20fae324fcf334b848f861723aae666690b6b17ee626dede89bac6b140e9ef8cd01fe SHA512 1bafbf6b18c9b65b5ecb3bbf23a164b17ee52ef4f053a00de986a35e17e662422b54cea1c145f83ee8a3973bba383a949b3c305dcfecfbf139ab90006d42935e

diff --git a/dev-python/nanobind/metadata.xml b/dev-python/nanobind/metadata.xml
new file mode 100644
index 000000000000..aa352e9fc755
--- /dev/null
+++ b/dev-python/nanobind/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">wjakob/nanobind</remote-id>
+		<remote-id type="pypi">nanobind</remote-id>
+	</upstream>
+</pkgmetadata>

diff --git a/dev-python/nanobind/nanobind-2.0.0.ebuild b/dev-python/nanobind/nanobind-2.0.0.ebuild
new file mode 100644
index 000000000000..43f1d179b19e
--- /dev/null
+++ b/dev-python/nanobind/nanobind-2.0.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit cmake distutils-r1
+
+DESCRIPTION="Tiny and efficient C++/Python bindings"
+HOMEPAGE="
+	https://github.com/wjakob/nanobind
+	https://pypi.org/project/nanobind/
+"
+SRC_URI="
+	https://github.com/wjakob/nanobind/archive/refs/tags/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# This test assumes in-source build for the .pyi stubs.
+	# (Hack because EPYTEST_IGNORE doesn't work with the paths it collects(?))
+	echo > tests/test_stubs.py || die
+
+	cmake_src_prepare
+	distutils-r1_python_prepare_all
+}
+
+python_configure() {
+	# XXX: nanobind installs a CMake config file which by default passes -Os
+	# We currently patch around it in dev-python/pyopencl. In future, we
+	# may want to add some override with Gentoo specific environment vars.
+	local mycmakeargs=(
+		-DNB_CREATE_INSTALL_RULES=ON
+		-DNB_USE_SUBMODULE_DEPS=OFF
+		-DNB_TEST=$(usex test)
+	)
+	cmake_src_configure
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	cmake_src_compile
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	cd "${BUILD_DIR}/tests" || die
+	epytest "${S}/tests"
+}
+
+python_install() {
+	distutils-r1_python_install
+	cmake_src_install
+}