[gentoo-commits] repo/proj/guru:master commit in: app-text/komikku/

["David Roman" <davidroman96@gmail.com>]

commit:     f81fefb5b435a2a144912a4082c62e19644e55b0
Author:     Takuya Wakazono <pastalian46 <AT> gmail <DOT> com>
AuthorDate: Wed Jun 26 12:32:42 2024 +0000
Commit:     David Roman <davidroman96 <AT> gmail <DOT> com>
CommitDate: Wed Jun 26 12:40:35 2024 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=f81fefb5

app-text/komikku: add 1.49.0

Signed-off-by: Takuya Wakazono <pastalian46 <AT> gmail.com>

 app-text/komikku/Manifest              |  1 +
 app-text/komikku/komikku-1.49.0.ebuild | 94 ++++++++++++++++++++++++++++++++++
 2 files changed, 95 insertions(+)

diff --git a/app-text/komikku/Manifest b/app-text/komikku/Manifest
index 65dc4dd5e..1be19737f 100644
--- a/app-text/komikku/Manifest
+++ b/app-text/komikku/Manifest
@@ -1 +1,2 @@
 DIST komikku-1.48.1.tar.gz 4913987 BLAKE2B db1126a89dc93b011208153df171c1eedf8f44b1dffff455e8d0343153d88fde12a7612896389cfdbc1b61eae3c3bd09a1df86ea5de8747752a196f6a234f338 SHA512 be4731e9b3da2699f12eb39a35ff5b54cf39c55a91b68c72db6d9800129635408dff369bd2c76c8c9372ff6266d3101b43aa15880999887524db12d3df17733c
+DIST komikku-1.49.0.tar.gz 4922860 BLAKE2B 708f6c57e5023a949d0d225f0370ec477cdd8430f5cd59d309ea3619875cc4b441c065fe33823771223ce099a68f5764d27eaf6a3ab287bf818428a86678a9b6 SHA512 aef5cc7ffb7b165bc7af90fefb6029e75cde348c684862454478fce41c2bcd2308bfbe0d1455bd011011a7cdf3805aacee7a297701c6ab0931c2b5620a454df2

diff --git a/app-text/komikku/komikku-1.49.0.ebuild b/app-text/komikku/komikku-1.49.0.ebuild
new file mode 100644
index 000000000..7af66f6f1
--- /dev/null
+++ b/app-text/komikku/komikku-1.49.0.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE="sqlite(+),ssl(+)"
+DISTUTILS_USE_PEP517=no
+DISTUTILS_SINGLE_IMPL=1
+inherit distutils-r1 meson gnome2-utils xdg
+
+DESCRIPTION="Manga reader for GNOME"
+HOMEPAGE="https://apps.gnome.org/Komikku/"
+SRC_URI="https://codeberg.org/valos/Komikku/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+
+RESTRICT="test"
+# Depend on a random server that may or may not be accessible.
+#PROPERTIES="test_network"
+
+DEPEND="
+	dev-libs/glib:2
+	dev-libs/gobject-introspection
+	>=gui-libs/gtk-4.12:4
+	>=gui-libs/libadwaita-1.5:1[introspection]
+	net-libs/webkit-gtk:6[introspection]
+"
+RDEPEND="
+	${DEPEND}
+	x11-libs/libnotify[introspection]
+	$(python_gen_cond_dep '
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/colorthief[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/dateparser[${PYTHON_USEDEP}]
+		dev-python/emoji[${PYTHON_USEDEP}]
+		dev-python/keyring[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/natsort[${PYTHON_USEDEP}]
+		dev-python/piexif[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pillow-heif[${PYTHON_USEDEP}]
+		dev-python/pygobject[${PYTHON_USEDEP}]
+		dev-python/python-magic[${PYTHON_USEDEP}]
+		dev-python/rarfile[compressed,${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/unidecode[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	dev-util/blueprint-compiler
+	sys-devel/gettext
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pytest-steps[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# fix broken shebang
+	sed "s|py_installation.full_path()|'${PYTHON}'|" -i bin/meson.build || die
+}
+
+src_test() {
+	emake setup
+	emake develop
+	emake test
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}