[gentoo-commits] repo/gentoo:master commit in: app-office/calcurse/

["Hanno Böck" <hanno@gentoo.org>]

commit:     8e8bf3dd9a3a075d39874934a5fe756649f3d26b
Author:     Hanno Böck <hanno <AT> gentoo <DOT> org>
AuthorDate: Thu Jun  6 19:55:13 2024 +0000
Commit:     Hanno Böck <hanno <AT> gentoo <DOT> org>
CommitDate: Thu Jun  6 19:55:13 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8e8bf3dd

app-office/calcurse: python 3.12 support

Also remove unused eclass inherit.

Closes: https://bugs.gentoo.org/929344
Signed-off-by: Hanno Böck <hanno <AT> gentoo.org>

 app-office/calcurse/calcurse-4.8.1-r1.ebuild | 56 ++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

diff --git a/app-office/calcurse/calcurse-4.8.1-r1.ebuild b/app-office/calcurse/calcurse-4.8.1-r1.ebuild
new file mode 100644
index 000000000000..0b35c3f066f2
--- /dev/null
+++ b/app-office/calcurse/calcurse-4.8.1-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit python-single-r1
+
+DESCRIPTION="A text-based calendar and scheduling application"
+HOMEPAGE="https://calcurse.org/"
+SRC_URI="https://calcurse.org/files/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+IUSE="caldav doc"
+
+RDEPEND="
+	sys-libs/ncurses:0=
+	sys-libs/timezone-data
+	${PYTHON_DEPS}
+	caldav? (
+		$(python_gen_cond_dep '
+			dev-python/httplib2[${PYTHON_USEDEP}]
+			dev-python/pyparsing[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+DEPEND="
+	${RDEPEND}
+"
+
+BDEPEND="virtual/pkgconfig"
+
+src_configure() {
+	local myconf=(
+		$(use_enable doc docs)
+		--without-asciidoc # do not use AsciiDoc to regenerate docs
+	)
+	ECONF_SOURCE="${S}" econf "${myconf[@]}"
+}
+
+src_compile() {
+	default
+	if use caldav; then
+		python_fix_shebang contrib/caldav/calcurse-caldav
+	fi
+}
+
+src_install() {
+	docompress -x /usr/share/doc # decompress text files
+	default
+}