[gentoo-commits] repo/gentoo:master commit in: dev-libs/gom/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     e555ccc2a4f8605dcba27bc0de98f8a19766a200
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Sun Jun 16 10:56:31 2024 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Sun Jun 16 10:57:10 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e555ccc2

dev-libs/gom: add 0.5.1

Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 dev-libs/gom/Manifest         |  1 +
 dev-libs/gom/gom-0.5.1.ebuild | 62 +++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/dev-libs/gom/Manifest b/dev-libs/gom/Manifest
index c60d37e387af..621eb28a30f5 100644
--- a/dev-libs/gom/Manifest
+++ b/dev-libs/gom/Manifest
@@ -1 +1,2 @@
 DIST gom-0.4.tar.xz 102744 BLAKE2B 8116ac388a56e85effbb37c3d5ea5036f6de2f4ad7ee8fe119bd058e1ac3e293eab612a739cdba7467202bc9e258f7cd65b1f116e146577d3a103fc03afba37f SHA512 d847928ce09c53a3f64777c313cb843052e5e001873f29d3f7acf02772cadf0e4b133fb0137aa0463b4ff95dd54810bde87062d8e396ff4fc6d142ba59c8e9c8
+DIST gom-0.5.1.tar.xz 106004 BLAKE2B 60cb744a77b4f7069430d27a88c6dce87cb5229758c637a49aa0ed05ff659099ba33923e5f576d797776b5af576beb57b0790633a1866f048279d5ae04e74f54 SHA512 6757a664f21cd8c1fb78b6446ed833e7290c9b91a39029363984049af840cd2685f43ebb184f7c966d9e395a1080454c182637fd64a1ff8b63272f4649db6a8a

diff --git a/dev-libs/gom/gom-0.5.1.ebuild b/dev-libs/gom/gom-0.5.1.ebuild
new file mode 100644
index 000000000000..57602b494bae
--- /dev/null
+++ b/dev-libs/gom/gom-0.5.1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+GCONF_DEBUG="yes"
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit gnome.org meson python-r1
+
+DESCRIPTION="GObject to SQLite object mapper library"
+HOMEPAGE="https://wiki.gnome.org/Projects/Gom"
+
+LICENSE="LGPL-2+ FDL-1.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="gtk-doc +introspection python test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="python? ( introspection ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	>=dev-db/sqlite-3.7:3
+	>=dev-libs/glib-2.38:2
+	introspection? ( >=dev-libs/gobject-introspection-1.30.0:= )
+	python? ( ${PYTHON_DEPS}
+		>=dev-python/pygobject-3.16:3[${PYTHON_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	gtk-doc? ( dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3 )
+	virtual/pkgconfig
+	test? ( x11-libs/gdk-pixbuf:2 )
+"
+
+src_prepare() {
+	default
+	sed -i -e '/subdir.*python/d' bindings/meson.build || die
+	# drop test building and deps if not enabled
+	if ! use test; then
+		sed -i -e '/gdkpixbuf_dep/d' meson.build || die
+		sed -i -e '/subdir(.*tests.*)/d' meson.build || die
+	fi
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use introspection enable-introspection)
+		$(meson_use gtk-doc enable-gtk-doc)
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	docinto examples
+	dodoc examples/*.py
+
+	meson_src_install
+
+	if use python; then
+		python_foreach_impl python_domodule bindings/python/gi
+	fi
+}