[gentoo-commits] repo/gentoo:master commit in: app-misc/fastfetch/

["Viorel Munteanu" <ceamac@gentoo.org>]

commit:     8fbb21ff6954db8cb4edc33e5a7b96ff40997fb2
Author:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 20 14:35:47 2024 +0000
Commit:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
CommitDate: Thu Jun 20 16:44:34 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8fbb21ff

app-misc/fastfetch: add 2.16.0

Signed-off-by: Viorel Munteanu <ceamac <AT> gentoo.org>

 app-misc/fastfetch/Manifest                |   1 +
 app-misc/fastfetch/fastfetch-2.16.0.ebuild | 111 +++++++++++++++++++++++++++++
 2 files changed, 112 insertions(+)

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index 6c32fd326897..14e344305507 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -2,3 +2,4 @@ DIST fastfetch-2.11.5.tar.gz 1321195 BLAKE2B 1e7fa7c92275ae8d3458ead537003fe4859
 DIST fastfetch-2.13.2.tar.gz 1254865 BLAKE2B 87d9c286f578d4929c0d50ce075d9ee04e53a5f05004ad8df2db73da84dd2079eb33fad650fb25cc18bd78c26008c8eea20c0ca515914371eec888d2a14bd753 SHA512 b9cfe2e333e234490f0143732419f596a42ee6ab80c316b23440adfa1fd5f05f194d4e5d2a9828c926e85f6a89781702d24ed4d0ac1b58c207dfd40c8095cf15
 DIST fastfetch-2.14.0.tar.gz 1083381 BLAKE2B bce9e8633d43ca50f1b35fa96a11c8d2cbdf68ebace97cae37b4285f05ae0325d394682ac32bb8b5eb7141c82b865f25188def48685601da7385e83676cafc97 SHA512 0d7fb6003d6e3178725a05f6efebc32218d07d7b8c79b0d981b3317d57464202e7d1f379684dc78ae0fc6b003cfd95c4fee3efa5d8b89ec6ef2e6236a3e9f7b5
 DIST fastfetch-2.15.0.tar.gz 1031800 BLAKE2B df41750c2281fb46c594004156b886d05863da7d7310ce21764fa3beb742f8c40bbec59464b947622682288ea16ca67626403ce42e792b6b1e6227d547deac98 SHA512 c2934432d23610e34d10cb66b13b0652619bdcb203dbc439fcd5e59a6a7814045ea90bf4d5dae12247f19e222a350cafee1184300845817d03ce6b0bcd947d2d
+DIST fastfetch-2.16.0.tar.gz 1044675 BLAKE2B 2c22fedef43155c71b3b0d4f590128699dc4d3f44211187f079e62baad338322bea60796bce8f6f23c1221174e1312d67c113b0ae3557a856b550756baebc077 SHA512 3a09e48775946876c69dfa8a739a090a18aa4598f455f6860d41962efeac2064127bf2a31d3a62ccc285682d12548402cf812eae01d56bc068b7855b0f00d4a7

diff --git a/app-misc/fastfetch/fastfetch-2.16.0.ebuild b/app-misc/fastfetch/fastfetch-2.16.0.ebuild
new file mode 100644
index 000000000000..b7b4acebe69c
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-2.16.0.ebuild
@@ -0,0 +1,111 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Fast neofetch-like system information tool"
+HOMEPAGE="https://github.com/fastfetch-cli/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/fastfetch-cli/fastfetch.git"
+	[[ ${PV} == *0.1.9999 ]] && EGIT_BRANCH=master
+	[[ ${PV} == *0.2.9999 ]] && EGIT_BRANCH=dev
+	[[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
+else
+	SRC_URI="https://github.com/fastfetch-cli/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+LICENSE="MIT nvidia-gpu? ( NVIDIA-NVLM )"
+SLOT="0"
+IUSE="X chafa dbus ddcutil drm gnome imagemagick networkmanager nvidia-gpu opencl opengl osmesa pulseaudio sqlite test vulkan wayland xcb xfce xrandr"
+RESTRICT="!test? ( test )"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+# make sure to crank yyjson minimum version to match bundled version
+RDEPEND="
+	>=dev-libs/yyjson-0.9.0
+	sys-libs/zlib
+	X? ( x11-libs/libX11 )
+	chafa? ( media-gfx/chafa )
+	dbus? ( sys-apps/dbus )
+	ddcutil? ( app-misc/ddcutil:= )
+	drm? ( x11-libs/libdrm )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	networkmanager? ( net-misc/networkmanager )
+	opencl? ( virtual/opencl )
+	opengl? ( media-libs/libglvnd[X] )
+	osmesa? ( media-libs/mesa[osmesa] )
+	pulseaudio? ( media-libs/libpulse )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? (
+		media-libs/vulkan-loader
+		sys-apps/pciutils
+	)
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="
+	${RDEPEND}
+	vulkan? ( dev-util/vulkan-headers )
+"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	xrandr? ( X )
+	chafa? ( imagemagick )
+"
+
+src_configure() {
+	local fastfetch_enable_imagemagick7=no
+	local fastfetch_enable_imagemagick6=no
+	if use imagemagick; then
+		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	fi
+
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_ZLIB=yes
+		-DENABLE_SYSTEM_YYJSON=yes
+		-DIS_MUSL=$(usex elibc_musl)
+		-DINSTALL_LICENSE=no
+
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_DDCUTIL=$(usex ddcutil)
+		-DENABLE_DRM=$(usex drm)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_GLX=$(usex opengl)
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_LIBNM=$(usex networkmanager)
+		-DENABLE_PROPRIETARY_GPU_DRIVER_API=$(usex nvidia-gpu)
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_OSMESA=$(usex osmesa)
+		-DENABLE_PULSE=$(usex pulseaudio)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_XCB=$(usex xcb)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DBUILD_TESTS=$(usex test)
+	)
+
+	append-cppflags -DNDEBUG
+
+	cmake_src_configure
+}