[gentoo-commits] repo/gentoo:master commit in: dev-python/pycxx/

["Sebastian Pipping" <sping@gentoo.org>]

commit:     fdf45f0baf27cfe02151a26a007e8cf72cba0b29
Author:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Sat Jun  8 19:42:44 2024 +0000
Commit:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Sat Jun  8 19:45:25 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fdf45f0b

dev-python/pycxx: Start using DISTUTILS_USE_PEP517

Closes: https://bugs.gentoo.org/909938
Signed-off-by: Sebastian Pipping <sping <AT> gentoo.org>

 dev-python/pycxx/pycxx-7.1.8-r1.ebuild | 52 ++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

diff --git a/dev-python/pycxx/pycxx-7.1.8-r1.ebuild b/dev-python/pycxx/pycxx-7.1.8-r1.ebuild
new file mode 100644
index 000000000000..937f1bf9eb40
--- /dev/null
+++ b/dev-python/pycxx/pycxx-7.1.8-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+
+PYTHON_COMPAT=( python3_{10..12} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+DESCRIPTION="Set of facilities to extend Python with C++"
+HOMEPAGE="https://cxx.sourceforge.net"
+SRC_URI="https://downloads.sourceforge.net/cxx/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="doc examples"
+
+BDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/setuptools[${PYTHON_USEDEP}]
+	' 3.12)
+"
+
+python_prepare_all() {
+	rm -R Src/Python2/ || die
+
+	# Without this, pysvn fails.
+	# Src/Python3/cxxextensions.c: No such file or directory
+	sed -e "/^#include/s:Src/::" -i Src/*.{c,cxx} || die "sed failed"
+
+	distutils-r1_python_prepare_all
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Move misplaced files into place
+	dodir "/usr/share/${EPYTHON}"
+	mv "${D}/usr/CXX" "${D}/usr/share/${EPYTHON}/CXX" || die
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( Doc/. )
+	if use examples ; then
+		docinto examples
+		dodoc -r Demo/Python3/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}