[gentoo-commits] repo/gentoo:master commit in: www-client/opera-developer/

["Matt Jolly" <kangie@gentoo.org>]

commit:     dd5c5686d4faa504f78399446a35be2fac39ad76
Author:     Matt Jolly <kangie <AT> gentoo <DOT> org>
AuthorDate: Wed Jun 19 07:42:58 2024 +0000
Commit:     Matt Jolly <kangie <AT> gentoo <DOT> org>
CommitDate: Wed Jun 19 09:35:57 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=dd5c5686

www-client/opera-developer: automated bump (112.0.5196.0)

Signed-off-by: Matt Jolly <kangie <AT> gentoo.org>

 www-client/opera-developer/Manifest                |   1 +
 .../opera-developer-112.0.5196.0.ebuild            | 173 +++++++++++++++++++++
 2 files changed, 174 insertions(+)

diff --git a/www-client/opera-developer/Manifest b/www-client/opera-developer/Manifest
index 601d866fad5f..93090710a8af 100644
--- a/www-client/opera-developer/Manifest
+++ b/www-client/opera-developer/Manifest
@@ -1,4 +1,5 @@
 DIST opera-developer_112.0.5179.0_amd64.deb 110489076 BLAKE2B 8904a78b8b91967524c633d79145de87c433d2e7a1b9e7758c91818bfcfbaa686086930e3272a20f40ab4313ed5e044204ab21671ec71cc5e425758cab816b9a SHA512 66a7742d30ae6c97315cd701881ff77c2f9c6f3325e6cbfede57a41196787f19fafadbf99dad0eec5559b1b9ab086a321289014d56f615b615267c6f32e60217
 DIST opera-developer_112.0.5186.0_amd64.deb 110440568 BLAKE2B 30dff5353c29bc1efd43137f0573ce32d8ad407b1c080b3c73fc1ed12349b53d6cc5c894f5b1f7b67b1a1309bb3e55450863745232b45a24ffcf9c533eb08edf SHA512 b9388896fcbd9dd26b6979ca263cbda14fb939179e2c6a197edf6ebc304138d816a96e084759a8d0c7ae945666bf23a67686d7bb280a533c0c7190bf77dcb790
 DIST opera-developer_112.0.5193.0_amd64.deb 110644548 BLAKE2B 79f5c078ecf6c150e2a42e3f4d8484bedb93ad590f523e97a7c1252835821a665d91d3f6df3b7c7dc356e650879089d1b9844e246ebf4bd05d0879ad83a9455c SHA512 42b7fcac19c08a1c9acb5a7dc226834de00d001d35dc70dc80722a076bb2d87e334b7bcdf5d2db3f6787c4ef777ad752c9ed6e8b9218ed4347a74bd4ce306c0e
+DIST opera-developer_112.0.5196.0_amd64.deb 111098252 BLAKE2B 6c61e6f202acb437afe8fab62866d7fbc08138d2b0a01d76f4f9314f171fd1c44cb3ff95e17890c0a4dcdae90250e6789a54b740c5fe0609725b39a509f03f9c SHA512 4286f35a3956322aca46965c8c6c9fc0efcb8e0f0e0890bd6d86859eb93c2cb047cd19572818760a07e5b1f456b702bc7e46d3246c3e877b031e6c4e4d0baad7
 DIST opera-developer_113.0.5201.0_amd64.deb 112140276 BLAKE2B e97d40a3541d7e1847ede364b33b0670b977b32db575b25019901bac80a61c79c205f09a81b99023ad3697ce3fcb31ddfb465a1c86a2260feee75d77cf88d758 SHA512 d6b37c5612d211c125cc955842ff4195646257dc824871df5531e041c9c3cb83106744a1c121d1a31fd276bc65dbb41b5ad85a6695f0750807de45754b07ea9b

diff --git a/www-client/opera-developer/opera-developer-112.0.5196.0.ebuild b/www-client/opera-developer/opera-developer-112.0.5196.0.ebuild
new file mode 100644
index 000000000000..0d49f3a56353
--- /dev/null
+++ b/www-client/opera-developer/opera-developer-112.0.5196.0.ebuild
@@ -0,0 +1,173 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CHROMIUM_LANGS="
+	bg bn ca cs da de el en-GB en-US es-419 es fil fi fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+
+# These are intended for ebuild maintainer use to force RPM if DEB is not available.
+: ${OPERA_FORCE_RPM=no}
+
+inherit chromium-2 pax-utils xdg
+
+if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+	inherit rpm
+	OPERA_ARCHIVE_EXT="rpm"
+else
+	inherit unpacker
+	OPERA_ARCHIVE_EXT="deb"
+fi
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+# Commit ref from `strings libffmpeg.so | grep -F "FFmpeg version"` matches this Chromium version
+# used to select the correct ffmpeg-chromium version (corresponds to a major version of Chromium)
+# Does not need to be updated for every new version of Opera, only when it breaks
+CHROMIUM_VERSION="125"
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}"
+S=${WORKDIR}
+
+LICENSE="OPERA-2018"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+IUSE="+ffmpeg-chromium +proprietary-codecs +suid qt5 qt6"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+	proprietary-codecs? (
+		!ffmpeg-chromium? ( >=media-video/ffmpeg-6.1-r1:0/58.60.60[chromium] )
+		ffmpeg-chromium? ( media-video/ffmpeg-chromium:${CHROMIUM_VERSION} )
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5[X]
+		dev-qt/qtwidgets:5
+	)
+	qt6? ( dev-qt/qtbase:6[gui,widgets] )
+"
+
+QA_PREBUILT="*"
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rpm_src_unpack "${A[0]}"
+	else
+		unpacker
+	fi
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
+	else
+		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	fi
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rm "${OPERA_HOME}/setup_repo.sh" || die
+	else
+		rm -r "usr/share/lintian" || die
+
+		# fix docs
+		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+		gzip -d usr/share/doc/${PF}/changelog.gz || die
+	fi
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		dosym ../../usr/$(get_libdir)/chromium/libffmpeg.so$(usex ffmpeg-chromium .${CHROMIUM_VERSION} "") \
+			  /${OPERA_HOME}/libffmpeg.so
+	fi
+
+	if ! use qt5; then
+		rm "${OPERA_HOME}/libqt5_shim.so" || die
+	fi
+	if ! use qt6; then
+		rm "${OPERA_HOME}/libqt6_shim.so" || die
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "/${OPERA_HOME}/opera_sandbox"
+}