[gentoo-commits] repo/gentoo:master commit in: app-i18n/ibus-table/

["Akinori Hattori" <hattya@gentoo.org>]

commit:     1f455955eaee0409f431439ffa46480ad07b9b0d
Author:     Akinori Hattori <hattya <AT> gentoo <DOT> org>
AuthorDate: Fri Jun 28 12:23:34 2024 +0000
Commit:     Akinori Hattori <hattya <AT> gentoo <DOT> org>
CommitDate: Fri Jun 28 12:28:57 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1f455955

app-i18n/ibus-table: new upstream release

Signed-off-by: Akinori Hattori <hattya <AT> gentoo.org>

 app-i18n/ibus-table/Manifest                 |  1 +
 app-i18n/ibus-table/ibus-table-1.17.6.ebuild | 55 ++++++++++++++++++++++++++++
 2 files changed, 56 insertions(+)

diff --git a/app-i18n/ibus-table/Manifest b/app-i18n/ibus-table/Manifest
index 3bccb11c2448..629bc9f583ad 100644
--- a/app-i18n/ibus-table/Manifest
+++ b/app-i18n/ibus-table/Manifest
@@ -1 +1,2 @@
 DIST ibus-table-1.17.4.tar.gz 1559267 BLAKE2B c3c48dcebc345e658a2e6a10b13f1a0312c2e906de0bd78ee0fcbe97379663b21c6f0dbe45d029343faea340f2d031937c6f41c2a113009b60e75d108b884244 SHA512 fde595635cf50e40657b394f61173360cd9f67aa212459f14d96e08805deb164931dddd564201653a85a2973b2e6429bd2683af96974c7cee5dae3067833efd3
+DIST ibus-table-1.17.6.tar.gz 1563218 BLAKE2B 45ad1f8f489f8df0ca1108df9fda910d0f144c10cff29d047f0e345efd1be9e5a6d6cd2b47ba59904769ba3f0c207d2d641c9e7299b0d1ca4b77ff59bffb5d4c SHA512 0c3f23595bf1ecc2c3e34962fca3e2317771ba0837c1a04fbcbaae089196994764307184dd482f0a9efcae2106e013ca51cf9530bd1c7cfb29070f54b16a276e

diff --git a/app-i18n/ibus-table/ibus-table-1.17.6.ebuild b/app-i18n/ibus-table/ibus-table-1.17.6.ebuild
new file mode 100644
index 000000000000..4ecd082cf0d0
--- /dev/null
+++ b/app-i18n/ibus-table/ibus-table-1.17.6.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE="sqlite(+)"
+
+inherit gnome2-utils python-single-r1 xdg
+
+DESCRIPTION="Tables engines for IBus"
+HOMEPAGE="https://github.com/ibus/ibus/wiki"
+SRC_URI="https://github.com/kaio/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls"
+RESTRICT="test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		app-i18n/ibus[python(+),${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+	virtual/libiconv
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	python_fix_shebang .
+
+	default
+}
+
+src_configure() {
+	econf $(use_enable nls)
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}