From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1639355-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (2048 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 8ECC315817D
for <garchives@archives.gentoo.org>; Thu, 6 Jun 2024 06:56:26 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 3DC172BC041;
Thu, 6 Jun 2024 06:56:25 +0000 (UTC)
Received: from smtp.gentoo.org (mail.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 231A32BC041
for <gentoo-commits@lists.gentoo.org>; Thu, 6 Jun 2024 06:56:25 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 4BAD833F9FD
for <gentoo-commits@lists.gentoo.org>; Thu, 6 Jun 2024 06:56:24 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 842391C80
for <gentoo-commits@lists.gentoo.org>; Thu, 6 Jun 2024 06:56:22 +0000 (UTC)
From: "Florian Schmaus" <flow@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Florian Schmaus" <flow@gentoo.org>
Message-ID: <1717656939.1e498e39056b81f18bf6792e4934df864d785949.flow@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: net-irc/weechat/
X-VCS-Repository: repo/gentoo
X-VCS-Files: net-irc/weechat/Manifest net-irc/weechat/weechat-4.3.1.ebuild
X-VCS-Directories: net-irc/weechat/
X-VCS-Committer: flow
X-VCS-Committer-Name: Florian Schmaus
X-VCS-Revision: 1e498e39056b81f18bf6792e4934df864d785949
X-VCS-Branch: master
Date: Thu, 6 Jun 2024 06:56:22 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: e3ecaafa-c779-41c7-8cfe-7f4c4cf80436
X-Archives-Hash: 0af2a23a02695112d5cd4ba400f3cb9e
commit: 1e498e39056b81f18bf6792e4934df864d785949
Author: Leonardo Hernández Hernández <leohdz172 <AT> proton <DOT> me>
AuthorDate: Mon Jun 3 19:24:08 2024 +0000
Commit: Florian Schmaus <flow <AT> gentoo <DOT> org>
CommitDate: Thu Jun 6 06:55:39 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1e498e39
net-irc/weechat: add 4.3.1
Signed-off-by: Leonardo Hernández Hernández <leohdz172 <AT> proton.me>
Signed-off-by: Florian Schmaus <flow <AT> gentoo.org>
net-irc/weechat/Manifest | 2 +
net-irc/weechat/weechat-4.3.1.ebuild | 190 +++++++++++++++++++++++++++++++++++
2 files changed, 192 insertions(+)
diff --git a/net-irc/weechat/Manifest b/net-irc/weechat/Manifest
index c25323f624cd..d8318684aab3 100644
--- a/net-irc/weechat/Manifest
+++ b/net-irc/weechat/Manifest
@@ -8,3 +8,5 @@ DIST weechat-4.1.3.tar.xz 2635936 BLAKE2B b810dc49f817f35b121037663e36dded1dd1f5
DIST weechat-4.1.3.tar.xz.asc 833 BLAKE2B 3db658a0323dedbe0cd1d057139d3fef216441538391ba36cb4b2763cb80bbd32ddd36f2a0f2330bdcd73722fdd73f02eff39da61a61bfda7a4fd8aaa1f98abb SHA512 054844c78dfeaa60e8a027e96aff994009c07b871b9fd712e3650a709c5bdf7ca1da8b4eb6251c82152153fc4e765f032760387b2a89840effd389d6532ea170
DIST weechat-4.2.1.tar.xz 2594044 BLAKE2B 336f5f1560a834601ac5a7e6924dfabcc85fdf00f1533f1c5d1d7f2cc627d2b3ca35819b16ed30328271699cf8c314fb33164a9353a7beebc591ae175107f290 SHA512 e9ed67cd45b374435b05043dd9f085d30f4b429dff1afa82fe5f50522283faa86b5e6909ec1f51af033a612abe5f52f4441433bcc94e59027fc5ccff86e84c62
DIST weechat-4.2.1.tar.xz.asc 833 BLAKE2B abd7e8299e748c228aac82cdfbe4591c75b94d4e213842444ae4332cec316d114b1262f2fcfe92245b236e012c27b942a26e1c018dce0cb0bc4bd0f34584308a SHA512 1f510ea85fd5eef667d738674182dcc78af42d0ea092a7df696f6210657c5d7f13bb631a332b87e1e127d1b40eac17603147fd05eeac363401b705e38fbaf3d5
+DIST weechat-4.3.1.tar.xz 2692548 BLAKE2B 5072bea7375802bfac1522ab97058f12705834525c27e7bf4f69d0ae3e51076755e622cb4cf121324e9bbab3da11b776127a26ea5a583803b613902f78c36d16 SHA512 e78fb37f983600340c88d63b5ba4e26febb18184c71da396daf8af6539a09c23656f6c8984d9ccb65cd5ec8fad099c4492111167870fbf9718088e7e9e5f556d
+DIST weechat-4.3.1.tar.xz.asc 833 BLAKE2B 1412d40e9f6950d6c8cfe51ea5ecd4423aa1e86d0aa522017d3af065c4aa64ed816c4bd8af701f1a8859c511b3b85377c22b7cf4f59a8ef2cfa44eb0abe0dada SHA512 358b41e4c27e1c32ed1c8c20fd4487c9445ea203cd76fb77c8a082baad38105c0e93a8aabb656680a0d429e76a26bb149f2f2b6a4eda4b8192f1520a9249458a
diff --git a/net-irc/weechat/weechat-4.3.1.ebuild b/net-irc/weechat/weechat-4.3.1.ebuild
new file mode 100644
index 000000000000..ae190a67def6
--- /dev/null
+++ b/net-irc/weechat/weechat-4.3.1.ebuild
@@ -0,0 +1,190 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-{1..4} )
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit cmake lua-single python-single-r1 xdg
+
+if [[ ${PV} == "9999" ]] ; then
+ inherit git-r3
+ EGIT_REPO_URI="https://github.com/weechat/weechat.git"
+else
+ inherit verify-sig
+ SRC_URI="https://weechat.org/files/src/${P}.tar.xz
+ verify-sig? ( https://weechat.org/files/src/${P}.tar.xz.asc )"
+ VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/weechat.org.asc
+ BDEPEND+="verify-sig? ( sec-keys/openpgp-keys-weechat )"
+ KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86 ~x64-macos"
+fi
+
+DESCRIPTION="Portable and multi-interface IRC client"
+HOMEPAGE="https://weechat.org/"
+
+LICENSE="GPL-3+"
+SLOT="0/${PV}"
+
+NETWORKS="+irc"
+PLUGINS="+alias +buflist +charset +exec +fifo +fset +logger +relay +scripts +spell +trigger +typing +xfer"
+# dev-lang/v8 was dropped from Gentoo so we can't enable javascript support
+# dev-lang/php eclass support is lacking, php plugins don't work. bug #705702
+SCRIPT_LANGS="guile lua +perl +python ruby tcl"
+LANGS=" cs de es fr it ja pl ru"
+IUSE="doc enchant man nls relay-api selinux test +zstd ${SCRIPT_LANGS} ${PLUGINS} ${INTERFACES} ${NETWORKS}"
+
+REQUIRED_USE="
+ enchant? ( spell )
+ lua? ( ${LUA_REQUIRED_USE} )
+ python? ( ${PYTHON_REQUIRED_USE} )
+ test? ( nls )
+ relay-api? ( relay )
+"
+
+RDEPEND="
+ dev-libs/libgcrypt:0=
+ net-libs/gnutls:=
+ sys-libs/ncurses:0=
+ sys-libs/zlib:=
+ net-misc/curl[ssl]
+ charset? ( virtual/libiconv )
+ guile? ( >=dev-scheme/guile-2.0:12= )
+ lua? ( ${LUA_DEPS} )
+ nls? ( virtual/libintl )
+ perl? (
+ dev-lang/perl:=
+ virtual/libcrypt:=
+ )
+ python? ( ${PYTHON_DEPS} )
+ ruby? (
+ || (
+ dev-lang/ruby:3.3
+ dev-lang/ruby:3.2
+ dev-lang/ruby:3.1
+ )
+ )
+ selinux? ( sec-policy/selinux-irc )
+ spell? (
+ enchant? ( app-text/enchant:* )
+ !enchant? ( app-text/aspell )
+ )
+ tcl? ( >=dev-lang/tcl-8.4.15:0= )
+ zstd? ( app-arch/zstd:= )
+"
+
+DEPEND="${RDEPEND}
+ test? ( dev-util/cpputest )
+"
+
+BDEPEND+="
+ virtual/pkgconfig
+ doc? ( >=dev-ruby/asciidoctor-1.5.4 )
+ man? ( >=dev-ruby/asciidoctor-1.5.4 )
+ nls? ( >=sys-devel/gettext-0.15 )
+"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-3.3-cmake_lua_version.patch
+)
+
+DOCS="AUTHORS.adoc ChangeLog.adoc Contributing.adoc ReleaseNotes.adoc README.adoc"
+
+RESTRICT="!test? ( test )"
+
+pkg_setup() {
+ use lua && lua-single_pkg_setup
+ use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ cmake_src_prepare
+
+ # install only required translations
+ local i
+ for i in ${LANGS} ; do
+ if ! has ${i} ${LINGUAS-${i}} ; then
+ sed -i \
+ -e "/${i}.po/d" \
+ po/CMakeLists.txt || die
+ fi
+ done
+
+ # install only required documentation ; en always
+ local j
+ for i in $(grep -e 'set(.*en.*)$' doc/CMakeLists.txt \
+ | sed -e 's/.*set(\(\w\+\).*/\1/'); do
+ for j in $(grep set.${i} doc/CMakeLists.txt \
+ | sed -e "s/.*${i}\(.*\)).*/\1/" -e 's/ en//'); do
+ if ! has ${j} ${LINGUAS-${j}} ; then
+ sed -i \
+ -e "s/\(set(${i}.*\) ${j}/\1/" \
+ doc/CMakeLists.txt || die
+ fi
+ done
+ done
+
+ # install docs in correct directory
+ sed -i "s#\${DATAROOTDIR}/doc/\${PROJECT_NAME}#\0-${PVR}/html#" doc/CMakeLists.txt || die
+
+ if [[ ${CHOST} == *-darwin* ]]; then
+ # fix linking error on Darwin
+ sed -i "s/+ get_config_var('LINKFORSHARED')//" \
+ cmake/FindPython.cmake || die
+ # allow to find the plugins by default
+ sed -i 's/".so,.dll"/".bundle,.so,.dll"/' \
+ src/core/wee-config.c || die
+ fi
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DLIBDIR="${EPREFIX}/usr/$(get_libdir)"
+ -DENABLE_JAVASCRIPT=OFF
+ -DENABLE_LARGEFILE=ON
+ -DENABLE_NCURSES=ON
+ -DENABLE_PHP=OFF
+ -DENABLE_ALIAS=$(usex alias)
+ -DENABLE_BUFLIST=$(usex buflist)
+ -DENABLE_CHARSET=$(usex charset)
+ # -DENABLE_DOC requires all plugins (except javascript).
+ # https://github.com/weechat/weechat/blob/v4.0.2/CMakeLists.txt#L144
+ # Impossible since php was dropped in net-irc/weechat-3.5.r1.ebuild. bug #705702
+ -DENABLE_DOC=OFF
+ -DENABLE_DOC_INCOMPLETE=$(usex doc)
+ -DENABLE_ENCHANT=$(usex enchant)
+ -DENABLE_EXEC=$(usex exec)
+ -DENABLE_FIFO=$(usex fifo)
+ -DENABLE_FSET=$(usex fset)
+ -DENABLE_GUILE=$(usex guile)
+ -DENABLE_IRC=$(usex irc)
+ -DENABLE_LOGGER=$(usex logger)
+ -DENABLE_LUA=$(usex lua)
+ -DENABLE_MAN=$(usex man)
+ -DENABLE_NLS=$(usex nls)
+ -DENABLE_PERL=$(usex perl)
+ -DENABLE_PYTHON=$(usex python)
+ -DENABLE_RELAY=$(usex relay)
+ -DENABLE_CJSON=$(usex relay-api)
+ -DENABLE_RUBY=$(usex ruby)
+ -DENABLE_SCRIPT=$(usex scripts)
+ -DENABLE_SCRIPTS=$(usex scripts)
+ -DENABLE_SPELL=$(usex spell)
+ -DENABLE_TCL=$(usex tcl)
+ -DENABLE_TESTS=$(usex test)
+ -DENABLE_TRIGGER=$(usex trigger)
+ -DENABLE_TYPING=$(usex typing)
+ -DENABLE_XFER=$(usex xfer)
+ -DENABLE_ZSTD=$(usex zstd)
+ )
+ cmake_src_configure
+}
+
+src_test() {
+ if $(locale -a | grep -iq "en_US\.utf.*8"); then
+ cmake_src_test -V
+ else
+ eerror "en_US.UTF-8 locale is required to run ${PN}'s ${FUNCNAME}"
+ die "required locale missing"
+ fi
+}