[gentoo-commits] repo/gentoo:master commit in: dev-python/twine/

["Michał Górny" <mgorny@gentoo.org>]

commit:     45de29a5d8620d0b2ce702a5646ea3444eaa3e74
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 27 12:30:03 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Jun 27 12:40:13 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=45de29a5

dev-python/twine: Bump to 5.1.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/twine/Manifest           |  1 +
 dev-python/twine/twine-5.1.1.ebuild | 80 +++++++++++++++++++++++++++++++++++++
 2 files changed, 81 insertions(+)

diff --git a/dev-python/twine/Manifest b/dev-python/twine/Manifest
index e056de4bfba7..02bc795a109d 100644
--- a/dev-python/twine/Manifest
+++ b/dev-python/twine/Manifest
@@ -1 +1,2 @@
 DIST twine-5.1.0.gh.tar.gz 221527 BLAKE2B 45b707883e84ade7cad8bee712e7b68f24eb8ccfd018de5c0522cf98cb66895e6a4324f17e54fa87dacdf97ee092a0fdbc0b5289b30871da36828c987c518c2f SHA512 41a5b94b6929a0a018cd15dd4ede45a361420752235e9b1a8b16979609e6a056bf46cd88efa869c27fa9bae3907f4e45d0c468de8058c3f82f15b48b4274b4cd
+DIST twine-5.1.1.gh.tar.gz 221931 BLAKE2B a95d50e52bde5db64c6ce5b57097188e9cb88763c91f337c3e552ca34bae34882d87bced4b0c55a292de185fce10384edf514b55373c4456ff252471076bcb28 SHA512 95f059235e32134a5320c0835befa2eed6eff35c56685afe4848224042c2e2af484db72f20fd0cfbe979cce8d495e8bb2d2ea38aca2c53ca7af8de378816bedf

diff --git a/dev-python/twine/twine-5.1.1.ebuild b/dev-python/twine/twine-5.1.1.ebuild
new file mode 100644
index 000000000000..764cc9a11109
--- /dev/null
+++ b/dev-python/twine/twine-5.1.1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Collection of utilities for publishing packages on PyPI"
+HOMEPAGE="
+	https://twine.readthedocs.io/
+	https://github.com/pypa/twine/
+	https://pypi.org/project/twine/
+"
+SRC_URI="
+	https://github.com/pypa/twine/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/colorama-0.4.3[${PYTHON_USEDEP}]
+	>=dev-python/importlib-metadata-3.6[${PYTHON_USEDEP}]
+	>=dev-python/keyring-15.1[${PYTHON_USEDEP}]
+	>=dev-python/pkginfo-1.8.1[${PYTHON_USEDEP}]
+	>=dev-python/readme-renderer-35.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.20.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-toolbelt-0.8.0[${PYTHON_USEDEP}]
+	>=dev-python/rfc3986-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/rich-12.0.0[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.26.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		dev-python/jaraco-envs[${PYTHON_USEDEP}]
+		dev-python/jaraco-functools[${PYTHON_USEDEP}]
+		dev-python/munch[${PYTHON_USEDEP}]
+		dev-python/portend[${PYTHON_USEDEP}]
+		dev-python/pretend[${PYTHON_USEDEP}]
+		dev-python/pypiserver[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# pytest-socket dep relevant only to test_integration, and upstream
+	# disables it anyway
+	sed -i -e '/--disable-socket/d' pytest.ini || die
+	sed -i -e '/--cov/d' pytest.ini || die
+
+	distutils-r1_python_prepare_all
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# Internet
+		tests/test_integration.py
+	)
+	local EPYTEST_DESELECT=(
+		# Regression due to deps?
+		tests/test_check.py::test_fails_rst_no_content
+		# Avoid needing heavy virtualx
+		tests/test_auth.py::test_warns_for_empty_password
+		# https://github.com/pypa/twine/issues/1116
+		'tests/test_package.py::test_pkginfo_returns_no_metadata[unsupported Metadata-Version]'
+	)
+
+	local -x COLUMNS=80
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}