[gentoo-commits] repo/gentoo:master commit in: sys-fs/unionfs-fuse/

["Sebastian Pipping" <sping@gentoo.org>]

commit:     a96939901a7a40effb608fa26cc687d4e5caedf5
Author:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Mon Jun 17 23:07:02 2024 +0000
Commit:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Mon Jun 17 23:07:02 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a9693990

sys-fs/unionfs-fuse: 3.5

Signed-off-by: Sebastian Pipping <sping <AT> gentoo.org>

 sys-fs/unionfs-fuse/Manifest                |  1 +
 sys-fs/unionfs-fuse/unionfs-fuse-3.5.ebuild | 48 +++++++++++++++++++++++++++++
 2 files changed, 49 insertions(+)

diff --git a/sys-fs/unionfs-fuse/Manifest b/sys-fs/unionfs-fuse/Manifest
index 9ae3bf58e1f9..5209b7595bf5 100644
--- a/sys-fs/unionfs-fuse/Manifest
+++ b/sys-fs/unionfs-fuse/Manifest
@@ -1 +1,2 @@
 DIST unionfs-fuse-3.4.tar.gz 54122 BLAKE2B 8d578a1bd88814acf5e2d437b06a5f400f38e61ea7c998fe38bb7ca536c9092f07872c4b4ccffc9db834eb8430f3e98c543a66920afab2b2371451c17c247d2c SHA512 fb719c8548ab1fa43f236d5c3207d7e8e7a7dc45efed453e447e29452a7c4d03483c84b00fd615bac115781b333c8171d811b87a0227172010a2ab34224150f7
+DIST unionfs-fuse-3.5.tar.gz 54906 BLAKE2B e9fb236fda184766affec0640127d5d2ba4c9f964e8882570f069f83fb8f35b551f3198dd4f252242287bb92a5ddea396f62975d1ecf5b9b002fe0a7fe9c85a8 SHA512 4f9d08a9ac7f374f15aa31bf2d8cc5e37b35f9a63bcbba50c6d805fb66ea019737b4aa2236b425317e638b6275659c4260ff8e1fecdee038079dc64797ab6013

diff --git a/sys-fs/unionfs-fuse/unionfs-fuse-3.5.ebuild b/sys-fs/unionfs-fuse/unionfs-fuse-3.5.ebuild
new file mode 100644
index 000000000000..70e1efca79a6
--- /dev/null
+++ b/sys-fs/unionfs-fuse/unionfs-fuse-3.5.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+
+PYTHON_COMPAT=( python3_{9..12} )
+inherit python-any-r1 toolchain-funcs
+
+DESCRIPTION="Self-syncing tree-merging file system based on FUSE"
+HOMEPAGE="https://github.com/rpodgorny/unionfs-fuse"
+SRC_URI="https://github.com/rpodgorny/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-linux"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-fs/fuse:3"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	test? (
+		$(python_gen_any_dep 'dev-python/pytest[${PYTHON_USEDEP}]')
+	)
+"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+python_check_deps() {
+	use test || return 0
+	python_has_version "dev-python/pytest[${PYTHON_USEDEP}]"
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)" CC="$(tc-getCC)"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
+}
+
+src_test() {
+	[[ -e /dev/fuse ]] || return 0
+	addwrite /dev/fuse
+	pytest -vv || die "Tests fail with ${EPYTHON}"
+}