public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed
* [gentoo-commits] repo/gentoo:master commit in: dev-python/btrfsutil/
@ 2024-06-20  1:47 Mike Gilbert
  0 siblings, 0 replies; 9+ messages in thread
From: Mike Gilbert @ 2024-06-20  1:47 UTC (permalink / raw
  To: gentoo-commits

commit:     0345190060013534bce58bc0d68c002b936c6579
Author:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
AuthorDate: Wed Jun 19 18:46:54 2024 +0000
Commit:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
CommitDate: Thu Jun 20 01:47:09 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=03451900

dev-python/btrfsutil: new package, add 6.8.1, 6.9

Closes: https://bugs.gentoo.org/934567
Signed-off-by: Mike Gilbert <floppym <AT> gentoo.org>

 dev-python/btrfsutil/Manifest               |  4 +++
 dev-python/btrfsutil/btrfsutil-6.8.1.ebuild | 54 +++++++++++++++++++++++++++++
 dev-python/btrfsutil/btrfsutil-6.9.ebuild   | 54 +++++++++++++++++++++++++++++
 dev-python/btrfsutil/metadata.xml           |  7 ++++
 4 files changed, 119 insertions(+)

diff --git a/dev-python/btrfsutil/Manifest b/dev-python/btrfsutil/Manifest
new file mode 100644
index 000000000000..09b043547505
--- /dev/null
+++ b/dev-python/btrfsutil/Manifest
@@ -0,0 +1,4 @@
+DIST btrfs-progs-v6.8.1.tar.sign 566 BLAKE2B 843eada2b00a2370522edc95d79bcfed88bd24233e647946d4807322550593e4d5f5bb5efa6652c754dd0965dc3e389bc97698a0bd8fc5d0e850bea94de98e72 SHA512 84ebaa6ec27aa5bc87a323f5c6cc82a860fada7311ab8319127de3592294c1076d25959e412f8387d54bad3b8ff838ce39c4db4b04a658b2de2eaa7c976e2b09
+DIST btrfs-progs-v6.8.1.tar.xz 2652968 BLAKE2B 34406dedc6d97bd94a498c3bbb424d34a59b8251b37f9a40a87740f96db77780a4cd76c88055b4d9e4f673b4a3621503a6bedb67ceaf20870fb26c10f49b74e0 SHA512 b5f0694e56eecf1956313b3406610c2e22658ace51a636d79efe996780bb0b03fed95e68a8c9a11dd8649958c0e7dbc7417bb479859365d47b52e478f6830d46
+DIST btrfs-progs-v6.9.tar.sign 566 BLAKE2B a2e26047775bcc407b8f5aa8b08b0708a01c84a8cd649e50a935e15d04e2ee917010fc98df0dfb80320ee25a8dbfbbbabbb1f155489f32391544100956ba9636 SHA512 1e8304b3df013a841e82a8656361946914d35f680b5bc547c1599fdd98a75b66e2b1f869c8b043d7532182318c2183e699a9d6101ab4b1544618d2c8a25362e1
+DIST btrfs-progs-v6.9.tar.xz 2663052 BLAKE2B 9fad691327b6290b3ba0e1a638576b65e4e4d6c8f32549ea0f10188fdb40028315abf5e330976ff7a5efb6a258d0008e7602ae81ba0339888f474dc056791798 SHA512 e97907b377040371f4742a45345ec720e0cb8e0cf9ee5fdc60618ce2bc76f572725ec32e1a178fd57534f73affd3eeb5e6cfebf23734f04583bbbef858d913b2

diff --git a/dev-python/btrfsutil/btrfsutil-6.8.1.ebuild b/dev-python/btrfsutil/btrfsutil-6.8.1.ebuild
new file mode 100644
index 000000000000..92b9fab71ba3
--- /dev/null
+++ b/dev-python/btrfsutil/btrfsutil-6.8.1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/dsterba.asc
+
+inherit distutils-r1 verify-sig
+
+DESCRIPTION="Library for managing Btrfs filesystems"
+HOMEPAGE="https://github.com/kdave/btrfs-progs"
+
+MY_PN="btrfs-progs"
+MY_PV="v${PV/_/-}"
+MY_P="${MY_PN}-${MY_PV}"
+SRC_URI="
+	https://mirrors.edge.kernel.org/pub/linux/kernel/people/kdave/${MY_PN}/${MY_P}.tar.xz
+	verify-sig? ( https://mirrors.edge.kernel.org/pub/linux/kernel/people/kdave/${MY_PN}/${MY_P}.tar.sign )
+"
+S="${WORKDIR}/${MY_P}/libbtrfsutil/python"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+DEPEND="~sys-fs/btrfs-progs-${PV}"
+RDEPEND="${DEPEND}"
+
+distutils_enable_tests unittest
+
+RDEPEND+=" !sys-fs/btrfs-progs[python(-)]"
+
+src_unpack() {
+	if use verify-sig ; then
+		mkdir "${T}"/verify-sig || die
+		pushd "${T}"/verify-sig >/dev/null || die
+
+		# Upstream sign the decompressed .tar
+		# Let's do it separately in ${T} then cleanup to avoid external
+		# effects on normal unpack.
+		cp "${DISTDIR}"/${MY_P}.tar.xz . || die
+		xz -d ${MY_P}.tar.xz || die
+		verify-sig_verify_detached ${MY_P}.tar "${DISTDIR}"/${MY_P}.tar.sign
+
+		popd >/dev/null || die
+		unpack "${T}"/verify-sig/${MY_P}.tar
+		rm -r "${T}"/verify-sig || die
+	else
+		default
+	fi
+}

diff --git a/dev-python/btrfsutil/btrfsutil-6.9.ebuild b/dev-python/btrfsutil/btrfsutil-6.9.ebuild
new file mode 100644
index 000000000000..92b9fab71ba3
--- /dev/null
+++ b/dev-python/btrfsutil/btrfsutil-6.9.ebuild
@@ -0,0 +1,54 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/dsterba.asc
+
+inherit distutils-r1 verify-sig
+
+DESCRIPTION="Library for managing Btrfs filesystems"
+HOMEPAGE="https://github.com/kdave/btrfs-progs"
+
+MY_PN="btrfs-progs"
+MY_PV="v${PV/_/-}"
+MY_P="${MY_PN}-${MY_PV}"
+SRC_URI="
+	https://mirrors.edge.kernel.org/pub/linux/kernel/people/kdave/${MY_PN}/${MY_P}.tar.xz
+	verify-sig? ( https://mirrors.edge.kernel.org/pub/linux/kernel/people/kdave/${MY_PN}/${MY_P}.tar.sign )
+"
+S="${WORKDIR}/${MY_P}/libbtrfsutil/python"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+DEPEND="~sys-fs/btrfs-progs-${PV}"
+RDEPEND="${DEPEND}"
+
+distutils_enable_tests unittest
+
+RDEPEND+=" !sys-fs/btrfs-progs[python(-)]"
+
+src_unpack() {
+	if use verify-sig ; then
+		mkdir "${T}"/verify-sig || die
+		pushd "${T}"/verify-sig >/dev/null || die
+
+		# Upstream sign the decompressed .tar
+		# Let's do it separately in ${T} then cleanup to avoid external
+		# effects on normal unpack.
+		cp "${DISTDIR}"/${MY_P}.tar.xz . || die
+		xz -d ${MY_P}.tar.xz || die
+		verify-sig_verify_detached ${MY_P}.tar "${DISTDIR}"/${MY_P}.tar.sign
+
+		popd >/dev/null || die
+		unpack "${T}"/verify-sig/${MY_P}.tar
+		rm -r "${T}"/verify-sig || die
+	else
+		default
+	fi
+}

diff --git a/dev-python/btrfsutil/metadata.xml b/dev-python/btrfsutil/metadata.xml
new file mode 100644
index 000000000000..65e1fc82d859
--- /dev/null
+++ b/dev-python/btrfsutil/metadata.xml
@@ -0,0 +1,7 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>base-system@gentoo.org</email>
+	</maintainer>
+</pkgmetadata>


^ permalink raw reply related	[flat|nested] 9+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-python/btrfsutil/
@ 2024-06-20  1:49 Mike Gilbert
  0 siblings, 0 replies; 9+ messages in thread
From: Mike Gilbert @ 2024-06-20  1:49 UTC (permalink / raw
  To: gentoo-commits

commit:     3795cc938e3527af75de4eadf5f686d57382cb5d
Author:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 20 01:48:47 2024 +0000
Commit:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
CommitDate: Thu Jun 20 01:48:47 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3795cc93

dev-python/btrfsutil: add github upstream metadata

Signed-off-by: Mike Gilbert <floppym <AT> gentoo.org>

 dev-python/btrfsutil/metadata.xml | 3 +++
 1 file changed, 3 insertions(+)

diff --git a/dev-python/btrfsutil/metadata.xml b/dev-python/btrfsutil/metadata.xml
index 65e1fc82d859..eb3c989f23bf 100644
--- a/dev-python/btrfsutil/metadata.xml
+++ b/dev-python/btrfsutil/metadata.xml
@@ -4,4 +4,7 @@
 	<maintainer type="project">
 		<email>base-system@gentoo.org</email>
 	</maintainer>
+	<upstream>
+		<remote-id type="github">kdave/btrfs-progs</remote-id>
+	</upstream>
 </pkgmetadata>


^ permalink raw reply related	[flat|nested] 9+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-python/btrfsutil/
@ 2024-06-20  2:12 Mike Gilbert
  0 siblings, 0 replies; 9+ messages in thread
From: Mike Gilbert @ 2024-06-20  2:12 UTC (permalink / raw
  To: gentoo-commits

commit:     5cc8ea52655a502cf3f1bc818d163e5154c05b3d
Author:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 20 02:11:24 2024 +0000
Commit:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
CommitDate: Thu Jun 20 02:11:24 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5cc8ea52

dev-python/btrfsutil: optimize src_unpack

Signed-off-by: Mike Gilbert <floppym <AT> gentoo.org>

 dev-python/btrfsutil/btrfsutil-6.8.1.ebuild | 19 ++++---------------
 dev-python/btrfsutil/btrfsutil-6.9.ebuild   | 19 ++++---------------
 2 files changed, 8 insertions(+), 30 deletions(-)

diff --git a/dev-python/btrfsutil/btrfsutil-6.8.1.ebuild b/dev-python/btrfsutil/btrfsutil-6.8.1.ebuild
index 92b9fab71ba3..6da2d87766a8 100644
--- a/dev-python/btrfsutil/btrfsutil-6.8.1.ebuild
+++ b/dev-python/btrfsutil/btrfsutil-6.8.1.ebuild
@@ -35,20 +35,9 @@ RDEPEND+=" !sys-fs/btrfs-progs[python(-)]"
 
 src_unpack() {
 	if use verify-sig ; then
-		mkdir "${T}"/verify-sig || die
-		pushd "${T}"/verify-sig >/dev/null || die
-
-		# Upstream sign the decompressed .tar
-		# Let's do it separately in ${T} then cleanup to avoid external
-		# effects on normal unpack.
-		cp "${DISTDIR}"/${MY_P}.tar.xz . || die
-		xz -d ${MY_P}.tar.xz || die
-		verify-sig_verify_detached ${MY_P}.tar "${DISTDIR}"/${MY_P}.tar.sign
-
-		popd >/dev/null || die
-		unpack "${T}"/verify-sig/${MY_P}.tar
-		rm -r "${T}"/verify-sig || die
-	else
-		default
+		verify-sig_verify_detached \
+			<(xz -cd "${DISTDIR}"/${MY_P}.tar.xz) \
+			"${DISTDIR}"/${MY_P}.tar.sign
 	fi
+	default
 }

diff --git a/dev-python/btrfsutil/btrfsutil-6.9.ebuild b/dev-python/btrfsutil/btrfsutil-6.9.ebuild
index 92b9fab71ba3..6da2d87766a8 100644
--- a/dev-python/btrfsutil/btrfsutil-6.9.ebuild
+++ b/dev-python/btrfsutil/btrfsutil-6.9.ebuild
@@ -35,20 +35,9 @@ RDEPEND+=" !sys-fs/btrfs-progs[python(-)]"
 
 src_unpack() {
 	if use verify-sig ; then
-		mkdir "${T}"/verify-sig || die
-		pushd "${T}"/verify-sig >/dev/null || die
-
-		# Upstream sign the decompressed .tar
-		# Let's do it separately in ${T} then cleanup to avoid external
-		# effects on normal unpack.
-		cp "${DISTDIR}"/${MY_P}.tar.xz . || die
-		xz -d ${MY_P}.tar.xz || die
-		verify-sig_verify_detached ${MY_P}.tar "${DISTDIR}"/${MY_P}.tar.sign
-
-		popd >/dev/null || die
-		unpack "${T}"/verify-sig/${MY_P}.tar
-		rm -r "${T}"/verify-sig || die
-	else
-		default
+		verify-sig_verify_detached \
+			<(xz -cd "${DISTDIR}"/${MY_P}.tar.xz) \
+			"${DISTDIR}"/${MY_P}.tar.sign
 	fi
+	default
 }


^ permalink raw reply related	[flat|nested] 9+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-python/btrfsutil/
@ 2024-06-20 10:24 Sam James
  0 siblings, 0 replies; 9+ messages in thread
From: Sam James @ 2024-06-20 10:24 UTC (permalink / raw
  To: gentoo-commits

commit:     c4671092372195ac224ea56511e91a828a5796d3
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 20 10:23:07 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu Jun 20 10:23:17 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c4671092

dev-python/btrfsutil: optimize src_unpack further

As mentioned in c8e331071da74d11d651ebd32bbf4efbd25e0f8e.

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-python/btrfsutil/btrfsutil-6.9.ebuild | 13 ++++++++-----
 1 file changed, 8 insertions(+), 5 deletions(-)

diff --git a/dev-python/btrfsutil/btrfsutil-6.9.ebuild b/dev-python/btrfsutil/btrfsutil-6.9.ebuild
index 6da2d87766a8..15d87b143716 100644
--- a/dev-python/btrfsutil/btrfsutil-6.9.ebuild
+++ b/dev-python/btrfsutil/btrfsutil-6.9.ebuild
@@ -34,10 +34,13 @@ distutils_enable_tests unittest
 RDEPEND+=" !sys-fs/btrfs-progs[python(-)]"
 
 src_unpack() {
-	if use verify-sig ; then
-		verify-sig_verify_detached \
-			<(xz -cd "${DISTDIR}"/${MY_P}.tar.xz) \
-			"${DISTDIR}"/${MY_P}.tar.sign
+	# Upstream sign the decompressed .tar
+	if use verify-sig; then
+		einfo "Unpacking ${MY_P}.tar.xz ..."
+		verify-sig_verify_detached - "${DISTDIR}"/${MY_P}.tar.sign \
+			< <(xz -cd "${DISTDIR}"/${MY_P}.tar.xz | tee >(tar -x))
+		assert "Unpack failed"
+	else
+		default
 	fi
-	default
 }


^ permalink raw reply related	[flat|nested] 9+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-python/btrfsutil/
@ 2024-07-08 11:57 Sam James
  0 siblings, 0 replies; 9+ messages in thread
From: Sam James @ 2024-07-08 11:57 UTC (permalink / raw
  To: gentoo-commits

commit:     29331d343d3b83ab28e636a0eb6b62bf7582ad3a
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Mon Jul  8 11:52:41 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon Jul  8 11:55:59 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=29331d34

dev-python/btrfsutil: disable py3.13

```
module.c: In function ‘path_converter’:
module.c:70:24: error: implicit declaration of function ‘_PyObject_LookupSpecial’ [-Wimplicit-function-declaration]
   70 |                 func = _PyObject_LookupSpecial(o, &PyId___fspath__);
      |                        ^~~~~~~~~~~~~~~~~~~~~~~
module.c:70:22: error: assignment to ‘PyObject *’ {aka ‘struct _object *’} from ‘int’ makes pointer from integer without a cast [-Wint-conversion]
   70 |                 func = _PyObject_LookupSpecial(o, &PyId___fspath__);
      |                      ^
```

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-python/btrfsutil/btrfsutil-6.8.1.ebuild | 3 ++-
 dev-python/btrfsutil/btrfsutil-6.9.ebuild   | 3 ++-
 2 files changed, 4 insertions(+), 2 deletions(-)

diff --git a/dev-python/btrfsutil/btrfsutil-6.8.1.ebuild b/dev-python/btrfsutil/btrfsutil-6.8.1.ebuild
index 6da2d87766a8..29bf098bb9e0 100644
--- a/dev-python/btrfsutil/btrfsutil-6.8.1.ebuild
+++ b/dev-python/btrfsutil/btrfsutil-6.8.1.ebuild
@@ -5,7 +5,8 @@ EAPI=8
 
 DISTUTILS_EXT=1
 DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{10..13} )
+# py3.13: https://github.com/kdave/btrfs-progs/issues/838
+PYTHON_COMPAT=( python3_{10..12} )
 VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/dsterba.asc
 
 inherit distutils-r1 verify-sig

diff --git a/dev-python/btrfsutil/btrfsutil-6.9.ebuild b/dev-python/btrfsutil/btrfsutil-6.9.ebuild
index 15d87b143716..ea175591c6b1 100644
--- a/dev-python/btrfsutil/btrfsutil-6.9.ebuild
+++ b/dev-python/btrfsutil/btrfsutil-6.9.ebuild
@@ -5,7 +5,8 @@ EAPI=8
 
 DISTUTILS_EXT=1
 DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{10..13} )
+# py3.13: https://github.com/kdave/btrfs-progs/issues/838
+PYTHON_COMPAT=( python3_{10..12} )
 VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/dsterba.asc
 
 inherit distutils-r1 verify-sig


^ permalink raw reply related	[flat|nested] 9+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-python/btrfsutil/
@ 2024-07-08 11:57 Sam James
  0 siblings, 0 replies; 9+ messages in thread
From: Sam James @ 2024-07-08 11:57 UTC (permalink / raw
  To: gentoo-commits

commit:     44dd5ce29bdf99412d728bf55e469a082cf0b48e
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Mon Jul  8 11:53:46 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon Jul  8 11:56:00 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=44dd5ce2

dev-python/btrfsutil: add 6.9.2

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-python/btrfsutil/Manifest               |  2 ++
 dev-python/btrfsutil/btrfsutil-6.9.2.ebuild | 47 +++++++++++++++++++++++++++++
 2 files changed, 49 insertions(+)

diff --git a/dev-python/btrfsutil/Manifest b/dev-python/btrfsutil/Manifest
index 09b043547505..e81c9c007988 100644
--- a/dev-python/btrfsutil/Manifest
+++ b/dev-python/btrfsutil/Manifest
@@ -1,4 +1,6 @@
 DIST btrfs-progs-v6.8.1.tar.sign 566 BLAKE2B 843eada2b00a2370522edc95d79bcfed88bd24233e647946d4807322550593e4d5f5bb5efa6652c754dd0965dc3e389bc97698a0bd8fc5d0e850bea94de98e72 SHA512 84ebaa6ec27aa5bc87a323f5c6cc82a860fada7311ab8319127de3592294c1076d25959e412f8387d54bad3b8ff838ce39c4db4b04a658b2de2eaa7c976e2b09
 DIST btrfs-progs-v6.8.1.tar.xz 2652968 BLAKE2B 34406dedc6d97bd94a498c3bbb424d34a59b8251b37f9a40a87740f96db77780a4cd76c88055b4d9e4f673b4a3621503a6bedb67ceaf20870fb26c10f49b74e0 SHA512 b5f0694e56eecf1956313b3406610c2e22658ace51a636d79efe996780bb0b03fed95e68a8c9a11dd8649958c0e7dbc7417bb479859365d47b52e478f6830d46
+DIST btrfs-progs-v6.9.2.tar.sign 566 BLAKE2B 4cd95496d355444c7d3e582a7e6c05fbb55683008b1585a26f38aef6cceb1afd5e80c9611518d6bd92dc1167798d4012c4bcab2f9bda752c459d94cfa6f3c477 SHA512 3fb04e1894e231abde388a39d2f0c90f43c1a1494622c2158fab9b94bb340e064404bcf96e24d913c60aaf5e06ade42fbb91a479949109b329682bb089f66bf2
+DIST btrfs-progs-v6.9.2.tar.xz 2661684 BLAKE2B 38ab189ac8271ba8d68b74e82569159c671cca1cb946f56ccab28b6b206cb6ee5b330d83afc3536b7e0d7399da3fb01e368809c1ef4a64b843ea88796ebd28bd SHA512 1df9d5456d07a035c38c17795996a4fc621eeaa244ef54383d4387205826d2a6e971910e55031d20bb1baf23193efa7439e110312ffd8471f07aaf8c0baca20a
 DIST btrfs-progs-v6.9.tar.sign 566 BLAKE2B a2e26047775bcc407b8f5aa8b08b0708a01c84a8cd649e50a935e15d04e2ee917010fc98df0dfb80320ee25a8dbfbbbabbb1f155489f32391544100956ba9636 SHA512 1e8304b3df013a841e82a8656361946914d35f680b5bc547c1599fdd98a75b66e2b1f869c8b043d7532182318c2183e699a9d6101ab4b1544618d2c8a25362e1
 DIST btrfs-progs-v6.9.tar.xz 2663052 BLAKE2B 9fad691327b6290b3ba0e1a638576b65e4e4d6c8f32549ea0f10188fdb40028315abf5e330976ff7a5efb6a258d0008e7602ae81ba0339888f474dc056791798 SHA512 e97907b377040371f4742a45345ec720e0cb8e0cf9ee5fdc60618ce2bc76f572725ec32e1a178fd57534f73affd3eeb5e6cfebf23734f04583bbbef858d913b2

diff --git a/dev-python/btrfsutil/btrfsutil-6.9.2.ebuild b/dev-python/btrfsutil/btrfsutil-6.9.2.ebuild
new file mode 100644
index 000000000000..ea175591c6b1
--- /dev/null
+++ b/dev-python/btrfsutil/btrfsutil-6.9.2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+# py3.13: https://github.com/kdave/btrfs-progs/issues/838
+PYTHON_COMPAT=( python3_{10..12} )
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/dsterba.asc
+
+inherit distutils-r1 verify-sig
+
+DESCRIPTION="Library for managing Btrfs filesystems"
+HOMEPAGE="https://github.com/kdave/btrfs-progs"
+
+MY_PN="btrfs-progs"
+MY_PV="v${PV/_/-}"
+MY_P="${MY_PN}-${MY_PV}"
+SRC_URI="
+	https://mirrors.edge.kernel.org/pub/linux/kernel/people/kdave/${MY_PN}/${MY_P}.tar.xz
+	verify-sig? ( https://mirrors.edge.kernel.org/pub/linux/kernel/people/kdave/${MY_PN}/${MY_P}.tar.sign )
+"
+S="${WORKDIR}/${MY_P}/libbtrfsutil/python"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+DEPEND="~sys-fs/btrfs-progs-${PV}"
+RDEPEND="${DEPEND}"
+
+distutils_enable_tests unittest
+
+RDEPEND+=" !sys-fs/btrfs-progs[python(-)]"
+
+src_unpack() {
+	# Upstream sign the decompressed .tar
+	if use verify-sig; then
+		einfo "Unpacking ${MY_P}.tar.xz ..."
+		verify-sig_verify_detached - "${DISTDIR}"/${MY_P}.tar.sign \
+			< <(xz -cd "${DISTDIR}"/${MY_P}.tar.xz | tee >(tar -x))
+		assert "Unpack failed"
+	else
+		default
+	fi
+}


^ permalink raw reply related	[flat|nested] 9+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-python/btrfsutil/
@ 2024-08-15 18:09 Sam James
  0 siblings, 0 replies; 9+ messages in thread
From: Sam James @ 2024-08-15 18:09 UTC (permalink / raw
  To: gentoo-commits

commit:     51e512df0f5edcffc6385182c2437bea4972f6bc
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Thu Aug 15 18:08:34 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu Aug 15 18:09:07 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=51e512df

dev-python/btrfsutil: add 6.10.1

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-python/btrfsutil/Manifest                |  2 ++
 dev-python/btrfsutil/btrfsutil-6.10.1.ebuild | 46 ++++++++++++++++++++++++++++
 2 files changed, 48 insertions(+)

diff --git a/dev-python/btrfsutil/Manifest b/dev-python/btrfsutil/Manifest
index e81c9c007988..e35d2c597415 100644
--- a/dev-python/btrfsutil/Manifest
+++ b/dev-python/btrfsutil/Manifest
@@ -1,3 +1,5 @@
+DIST btrfs-progs-v6.10.1.tar.sign 566 BLAKE2B dc18c0048716e422475c6630c26c74e09b3595fb8c5c1a1826464eb837d16edfe7d5fa1f418631ae4d380b24bc3fb91fa79ba1e9b1d42a2534838558362ddc18 SHA512 a8a1805ab22feda9f0535841d44120200e48d6d3762ae98f3323be09c9bd7905ff69f21066a8de1fe5cb34a3113879b73ae030a74ccc74737f06dafb32093375
+DIST btrfs-progs-v6.10.1.tar.xz 2670604 BLAKE2B 7a2631b8462bb02be0936861a42b868907bd4f4e365293f9c95744b963e769b81248ba0a290fca517d689ff9f93d8709cc37e217264b2dac1469a47349f97e8c SHA512 cd10747d1f5f9377abfdf209b517791d3eb13b417c0be65fd5c0c044b01063125b4176c178345387bb3deda7a3a379953f31d46d7834854455a5dbfbf967aa97
 DIST btrfs-progs-v6.8.1.tar.sign 566 BLAKE2B 843eada2b00a2370522edc95d79bcfed88bd24233e647946d4807322550593e4d5f5bb5efa6652c754dd0965dc3e389bc97698a0bd8fc5d0e850bea94de98e72 SHA512 84ebaa6ec27aa5bc87a323f5c6cc82a860fada7311ab8319127de3592294c1076d25959e412f8387d54bad3b8ff838ce39c4db4b04a658b2de2eaa7c976e2b09
 DIST btrfs-progs-v6.8.1.tar.xz 2652968 BLAKE2B 34406dedc6d97bd94a498c3bbb424d34a59b8251b37f9a40a87740f96db77780a4cd76c88055b4d9e4f673b4a3621503a6bedb67ceaf20870fb26c10f49b74e0 SHA512 b5f0694e56eecf1956313b3406610c2e22658ace51a636d79efe996780bb0b03fed95e68a8c9a11dd8649958c0e7dbc7417bb479859365d47b52e478f6830d46
 DIST btrfs-progs-v6.9.2.tar.sign 566 BLAKE2B 4cd95496d355444c7d3e582a7e6c05fbb55683008b1585a26f38aef6cceb1afd5e80c9611518d6bd92dc1167798d4012c4bcab2f9bda752c459d94cfa6f3c477 SHA512 3fb04e1894e231abde388a39d2f0c90f43c1a1494622c2158fab9b94bb340e064404bcf96e24d913c60aaf5e06ade42fbb91a479949109b329682bb089f66bf2

diff --git a/dev-python/btrfsutil/btrfsutil-6.10.1.ebuild b/dev-python/btrfsutil/btrfsutil-6.10.1.ebuild
new file mode 100644
index 000000000000..15d87b143716
--- /dev/null
+++ b/dev-python/btrfsutil/btrfsutil-6.10.1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/dsterba.asc
+
+inherit distutils-r1 verify-sig
+
+DESCRIPTION="Library for managing Btrfs filesystems"
+HOMEPAGE="https://github.com/kdave/btrfs-progs"
+
+MY_PN="btrfs-progs"
+MY_PV="v${PV/_/-}"
+MY_P="${MY_PN}-${MY_PV}"
+SRC_URI="
+	https://mirrors.edge.kernel.org/pub/linux/kernel/people/kdave/${MY_PN}/${MY_P}.tar.xz
+	verify-sig? ( https://mirrors.edge.kernel.org/pub/linux/kernel/people/kdave/${MY_PN}/${MY_P}.tar.sign )
+"
+S="${WORKDIR}/${MY_P}/libbtrfsutil/python"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+DEPEND="~sys-fs/btrfs-progs-${PV}"
+RDEPEND="${DEPEND}"
+
+distutils_enable_tests unittest
+
+RDEPEND+=" !sys-fs/btrfs-progs[python(-)]"
+
+src_unpack() {
+	# Upstream sign the decompressed .tar
+	if use verify-sig; then
+		einfo "Unpacking ${MY_P}.tar.xz ..."
+		verify-sig_verify_detached - "${DISTDIR}"/${MY_P}.tar.sign \
+			< <(xz -cd "${DISTDIR}"/${MY_P}.tar.xz | tee >(tar -x))
+		assert "Unpack failed"
+	else
+		default
+	fi
+}


^ permalink raw reply related	[flat|nested] 9+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-python/btrfsutil/
@ 2024-09-02  3:17 Sam James
  0 siblings, 0 replies; 9+ messages in thread
From: Sam James @ 2024-09-02  3:17 UTC (permalink / raw
  To: gentoo-commits

commit:     7e414a3362eb6271f55104f28d99579bfba62b69
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Mon Sep  2 03:16:50 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon Sep  2 03:17:13 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7e414a33

dev-python/btrfsutil: drop 6.8.1, 6.9

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-python/btrfsutil/Manifest               |  4 ---
 dev-python/btrfsutil/btrfsutil-6.8.1.ebuild | 44 ---------------------------
 dev-python/btrfsutil/btrfsutil-6.9.ebuild   | 47 -----------------------------
 3 files changed, 95 deletions(-)

diff --git a/dev-python/btrfsutil/Manifest b/dev-python/btrfsutil/Manifest
index e35d2c597415..2343cf118064 100644
--- a/dev-python/btrfsutil/Manifest
+++ b/dev-python/btrfsutil/Manifest
@@ -1,8 +1,4 @@
 DIST btrfs-progs-v6.10.1.tar.sign 566 BLAKE2B dc18c0048716e422475c6630c26c74e09b3595fb8c5c1a1826464eb837d16edfe7d5fa1f418631ae4d380b24bc3fb91fa79ba1e9b1d42a2534838558362ddc18 SHA512 a8a1805ab22feda9f0535841d44120200e48d6d3762ae98f3323be09c9bd7905ff69f21066a8de1fe5cb34a3113879b73ae030a74ccc74737f06dafb32093375
 DIST btrfs-progs-v6.10.1.tar.xz 2670604 BLAKE2B 7a2631b8462bb02be0936861a42b868907bd4f4e365293f9c95744b963e769b81248ba0a290fca517d689ff9f93d8709cc37e217264b2dac1469a47349f97e8c SHA512 cd10747d1f5f9377abfdf209b517791d3eb13b417c0be65fd5c0c044b01063125b4176c178345387bb3deda7a3a379953f31d46d7834854455a5dbfbf967aa97
-DIST btrfs-progs-v6.8.1.tar.sign 566 BLAKE2B 843eada2b00a2370522edc95d79bcfed88bd24233e647946d4807322550593e4d5f5bb5efa6652c754dd0965dc3e389bc97698a0bd8fc5d0e850bea94de98e72 SHA512 84ebaa6ec27aa5bc87a323f5c6cc82a860fada7311ab8319127de3592294c1076d25959e412f8387d54bad3b8ff838ce39c4db4b04a658b2de2eaa7c976e2b09
-DIST btrfs-progs-v6.8.1.tar.xz 2652968 BLAKE2B 34406dedc6d97bd94a498c3bbb424d34a59b8251b37f9a40a87740f96db77780a4cd76c88055b4d9e4f673b4a3621503a6bedb67ceaf20870fb26c10f49b74e0 SHA512 b5f0694e56eecf1956313b3406610c2e22658ace51a636d79efe996780bb0b03fed95e68a8c9a11dd8649958c0e7dbc7417bb479859365d47b52e478f6830d46
 DIST btrfs-progs-v6.9.2.tar.sign 566 BLAKE2B 4cd95496d355444c7d3e582a7e6c05fbb55683008b1585a26f38aef6cceb1afd5e80c9611518d6bd92dc1167798d4012c4bcab2f9bda752c459d94cfa6f3c477 SHA512 3fb04e1894e231abde388a39d2f0c90f43c1a1494622c2158fab9b94bb340e064404bcf96e24d913c60aaf5e06ade42fbb91a479949109b329682bb089f66bf2
 DIST btrfs-progs-v6.9.2.tar.xz 2661684 BLAKE2B 38ab189ac8271ba8d68b74e82569159c671cca1cb946f56ccab28b6b206cb6ee5b330d83afc3536b7e0d7399da3fb01e368809c1ef4a64b843ea88796ebd28bd SHA512 1df9d5456d07a035c38c17795996a4fc621eeaa244ef54383d4387205826d2a6e971910e55031d20bb1baf23193efa7439e110312ffd8471f07aaf8c0baca20a
-DIST btrfs-progs-v6.9.tar.sign 566 BLAKE2B a2e26047775bcc407b8f5aa8b08b0708a01c84a8cd649e50a935e15d04e2ee917010fc98df0dfb80320ee25a8dbfbbbabbb1f155489f32391544100956ba9636 SHA512 1e8304b3df013a841e82a8656361946914d35f680b5bc547c1599fdd98a75b66e2b1f869c8b043d7532182318c2183e699a9d6101ab4b1544618d2c8a25362e1
-DIST btrfs-progs-v6.9.tar.xz 2663052 BLAKE2B 9fad691327b6290b3ba0e1a638576b65e4e4d6c8f32549ea0f10188fdb40028315abf5e330976ff7a5efb6a258d0008e7602ae81ba0339888f474dc056791798 SHA512 e97907b377040371f4742a45345ec720e0cb8e0cf9ee5fdc60618ce2bc76f572725ec32e1a178fd57534f73affd3eeb5e6cfebf23734f04583bbbef858d913b2

diff --git a/dev-python/btrfsutil/btrfsutil-6.8.1.ebuild b/dev-python/btrfsutil/btrfsutil-6.8.1.ebuild
deleted file mode 100644
index 29bf098bb9e0..000000000000
--- a/dev-python/btrfsutil/btrfsutil-6.8.1.ebuild
+++ /dev/null
@@ -1,44 +0,0 @@
-# Copyright 2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_EXT=1
-DISTUTILS_USE_PEP517=setuptools
-# py3.13: https://github.com/kdave/btrfs-progs/issues/838
-PYTHON_COMPAT=( python3_{10..12} )
-VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/dsterba.asc
-
-inherit distutils-r1 verify-sig
-
-DESCRIPTION="Library for managing Btrfs filesystems"
-HOMEPAGE="https://github.com/kdave/btrfs-progs"
-
-MY_PN="btrfs-progs"
-MY_PV="v${PV/_/-}"
-MY_P="${MY_PN}-${MY_PV}"
-SRC_URI="
-	https://mirrors.edge.kernel.org/pub/linux/kernel/people/kdave/${MY_PN}/${MY_P}.tar.xz
-	verify-sig? ( https://mirrors.edge.kernel.org/pub/linux/kernel/people/kdave/${MY_PN}/${MY_P}.tar.sign )
-"
-S="${WORKDIR}/${MY_P}/libbtrfsutil/python"
-
-LICENSE="LGPL-2+"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
-
-DEPEND="~sys-fs/btrfs-progs-${PV}"
-RDEPEND="${DEPEND}"
-
-distutils_enable_tests unittest
-
-RDEPEND+=" !sys-fs/btrfs-progs[python(-)]"
-
-src_unpack() {
-	if use verify-sig ; then
-		verify-sig_verify_detached \
-			<(xz -cd "${DISTDIR}"/${MY_P}.tar.xz) \
-			"${DISTDIR}"/${MY_P}.tar.sign
-	fi
-	default
-}

diff --git a/dev-python/btrfsutil/btrfsutil-6.9.ebuild b/dev-python/btrfsutil/btrfsutil-6.9.ebuild
deleted file mode 100644
index ea175591c6b1..000000000000
--- a/dev-python/btrfsutil/btrfsutil-6.9.ebuild
+++ /dev/null
@@ -1,47 +0,0 @@
-# Copyright 2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_EXT=1
-DISTUTILS_USE_PEP517=setuptools
-# py3.13: https://github.com/kdave/btrfs-progs/issues/838
-PYTHON_COMPAT=( python3_{10..12} )
-VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/dsterba.asc
-
-inherit distutils-r1 verify-sig
-
-DESCRIPTION="Library for managing Btrfs filesystems"
-HOMEPAGE="https://github.com/kdave/btrfs-progs"
-
-MY_PN="btrfs-progs"
-MY_PV="v${PV/_/-}"
-MY_P="${MY_PN}-${MY_PV}"
-SRC_URI="
-	https://mirrors.edge.kernel.org/pub/linux/kernel/people/kdave/${MY_PN}/${MY_P}.tar.xz
-	verify-sig? ( https://mirrors.edge.kernel.org/pub/linux/kernel/people/kdave/${MY_PN}/${MY_P}.tar.sign )
-"
-S="${WORKDIR}/${MY_P}/libbtrfsutil/python"
-
-LICENSE="LGPL-2+"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
-
-DEPEND="~sys-fs/btrfs-progs-${PV}"
-RDEPEND="${DEPEND}"
-
-distutils_enable_tests unittest
-
-RDEPEND+=" !sys-fs/btrfs-progs[python(-)]"
-
-src_unpack() {
-	# Upstream sign the decompressed .tar
-	if use verify-sig; then
-		einfo "Unpacking ${MY_P}.tar.xz ..."
-		verify-sig_verify_detached - "${DISTDIR}"/${MY_P}.tar.sign \
-			< <(xz -cd "${DISTDIR}"/${MY_P}.tar.xz | tee >(tar -x))
-		assert "Unpack failed"
-	else
-		default
-	fi
-}


^ permalink raw reply related	[flat|nested] 9+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: dev-python/btrfsutil/
@ 2024-09-17 16:45 Sam James
  0 siblings, 0 replies; 9+ messages in thread
From: Sam James @ 2024-09-17 16:45 UTC (permalink / raw
  To: gentoo-commits

commit:     f9ceacbbdf16a9b2e7380b9c5167e90ac780b246
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Tue Sep 17 16:42:26 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Sep 17 16:42:26 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f9ceacbb

dev-python/btrfsutil: add 6.11

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-python/btrfsutil/Manifest              |  2 ++
 dev-python/btrfsutil/btrfsutil-6.11.ebuild | 46 ++++++++++++++++++++++++++++++
 2 files changed, 48 insertions(+)

diff --git a/dev-python/btrfsutil/Manifest b/dev-python/btrfsutil/Manifest
index 2343cf118064..4e69acaa55d3 100644
--- a/dev-python/btrfsutil/Manifest
+++ b/dev-python/btrfsutil/Manifest
@@ -1,4 +1,6 @@
 DIST btrfs-progs-v6.10.1.tar.sign 566 BLAKE2B dc18c0048716e422475c6630c26c74e09b3595fb8c5c1a1826464eb837d16edfe7d5fa1f418631ae4d380b24bc3fb91fa79ba1e9b1d42a2534838558362ddc18 SHA512 a8a1805ab22feda9f0535841d44120200e48d6d3762ae98f3323be09c9bd7905ff69f21066a8de1fe5cb34a3113879b73ae030a74ccc74737f06dafb32093375
 DIST btrfs-progs-v6.10.1.tar.xz 2670604 BLAKE2B 7a2631b8462bb02be0936861a42b868907bd4f4e365293f9c95744b963e769b81248ba0a290fca517d689ff9f93d8709cc37e217264b2dac1469a47349f97e8c SHA512 cd10747d1f5f9377abfdf209b517791d3eb13b417c0be65fd5c0c044b01063125b4176c178345387bb3deda7a3a379953f31d46d7834854455a5dbfbf967aa97
+DIST btrfs-progs-v6.11.tar.sign 566 BLAKE2B 15db44b5db3265eff9d5195ad4842cef5d001c46e1170f219784fca8d049756dccbc1bd95f20fc343fbdf1078c610a166921c043828cdc5f64c0f465323ca0e4 SHA512 a2fdd9100ad3ddd30cb923a72a2b4f70634277e5fbbf0d2cf912c00dc876dad6cd2c24e624f41dbb83aabdda4e3c08aea9c0ae39084bb3481700491df3d47fd5
+DIST btrfs-progs-v6.11.tar.xz 2695752 BLAKE2B 6dec219394e39a821f29858eddf1d501537d3cebad2dc83f0cea6d88d0b0e94c4fe2e660a48a27942ccfb6f3ac0630d5930f44e083168de65b60af36e895b2af SHA512 fad3c7e908e2020a3983f9737a7e87367023e2ad35aea14197e2bfa71c1e0435bc3da3f7e6ef463de47c033323163f8b1b7933013042c6fcea673d0f4723ade1
 DIST btrfs-progs-v6.9.2.tar.sign 566 BLAKE2B 4cd95496d355444c7d3e582a7e6c05fbb55683008b1585a26f38aef6cceb1afd5e80c9611518d6bd92dc1167798d4012c4bcab2f9bda752c459d94cfa6f3c477 SHA512 3fb04e1894e231abde388a39d2f0c90f43c1a1494622c2158fab9b94bb340e064404bcf96e24d913c60aaf5e06ade42fbb91a479949109b329682bb089f66bf2
 DIST btrfs-progs-v6.9.2.tar.xz 2661684 BLAKE2B 38ab189ac8271ba8d68b74e82569159c671cca1cb946f56ccab28b6b206cb6ee5b330d83afc3536b7e0d7399da3fb01e368809c1ef4a64b843ea88796ebd28bd SHA512 1df9d5456d07a035c38c17795996a4fc621eeaa244ef54383d4387205826d2a6e971910e55031d20bb1baf23193efa7439e110312ffd8471f07aaf8c0baca20a

diff --git a/dev-python/btrfsutil/btrfsutil-6.11.ebuild b/dev-python/btrfsutil/btrfsutil-6.11.ebuild
new file mode 100644
index 000000000000..cfecacd0b135
--- /dev/null
+++ b/dev-python/btrfsutil/btrfsutil-6.11.ebuild
@@ -0,0 +1,46 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/dsterba.asc
+
+inherit distutils-r1 verify-sig
+
+DESCRIPTION="Library for managing Btrfs filesystems"
+HOMEPAGE="https://github.com/kdave/btrfs-progs"
+
+MY_PN="btrfs-progs"
+MY_PV="v${PV/_/-}"
+MY_P="${MY_PN}-${MY_PV}"
+SRC_URI="
+	https://mirrors.edge.kernel.org/pub/linux/kernel/people/kdave/${MY_PN}/${MY_P}.tar.xz
+	verify-sig? ( https://mirrors.edge.kernel.org/pub/linux/kernel/people/kdave/${MY_PN}/${MY_P}.tar.sign )
+"
+S="${WORKDIR}/${MY_P}/libbtrfsutil/python"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+DEPEND="~sys-fs/btrfs-progs-${PV}"
+RDEPEND="${DEPEND}"
+
+distutils_enable_tests unittest
+
+RDEPEND+=" !sys-fs/btrfs-progs[python(-)]"
+
+src_unpack() {
+	# Upstream sign the decompressed .tar
+	if use verify-sig; then
+		einfo "Unpacking ${MY_P}.tar.xz ..."
+		verify-sig_verify_detached - "${DISTDIR}"/${MY_P}.tar.sign \
+			< <(xz -cd "${DISTDIR}"/${MY_P}.tar.xz | tee >(tar -x))
+		assert "Unpack failed"
+	else
+		default
+	fi
+}


^ permalink raw reply related	[flat|nested] 9+ messages in thread
end of thread, other threads:[~2024-09-17 16:45 UTC | newest]

Thread overview: 9+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2024-07-08 11:57 [gentoo-commits] repo/gentoo:master commit in: dev-python/btrfsutil/ Sam James
  -- strict thread matches above, loose matches on Subject: below --
2024-09-17 16:45 Sam James
2024-09-02  3:17 Sam James
2024-08-15 18:09 Sam James
2024-07-08 11:57 Sam James
2024-06-20 10:24 Sam James
2024-06-20  2:12 Mike Gilbert
2024-06-20  1:49 Mike Gilbert
2024-06-20  1:47 Mike Gilbert

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox