[gentoo-commits] proj/kde:master commit in: kde-misc/kweather/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     723979b4d524cdb6bdaf3d1f31aa1c559e4e20b1
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Jun 11 16:04:56 2024 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Jun 11 19:33:08 2024 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=723979b4

kde-misc/kweather: 24.05.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-misc/kweather/kweather-24.05.1.ebuild | 52 +++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

diff --git a/kde-misc/kweather/kweather-24.05.1.ebuild b/kde-misc/kweather/kweather-24.05.1.ebuild
new file mode 100644
index 0000000000..864f5f7694
--- /dev/null
+++ b/kde-misc/kweather/kweather-24.05.1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_CATEGORY="utilities"
+ECM_TEST="false"
+KFMIN=6.3.0
+QTMIN=6.6.2
+inherit ecm gear.kde.org
+
+DESCRIPTION="Weather forecast application for Plasma with flat and dynamic/animated views"
+HOMEPAGE="https://apps.kde.org/kweather/"
+
+LICENSE="GPL-2+"
+SLOT="6"
+KEYWORDS="~amd64"
+
+DEPEND="
+	dev-libs/kirigami-addons:6
+	dev-libs/kweathercore:6
+	>=dev-qt/qtbase-${QTMIN}:6[gui,network,opengl,widgets]
+	>=dev-qt/qtcharts-${QTMIN}:6[qml]
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=dev-qt/qtsvg-${QTMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kholidays-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kirigami-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	kde-plasma/libplasma:6
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qt5compat-${QTMIN}:6[qml]
+	>=dev-qt/qtpositioning-${QTMIN}:6[geoclue]
+"
+
+src_prepare() {
+	ecm_src_prepare
+
+	sed -e "/include(ECMCheckOutboundLicense)/s/^/#DONT /" \
+		-e "/ecm_check_outbound_license/s/^/#DONT /" \
+		-i CMakeLists.txt || die # avoid cmake spam about python, reusetool
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_PLASMOID=ON
+	)
+	ecm_src_configure
+}