[gentoo-commits] repo/gentoo:master commit in: x11-themes/kvantum/

["Arthur Zamarin" <arthurzam@gentoo.org>]

commit:     017fbe970e9cf4b9091b638da29c23a5525e36a8
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 13 15:27:27 2024 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Thu Jun 13 15:50:41 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=017fbe97

x11-themes/kvantum: add 1.1.2

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 x11-themes/kvantum/Manifest             |  1 +
 x11-themes/kvantum/kvantum-1.1.2.ebuild | 80 +++++++++++++++++++++++++++++++++
 2 files changed, 81 insertions(+)

diff --git a/x11-themes/kvantum/Manifest b/x11-themes/kvantum/Manifest
index 89f1c29d0331..65e9aa9e1f2e 100644
--- a/x11-themes/kvantum/Manifest
+++ b/x11-themes/kvantum/Manifest
@@ -1 +1,2 @@
 DIST kvantum-1.0.10.tar.gz 2969117 BLAKE2B f2e9cc954a3a6cf4cac77d1e0b5a455faf95927cb78101113d99bf9a8e3d1875dff248909c1d95af028d5a369b517ad501e298e2c54fbd785d254afd7e30e465 SHA512 fb31f424a16c37eafaaa0a1cdddde165bcaa58ed6ea3ef76e77d689c2b8b47e516a651d066712eaf14b1344e4b30955ce6c955367caf25d51f2aaa2c8970b0fd
+DIST kvantum-1.1.2.tar.gz 3041246 BLAKE2B 7587adb7858fad2e4e3cf953fd4419d8a518d0e4b641afc426bc0c5417b91ff2d174af9c1e6d198d8eb979130f4704fb475bc0a84766957500e8913b6738706d SHA512 71c714df902ac4d7ac707e26842e2227eb7eeddad03af0bbd1ab1fcfa132204a9dd0453eafac3000cd3187dcb4ff03d64f01674c442f5a225e0c9b3652277f0e

diff --git a/x11-themes/kvantum/kvantum-1.1.2.ebuild b/x11-themes/kvantum/kvantum-1.1.2.ebuild
new file mode 100644
index 000000000000..e56f43d71527
--- /dev/null
+++ b/x11-themes/kvantum/kvantum-1.1.2.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# taken from Kvantum/style/CMakeLists.txt
+QT5MIN="5.15.0"
+QT6MIN="6.2.0"
+KF5MIN="5.82.0"
+
+inherit cmake multibuild xdg
+
+DESCRIPTION="SVG-based theme engine for Qt5, KDE Plasma and LXQt"
+HOMEPAGE="https://github.com/tsujan/Kvantum"
+SRC_URI="https://github.com/tsujan/${PN^}/archive/V${PV}.tar.gz -> ${P}.tar.gz"
+S=${WORKDIR}/${PN^}-${PV}/${PN^}
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="kde +qt5 qt6"
+REQUIRED_USE="|| ( qt5 qt6 ) kde? ( qt5 )"
+RESTRICT="test" # no tests
+
+RDEPEND="
+	x11-libs/libX11
+	qt5? (
+		>=dev-qt/qtcore-${QT5MIN}:5
+		>=dev-qt/qtgui-${QT5MIN}:5
+		>=dev-qt/qtsvg-${QT5MIN}:5
+		>=dev-qt/qtwidgets-${QT5MIN}:5
+		>=dev-qt/qtx11extras-${QT5MIN}:5
+		kde? ( >=kde-frameworks/kwindowsystem-${KF5MIN}:5 )
+	)
+	qt6? (
+		>=dev-qt/qtbase-${QT6MIN}:6[gui,widgets]
+		>=dev-qt/qtsvg-${QT6MIN}:6
+	)
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	qt5? ( dev-qt/linguist-tools:5 )
+	qt6? ( dev-qt/qttools:6[linguist] )
+"
+
+pkg_setup() {
+	MULTIBUILD_VARIANTS=( $(usev qt5) $(usev qt6) )
+}
+
+src_configure() {
+	my_src_configure() {
+		local mycmakeargs=(
+			-DENABLE_QT4=OFF
+		)
+		if [[ ${MULTIBUILD_VARIANT} = qt5 ]]; then
+			mycmakeargs+=(
+				-DENABLE_QT5=ON
+				-DWITHOUT_KF=$(usex !kde)
+			)
+		elif [[ ${MULTIBUILD_VARIANT} = qt6 ]]; then
+			mycmakeargs+=(
+				-DENABLE_QT5=OFF
+				-DWITHOUT_KF=ON
+			)
+		fi
+		cmake_src_configure
+	}
+
+	multibuild_foreach_variant my_src_configure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake_src_compile
+}
+
+src_install() {
+	multibuild_foreach_variant cmake_src_install
+}