[gentoo-commits] repo/gentoo:master commit in: app-text/poppler/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     a086ca96a7cb13b9c87b78c5a1ec57a708ea0f18
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Jun  5 17:10:31 2024 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Jun  5 18:16:54 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a086ca96

app-text/poppler: add 24.06.0

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 app-text/poppler/Manifest               |   2 +
 app-text/poppler/poppler-24.06.0.ebuild | 157 ++++++++++++++++++++++++++++++++
 2 files changed, 159 insertions(+)

diff --git a/app-text/poppler/Manifest b/app-text/poppler/Manifest
index 0c5f1820b290..b019852cb32a 100644
--- a/app-text/poppler/Manifest
+++ b/app-text/poppler/Manifest
@@ -4,5 +4,7 @@ DIST poppler-24.04.0.tar.xz 1904936 BLAKE2B c4a9350b990981b0018229923160ded621f4
 DIST poppler-24.04.0.tar.xz.sig 833 BLAKE2B 842f500b45396a3a0a6e5789a6f0957ea5f3d66536dfb6e32420201bdfc4a867a0262d0dc97302cc0d530e68ca163fda10f143516a472394bcb085f746d891d1 SHA512 4419a2a94c34621ffde1f1e0d1d26929171f81b6809a5380af30434c2220a7bf694ff2f8e7ba7a611b1ebd265e91424060238f51d2cccd9acecd92f66e0e1e28
 DIST poppler-24.05.0.tar.xz 1909164 BLAKE2B 65d5d1509078012a26d0bd97985516a39c49594a3c83016f1b7c7745caf1d13faaa82bbaea62c16466f4b1c159c765fa88f97e20f10a87b08514b00e5bdb1113 SHA512 caa3d31b8f22186a7218831039c2ff7384b07863de04f166980dfe534a7a5f047e7c21e1114b9ed0ef323beb60983b45a36bb906c4189c0828f4119e3e2dbaa1
 DIST poppler-24.05.0.tar.xz.sig 833 BLAKE2B f1125a8b81089a4b8beb9385fa4a9b170b97f08e2bc732fd1cc2671ed43a81bb7b58b9ced61691e55188af94ee6b2c701be0ea1e12feecebbc7c4062a97b76fb SHA512 3010eeda09ff58d9705465bffe4861d9af1f294597b8eec1e1cc90f59008ab146000fcc694b2fad8bb675d89d68b2b78d54236ae6d42411058b9444b87514db3
+DIST poppler-24.06.0.tar.xz 1910016 BLAKE2B cd5f8f127048b15b8630f0ef0ef8382b3c32919a0dd63a94f6e25a1e62277a64115a3d77b627a91d032c2e939adc7c2ebb227369cfc95b5a9126ada19c4d94d1 SHA512 4e69aedcba7ee65de25e107593736f70353b7811b800ef7d0b4d7efe8f8a5a4d0134af5f9bf5cff005d095d02af247bf46c8c53b52958900245a4139d153c1ea
+DIST poppler-24.06.0.tar.xz.sig 833 BLAKE2B d453a7ea8949238ea3b8446eaa77b5efa5d0bb7beb5c53145612d8950bf7b7f2eda4ceb7b61ab177cee4b12c515e5c6592cb770a547834026ab5b517f1fe769b SHA512 34471d4f5c9ea83d545f013d7b6598ce9f5797fa1e68e2d1eff8bc965932d2d087612ff7f4256405687a4858ce7255430509a589033d5b923519009682bbd3d1
 DIST poppler-test-400f3ff05b2b1c0ae17797a0bd50e75e35c1f1b1.tar.bz2 5199265 BLAKE2B d58f6ee7b44ca45291c205f9619db3833871f5789dd6a4e3ccc9acce2b6d7967a6b8596e3f32b7b35ba3d185976e8b9c8a998071c4451bb5ce674825a4005d6d SHA512 5bf5d99956fa0a6a93e0b0dc4713ecd8810811eca35514cc5765ffaafb9485f64f94b21487afa46c16eaf66326fcb999e792b8121eeb188e7e33a32a4798fb76
 DIST poppler-test-ff3133cdb6cb496ee1d2c3231bfa35006a5e8410.tar.bz2 5207226 BLAKE2B 15153457989a53301bcdc3468ab2b06b637457199004651b39ea848f488f8a2ba594ce2e36091de4fd06fc0a52b783c6b2ee243ac5d95ce1e9db7483ea880829 SHA512 335cd3d55fc6e28331e791e5b63a08d293abc70764a9f314b2c590c26a5a78b38243c74f988bb95afffe0bdcc54dee1e633dbf1672b19a290be40a298e16995f

