[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-commander/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     ea2c8f79c5836820ccd587ac25abc2b0f13d6237
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Thu May 16 23:13:17 2024 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Fri Jun 28 08:23:13 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ea2c8f79

gnome-extra/gnome-commander: Bump to 1.16.2

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/36709
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 gnome-extra/gnome-commander/Manifest               |  1 +
 .../gnome-commander/gnome-commander-1.16.2.ebuild  | 61 ++++++++++++++++++++++
 2 files changed, 62 insertions(+)

diff --git a/gnome-extra/gnome-commander/Manifest b/gnome-extra/gnome-commander/Manifest
index e51d765e6ae5..6d9da48a61de 100644
--- a/gnome-extra/gnome-commander/Manifest
+++ b/gnome-extra/gnome-commander/Manifest
@@ -1 +1,2 @@
 DIST gnome-commander-1.16.1.tar.xz 6240500 BLAKE2B c24b9647f19faa55479e88b11524bc88a1720feffe9a4de638bebbd54aea17a6975d8319eb52281bbc6006907294d86c1f1874eb252a51f9fe5075748f84d24c SHA512 3a42671350e071552f82e44cf09e7598c9851a8d0b47cedc059a23347e8da71e1cc140f16191b31b1e66b74d803240db63a0eb8ba6a189dfc64315783fb954e0
+DIST gnome-commander-1.16.2.tar.xz 6239476 BLAKE2B 56f44428b89ef765bfb976dc3e8084da34844e0056e96afbdaf073265aaf4f87b86c4c2a93fcefe4d07b9fae2be3d72ffa49684dfb0613ee98373d4fac6ef42f SHA512 da2675a6625a67ab873d49f1caf939c30a317ecc0cb9b15c794b27c4a46dfba4cdea10266b380ef1e6809329ee770db4d7559a9cf94b575340b7fe4bb997d6c2

diff --git a/gnome-extra/gnome-commander/gnome-commander-1.16.2.ebuild b/gnome-extra/gnome-commander/gnome-commander-1.16.2.ebuild
new file mode 100644
index 000000000000..60ecfc3c6756
--- /dev/null
+++ b/gnome-extra/gnome-commander/gnome-commander-1.16.2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2 meson optfeature
+
+DESCRIPTION="A graphical, full featured, twin-panel file manager"
+HOMEPAGE="https://gcmd.github.io/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc exif gsf pdf samba taglib test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	doc? ( gnome-extra/yelp )
+	>=dev-libs/glib-2.70.0:2
+	>=x11-libs/gtk+-2.24.0:2
+	exif? ( >=media-gfx/exiv2-0.14:= )
+	gsf? ( >=gnome-extra/libgsf-1.12:= )
+	pdf? ( >=app-text/poppler-0.18:= )
+	samba? ( gnome-base/gvfs[samba] )
+	taglib? ( >=media-libs/taglib-1.4 )
+"
+BDEPEND="
+	doc? ( app-text/yelp-tools )
+	dev-util/glib-utils
+	dev-build/gtk-doc-am
+	app-alternatives/lex
+	>=sys-devel/gettext-0.19.7
+	virtual/pkgconfig
+"
+DEPEND="
+	${RDEPEND}
+	test? ( >=dev-cpp/gtest-1.7.0 )
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature exif exiv2)
+		$(meson_feature gsf libgsf)
+		$(meson_feature pdf poppler)
+		$(meson_feature samba)
+		$(meson_feature taglib)
+		$(meson_feature test tests)
+		$(meson_use doc help)
+		-Dunique=disabled
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	optfeature "synchronizing files and directories" dev-util/meld
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+}