[gentoo-commits] repo/gentoo:master commit in: dev-ruby/json/

["Hans de Graaff" <graaff@gentoo.org>]

commit:     1b25a69077f514882b5039e763c5bcbc5841b757
Author:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
AuthorDate: Tue Jun  4 04:26:28 2024 +0000
Commit:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
CommitDate: Tue Jun  4 04:26:28 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1b25a690

dev-ruby/json: allow all ragel versions

It turns out dev-ruby/json does not use ragel to generate ruby code and
using ragel 7 works fine for this case.

Bug: https://bugs.gentoo.org/794235
Signed-off-by: Hans de Graaff <graaff <AT> gentoo.org>

 dev-ruby/json/json-2.7.2-r1.ebuild | 51 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

diff --git a/dev-ruby/json/json-2.7.2-r1.ebuild b/dev-ruby/json/json-2.7.2-r1.ebuild
new file mode 100644
index 000000000000..e0ef6a572308
--- /dev/null
+++ b/dev-ruby/json/json-2.7.2-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby31 ruby32 ruby33"
+
+RUBY_FAKEGEM_EXTRADOC="CHANGES.md README.md"
+RUBY_FAKEGEM_DOCDIR="doc"
+
+RUBY_FAKEGEM_GEMSPEC="json.gemspec"
+
+RUBY_FAKEGEM_EXTENSIONS=(ext/json/ext/parser/extconf.rb ext/json/ext/generator/extconf.rb)
+RUBY_FAKEGEM_EXTENSION_LIBDIR=lib/json/ext
+
+inherit ruby-fakegem
+
+DESCRIPTION="A JSON implementation as a Ruby extension"
+HOMEPAGE="https://github.com/flori/json"
+SRC_URI="https://github.com/flori/json/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="|| ( BSD-2 Ruby )"
+
+SLOT="$(ver_cut 1)"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="doc test"
+
+DEPEND="dev-util/ragel"
+
+ruby_add_bdepend "dev-ruby/rake
+	doc? ( dev-ruby/rdoc )
+	test? (
+		dev-ruby/test-unit:2
+		dev-ruby/test-unit-ruby-core
+	)"
+
+all_ruby_prepare() {
+	# Avoid building the extension twice!
+	# And use rdoc instead of sdoc which we don't have packaged
+	# And don't call git to list files. We're using the pregenerated spec anyway.
+	sed -i \
+		-e '/task :test/ s|:compile,||' \
+		-e 's| => :clean||' \
+		-e 's|sdoc|rdoc|' \
+		-e 's|`git ls-files`|""|' \
+		Rakefile || die "rakefile fix failed"
+
+	sed -e 's/__dir__/"."/' \
+		-i ${RUBY_FAKEGEM_GEMSPEC} || die
+
+	# Avoid setting gem since it will not be available yet when installing
+	sed -i -e '/gem/ s:^:#:' tests/test_helper.rb || die
+}