diff --git a/app-text/poppler/poppler-24.06.0.ebuild b/app-text/poppler/poppler-24.06.0.ebuild
new file mode 100644
index 000000000000..fe2ff39083f0
--- /dev/null
+++ b/app-text/poppler/poppler-24.06.0.ebuild
@@ -0,0 +1,157 @@
+# Copyright 2005-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic toolchain-funcs xdg-utils
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/poppler/poppler.git"
+	SLOT="0/9999"
+else
+	VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/aacid.asc
+	inherit verify-sig
+
+	TEST_COMMIT="ff3133cdb6cb496ee1d2c3231bfa35006a5e8410"
+	SRC_URI="https://poppler.freedesktop.org/${P}.tar.xz"
+	SRC_URI+=" test? ( https://gitlab.freedesktop.org/poppler/test/-/archive/${TEST_COMMIT}/test-${TEST_COMMIT}.tar.bz2 -> ${PN}-test-${TEST_COMMIT}.tar.bz2 )"
+	SRC_URI+=" verify-sig? ( https://poppler.freedesktop.org/${P}.tar.xz.sig )"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+	SLOT="0/137"   # CHECK THIS WHEN BUMPING!!! SUBSLOT IS libpoppler.so SOVERSION
+fi
+
+DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"
+HOMEPAGE="https://poppler.freedesktop.org/"
+
+LICENSE="GPL-2"
+IUSE="boost cairo cjk curl +cxx debug doc gpgme +introspection +jpeg +jpeg2k +lcms nss png qt5 qt6 test tiff +utils"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	>=media-libs/fontconfig-2.13
+	>=media-libs/freetype-2.10
+	sys-libs/zlib
+	cairo? (
+		>=dev-libs/glib-2.64:2
+		>=x11-libs/cairo-1.16
+		introspection? ( >=dev-libs/gobject-introspection-1.72:= )
+	)
+	curl? ( net-misc/curl )
+	gpgme? ( >=app-crypt/gpgme-1.19.0:=[cxx] )
+	jpeg? ( >=media-libs/libjpeg-turbo-1.1.0:= )
+	jpeg2k? ( >=media-libs/openjpeg-2.3.0-r1:2= )
+	lcms? ( media-libs/lcms:2 )
+	nss? ( >=dev-libs/nss-3.49 )
+	png? ( media-libs/libpng:0= )
+	qt5? (
+		>=dev-qt/qtcore-5.15.2:5
+		>=dev-qt/qtgui-5.15.2:5
+		>=dev-qt/qtxml-5.15.2:5
+	)
+	qt6? ( dev-qt/qtbase:6[gui,xml] )
+	tiff? ( media-libs/tiff:= )
+"
+RDEPEND="${COMMON_DEPEND}
+	cjk? ( app-text/poppler-data )
+"
+DEPEND="${COMMON_DEPEND}
+	boost? ( >=dev-libs/boost-1.74 )
+	test? (
+		qt5? (
+			>=dev-qt/qttest-5.15.2:5
+			>=dev-qt/qtwidgets-5.15.2:5
+		)
+		qt6? ( dev-qt/qtbase:6[widgets] )
+	)
+"
+BDEPEND="
+	>=dev-util/glib-utils-2.64
+	virtual/pkgconfig
+"
+
+if [[ ${PV} != *9999* ]] ; then
+	BDEPEND+=" verify-sig? ( >=sec-keys/openpgp-keys-aacid-20230907 )"
+fi
+
+DOCS=( AUTHORS NEWS README.md README-XPDF )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-23.10.0-qt-deps.patch"
+	"${FILESDIR}/${PN}-21.09.0-respect-cflags.patch"
+	"${FILESDIR}/${PN}-0.57.0-disable-internal-jpx.patch"
+)
+
+src_unpack() {
+	if [[ ${PV} == *9999* ]] ; then
+		git-r3_src_unpack
+	elif use verify-sig ; then
+		verify-sig_verify_detached "${DISTDIR}"/${P}.tar.xz{,.sig}
+	fi
+
+	default
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Clang doesn't grok this flag, the configure nicely tests that, but
+	# cmake just uses it, so remove it if we use clang
+	if tc-is-clang ; then
+		sed -e 's/-fno-check-new//' -i cmake/modules/PopplerMacros.cmake || die
+	fi
+
+	if ! grep -Fq 'cmake_policy(SET CMP0002 OLD)' CMakeLists.txt ; then
+		sed -e '/^cmake_minimum_required/acmake_policy(SET CMP0002 OLD)' \
+			-i CMakeLists.txt || die
+	else
+		einfo "policy(SET CMP0002 OLD) - workaround can be removed"
+	fi
+}
+
+src_configure() {
+	xdg_environment_reset
+	append-lfs-flags # bug #898506
+
+	local mycmakeargs=(
+		-DBUILD_GTK_TESTS=OFF
+		-DBUILD_QT5_TESTS=$(usex test $(usex qt5))
+		-DBUILD_QT6_TESTS=$(usex test $(usex qt6))
+		-DBUILD_CPP_TESTS=$(usex test)
+		-DBUILD_MANUAL_TESTS=$(usex test)
+		-DTESTDATADIR="${WORKDIR}"/test-${TEST_COMMIT}
+		-DRUN_GPERF_IF_PRESENT=OFF
+		-DENABLE_BOOST="$(usex boost)"
+		-DENABLE_ZLIB_UNCOMPRESS=OFF
+		-DENABLE_UNSTABLE_API_ABI_HEADERS=ON
+		-DUSE_FLOAT=OFF
+		-DWITH_Cairo=$(usex cairo)
+		-DENABLE_LIBCURL=$(usex curl)
+		-DENABLE_CPP=$(usex cxx)
+		-DENABLE_GPGME=$(usex gpgme)
+		-DWITH_JPEG=$(usex jpeg)
+		-DENABLE_DCTDECODER=$(usex jpeg libjpeg none)
+		-DENABLE_LIBOPENJPEG=$(usex jpeg2k openjpeg2 none)
+		-DENABLE_LCMS=$(usex lcms)
+		-DENABLE_NSS3=$(usex nss)
+		-DWITH_PNG=$(usex png)
+		-DENABLE_QT5=$(usex qt5)
+		-DENABLE_QT6=$(usex qt6)
+		-DENABLE_LIBTIFF=$(usex tiff)
+		-DENABLE_UTILS=$(usex utils)
+	)
+	use cairo && mycmakeargs+=( -DWITH_GObjectIntrospection=$(usex introspection) )
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	# live version doesn't provide html documentation
+	if use cairo && use doc && [[ ${PV} != *9999* ]]; then
+		# For now install gtk-doc there
+		insinto /usr/share/gtk-doc/html/poppler
+		doins -r "${S}"/glib/reference/html/*
+	fi
+}