[gentoo-commits] repo/gentoo:master commit in: dev-python/tornado/

["Michał Górny" <mgorny@gentoo.org>]

commit:     b34a56db7869fed3864deea7417834b75ff715bc
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Jun  7 01:43:32 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Jun  7 01:55:45 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b34a56db

dev-python/tornado: Bump to 6.4.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/tornado/Manifest             |  1 +
 dev-python/tornado/tornado-6.4.1.ebuild | 61 +++++++++++++++++++++++++++++++++
 2 files changed, 62 insertions(+)

diff --git a/dev-python/tornado/Manifest b/dev-python/tornado/Manifest
index 17479fd3986d..1aa1c1dcecb0 100644
--- a/dev-python/tornado/Manifest
+++ b/dev-python/tornado/Manifest
@@ -1 +1,2 @@
+DIST tornado-6.4.1.tar.gz 500623 BLAKE2B e359d9cbf5e7311e608753a2908e61ea121e4d108209866fda49e79ecca3dc8495c35583406dd7d6b2852c4f6a9df2e340b1f4b892489be976d70000ed51aa33 SHA512 294b4fff8a6d1b9592d355f7faf78f1a94a2aaea1b54414b7e81884b8d4069713a28f6105ae36f27be78abf4c47a1fceab3801bc92b5429374f7a534f104c437
 DIST tornado-6.4.tar.gz 498845 BLAKE2B ebcdcfa93490107addfe69f722e2d85058a92fc366b09a4794a4d6e0a93040ef9791095a5a94d21937d4e88dea09521644cf92d0f2c7e98238dc58e6b864a009 SHA512 c063509d4c385e410c63cccdc1e9c66aa2bb739473667ede56cb801b7379b910c8059dec831d609109f3076222b588b257afd960dffa422d7a872867dcdda7c7

diff --git a/dev-python/tornado/tornado-6.4.1.ebuild b/dev-python/tornado/tornado-6.4.1.ebuild
new file mode 100644
index 000000000000..48e48fe9a958
--- /dev/null
+++ b/dev-python/tornado/tornado-6.4.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python web framework and asynchronous networking library"
+HOMEPAGE="
+	https://www.tornadoweb.org/
+	https://github.com/tornadoweb/tornado/
+	https://pypi.org/project/tornado/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~x64-macos"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		$(python_gen_cond_dep '
+			>=dev-python/pycurl-7.19.3.1[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-6.3.2-test-timeout-increase.patch"
+	"${FILESDIR}/${PN}-6.3.2-ignore-deprecationwarning.patch"
+)
+
+src_prepare() {
+	# network-sandbox? ipv6?
+	sed -i -e 's:test_localhost:_&:' \
+		tornado/test/netutil_test.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x ASYNC_TEST_TIMEOUT=60
+	# Avoid time-sensitive tests
+	# https://github.com/tornadoweb/tornado/blob/10974e6ebee80a26a2a65bb9bd715cf858fafde5/tornado/test/util.py#L19
+	local -x TRAVIS=1
+	local -x NO_NETWORK=1
+
+	cd "${T}" || die
+	"${EPYTHON}" -m tornado.test.runtests --verbose ||
+		die "tests failed under ${EPYTHON}"
+}