[gentoo-commits] repo/gentoo:master commit in: dev-libs/castxml/

["Thomas Beierlein" <tomjbe@gentoo.org>]

commit:     b7a68764b543b85e211500ec17699713adfac5a3
Author:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
AuthorDate: Thu Jul  4 14:29:17 2024 +0000
Commit:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
CommitDate: Thu Jul  4 14:29:17 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b7a68764

dev-libs/castxml: add 0.6.7

Signed-off-by: Thomas Beierlein <tomjbe <AT> gentoo.org>

 dev-libs/castxml/Manifest             |  1 +
 dev-libs/castxml/castxml-0.6.7.ebuild | 62 +++++++++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/dev-libs/castxml/Manifest b/dev-libs/castxml/Manifest
index 81f027076901..862260348ec5 100644
--- a/dev-libs/castxml/Manifest
+++ b/dev-libs/castxml/Manifest
@@ -1 +1,2 @@
 DIST CastXML-0.6.6.tar.gz 122349 BLAKE2B ab2d928386e3128cd05fcc60c02799508e671883cffd33f952eb81167672e4c76057be21d3ba6b3f327051b015894914c83ad66b5ce87e43fa1b251dea5c5371 SHA512 6ba62b91193eb3458cbd0a0838a626528f66972661cc33c6ef87b760f8baa985afe998a467d07fd7d28c1363f5ba74300f5d49c182830d217a4e051a97a4a913
+DIST CastXML-0.6.7.tar.gz 122608 BLAKE2B 04d10c34131fac97382fe33b1cfd8e65d62ce1339cb8eb253d867500f777346f352dfb9ff061c8e18be961ea9b7aeb86aef1d9c35d8f7e78687124e560bef435 SHA512 31acd05e15e44f64a92c47bbef13115d26e17488a111e5b2bb32bf6191c4555e8f7e380489ab9d6e52060285e25088f41253ba46f4eb95b6ec11e5c63412442f

diff --git a/dev-libs/castxml/castxml-0.6.7.ebuild b/dev-libs/castxml/castxml-0.6.7.ebuild
new file mode 100644
index 000000000000..894410252a94
--- /dev/null
+++ b/dev-libs/castxml/castxml-0.6.7.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LLVM_COMPAT=( {17..19} )
+
+inherit cmake llvm-r1
+
+MY_P=CastXML-${PV}
+DESCRIPTION="C-family abstract syntax tree XML output tool"
+HOMEPAGE="https://github.com/CastXML/CastXML"
+SRC_URI="
+	https://github.com/CastXML/CastXML/archive/v${PV}.tar.gz
+		-> ${MY_P}.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~riscv ~x86"
+IUSE="+man test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	$(llvm_gen_dep '
+		sys-devel/clang:${LLVM_SLOT}=
+	')
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	man? ( dev-python/sphinx )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCastXML_INSTALL_DOC_DIR="share/doc/${PF}"
+		-DCastXML_INSTALL_MAN_DIR="share/man"
+		-DSPHINX_MAN="$(usex man)"
+		-DSPHINX_HTML=OFF
+		-DBUILD_TESTING="$(usex test)"
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	local CMAKE_SKIP_TESTS=(
+		# Regex doesn't match the full build path
+		cmd.input-missing
+		cmd.rsp-missing
+
+		# Gets confused by extra #defines we set for hardening etc (bug #891813)
+		cmd.cc-gnu-src-cxx-E
+		cmd.cc-gnu-src-cxx-cmd
+		cmd.cc-gnu-c-src-c-E
+		cmd.cc-gnu-c-src-c-cmd
+	)
+
+	cmake_src_test
+}