[gentoo-commits] repo/gentoo:master commit in: www-client/opera-developer/

["Matt Jolly" <kangie@gentoo.org>]

commit:     08e70deba1a8573b7f3e4e7f55fe34bd0d420b7a
Author:     Matt Jolly <kangie <AT> gentoo <DOT> org>
AuthorDate: Thu Jun  6 04:19:56 2024 +0000
Commit:     Matt Jolly <kangie <AT> gentoo <DOT> org>
CommitDate: Thu Jun  6 15:17:58 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=08e70deb

www-client/opera-developer: automated bump (112.0.5179.0)

Signed-off-by: Matt Jolly <kangie <AT> gentoo.org>

 www-client/opera-developer/Manifest                |   1 +
 .../opera-developer-112.0.5179.0.ebuild            | 173 +++++++++++++++++++++
 2 files changed, 174 insertions(+)

diff --git a/www-client/opera-developer/Manifest b/www-client/opera-developer/Manifest
index 301e07bcce35..33ebc8093425 100644
--- a/www-client/opera-developer/Manifest
+++ b/www-client/opera-developer/Manifest
@@ -1,4 +1,5 @@
 DIST opera-developer_111.0.5159.0_amd64.deb 111427528 BLAKE2B 3142d6efd50ed145931ca2cfa0de85145f90c33671a7af54c4281d5872fea6f7fe09de0340473e0ee9ef9c2a464d85af2ecbcf1a9ee1a35cb25a608760ac0dd3 SHA512 40c0917016ec646a8f14442846495b5d3427d7593bfabde52f2579e744c2f043b9fdbb8e445fb05997fe2ce2f1d03c49151ebc7ccd875b5dd26ff2bad9e28f75
 DIST opera-developer_111.0.5167.0_amd64.deb 109894988 BLAKE2B 0c52050b6b9524e15ed9535119d0284e6778e5d4427bb5bb09b753a701e9e67ea9cd44c7be19f5bccc489b2eee636525e3aec3cd148939ea400ddb8c0fed77fd SHA512 1d17d22e0eda575960c8d44babe8136ce4499f5e83ae134a8de1b244099aa704a5d94e9af13fe6b84b8f365fac6f17da77dbd147cb49b81197fadac2e850a37e
 DIST opera-developer_112.0.5172.0_amd64.deb 110792748 BLAKE2B 4c23cc247b9fd4af98a677e10091c030375f3971b67092cf47ca82c8436de8bf41346fd2840c2d9fc7e5dd6eb3ef3151c9ad9431dc417c42275162c1b74760d0 SHA512 e938c040d9327f892d98e0d62e16580958945f0d13c0b2cdc078b3c21381b7123cc26716600d3d1fed54b2451ae8306c2e4bf079086bf063ad0c9cfe5332243c
+DIST opera-developer_112.0.5179.0_amd64.deb 110489076 BLAKE2B 8904a78b8b91967524c633d79145de87c433d2e7a1b9e7758c91818bfcfbaa686086930e3272a20f40ab4313ed5e044204ab21671ec71cc5e425758cab816b9a SHA512 66a7742d30ae6c97315cd701881ff77c2f9c6f3325e6cbfede57a41196787f19fafadbf99dad0eec5559b1b9ab086a321289014d56f615b615267c6f32e60217
 DIST opera-developer_112.0.5186.0_amd64.deb 110440568 BLAKE2B 30dff5353c29bc1efd43137f0573ce32d8ad407b1c080b3c73fc1ed12349b53d6cc5c894f5b1f7b67b1a1309bb3e55450863745232b45a24ffcf9c533eb08edf SHA512 b9388896fcbd9dd26b6979ca263cbda14fb939179e2c6a197edf6ebc304138d816a96e084759a8d0c7ae945666bf23a67686d7bb280a533c0c7190bf77dcb790

diff --git a/www-client/opera-developer/opera-developer-112.0.5179.0.ebuild b/www-client/opera-developer/opera-developer-112.0.5179.0.ebuild
new file mode 100644
index 000000000000..cfafbce68c18
--- /dev/null
+++ b/www-client/opera-developer/opera-developer-112.0.5179.0.ebuild
@@ -0,0 +1,173 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CHROMIUM_LANGS="
+	bg bn ca cs da de el en-GB en-US es-419 es fil fi fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+
+# These are intended for ebuild maintainer use to force RPM if DEB is not available.
+: ${OPERA_FORCE_RPM=no}
+
+inherit chromium-2 pax-utils xdg
+
+if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+	inherit rpm
+	OPERA_ARCHIVE_EXT="rpm"
+else
+	inherit unpacker
+	OPERA_ARCHIVE_EXT="deb"
+fi
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+# Commit ref from `strings libffmpeg.so | grep -F "FFmpeg version"` matches this Chromium version
+# used to select the correct ffmpeg-chromium version (corresponds to a major version of Chromium)
+# Does not need to be updated for every new version of Opera, only when it breaks
+CHROMIUM_VERSION="124"
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}"
+S=${WORKDIR}
+
+LICENSE="OPERA-2018"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+IUSE="+ffmpeg-chromium +proprietary-codecs +suid qt5 qt6"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+	proprietary-codecs? (
+		!ffmpeg-chromium? ( >=media-video/ffmpeg-6.1-r1:0/58.60.60[chromium] )
+		ffmpeg-chromium? ( media-video/ffmpeg-chromium:${CHROMIUM_VERSION} )
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5[X]
+		dev-qt/qtwidgets:5
+	)
+	qt6? ( dev-qt/qtbase:6[gui,widgets] )
+"
+
+QA_PREBUILT="*"
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rpm_src_unpack "${A[0]}"
+	else
+		unpacker
+	fi
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
+	else
+		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	fi
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rm "${OPERA_HOME}/setup_repo.sh" || die
+	else
+		rm -r "usr/share/lintian" || die
+
+		# fix docs
+		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+		gzip -d usr/share/doc/${PF}/changelog.gz || die
+	fi
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		dosym ../../usr/$(get_libdir)/chromium/libffmpeg.so$(usex ffmpeg-chromium .${CHROMIUM_VERSION} "") \
+			  /${OPERA_HOME}/libffmpeg.so
+	fi
+
+	if ! use qt5; then
+		rm "${OPERA_HOME}/libqt5_shim.so" || die
+	fi
+	if ! use qt6; then
+		rm "${OPERA_HOME}/libqt6_shim.so" || die
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "/${OPERA_HOME}/opera_sandbox"
+}