[gentoo-commits] repo/proj/guru:dev commit in: dev-vcs/jj/

["Steffen Winter" <stffn.mobil@freenet.de>]

commit:     c89b19b77677008771b524be9be4d6ee967d4203
Author:     Steffen Winter <steffen.winter <AT> proton <DOT> me>
AuthorDate: Mon Jun 10 18:10:48 2024 +0000
Commit:     Steffen Winter <stffn.mobil <AT> freenet <DOT> de>
CommitDate: Mon Jun 10 18:25:35 2024 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=c89b19b7

dev-vcs/jj: add 9999

Signed-off-by: Steffen Winter <steffen.winter <AT> proton.me>

 dev-vcs/jj/jj-9999.ebuild | 58 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

diff --git a/dev-vcs/jj/jj-9999.ebuild b/dev-vcs/jj/jj-9999.ebuild
new file mode 100644
index 000000000..4895d0b65
--- /dev/null
+++ b/dev-vcs/jj/jj-9999.ebuild
@@ -0,0 +1,58 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cargo
+
+DESCRIPTION="Jujutsu - an experimental version control system"
+HOMEPAGE="https://github.com/martinvonz/jj"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/martinvonz/jj.git"
+else
+	SRC_URI="
+		https://github.com/martinvonz/jj/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
+		${CARGO_CRATE_URIS}
+	"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="Apache-2.0"
+# Dependent crate licenses
+LICENSE+=" Apache-2.0 BSD MIT MPL-2.0 Unicode-DFS-2016"
+SLOT="0"
+
+BDEPEND="virtual/pkgconfig"
+DEPEND="
+	>=app-arch/zstd-1.5.5:=
+	>=dev-libs/libgit2-1.7.2:=
+	dev-libs/openssl
+	net-libs/libssh2:=
+	sys-libs/zlib
+"
+RDEPEND="${DEPEND}"
+
+QA_FLAGS_IGNORED="usr/bin/${PN}"
+
+pkg_setup() {
+	export LIBGIT2_NO_VENDOR=1
+	export LIBSSH2_SYS_USE_PKG_CONFIG=1
+	export OPENSSL_NO_VENDOR=1
+	export PKG_CONFIG_ALLOW_CROSS=1
+	export ZSTD_SYS_USE_PKG_CONFIG=1
+}
+
+src_unpack() {
+	if [[ ${PV} == 9999 ]]; then
+		git-r3_src_unpack
+		cargo_live_src_unpack
+	else
+		cargo_src_unpack
+	fi
+}
+
+src_install() {
+	cargo_src_install --path cli
+}