public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed
From: "Horodniceanu Andrei" <a.horodniceanu@proton.me>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/user/dlang:master commit in: dev-util/dub/
Date: Thu, 30 May 2024 17:28:42 +0000 (UTC)	[thread overview]
Message-ID: <1717089128.7d061e482d0af10bcba399b21080e320a8bad1a0.a.horodniceanu@gentoo> (raw)

commit:     7d061e482d0af10bcba399b21080e320a8bad1a0
Author:     Andrei Horodniceanu <a.horodniceanu <AT> proton <DOT> me>
AuthorDate: Thu May 30 17:12:08 2024 +0000
Commit:     Horodniceanu Andrei <a.horodniceanu <AT> proton <DOT> me>
CommitDate: Thu May 30 17:12:08 2024 +0000
URL:        https://gitweb.gentoo.org/repo/user/dlang.git/commit/?id=7d061e48

dev-util/dub: drop 1.36.0

Signed-off-by: Andrei Horodniceanu <a.horodniceanu <AT> proton.me>

 dev-util/dub/dub-1.36.0.ebuild | 174 -----------------------------------------
 1 file changed, 174 deletions(-)

diff --git a/dev-util/dub/dub-1.36.0.ebuild b/dev-util/dub/dub-1.36.0.ebuild
deleted file mode 100644
index 7bae587..0000000
--- a/dev-util/dub/dub-1.36.0.ebuild
+++ /dev/null
@@ -1,174 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DESCRIPTION="Package and build management system for D"
-HOMEPAGE="https://code.dlang.org/"
-LICENSE="MIT"
-
-SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~x86"
-IUSE="debug doc test"
-RESTRICT="!test? ( test )"
-
-DUB_TEST_DEPS=(
-	gitcompatibledubpackage@1.0.1
-	gitcompatibledubpackage@1.0.4
-	urld@2.1.1
-)
-generate_dub_dependencies() {
-	local dep
-	for dep in "${DUB_TEST_DEPS[@]}"; do
-		local depName depVersion
-		depName="${dep%@*}"
-		depVersion="${dep#*@}"
-		echo "https://code.dlang.org/packages/${depName}/${depVersion}.zip -> ${depName}-${depVersion}.zip"
-	done
-}
-
-GITHUB_URI="https://codeload.github.com/dlang"
-SRC_URI="
-${GITHUB_URI}/${PN}/tar.gz/v${PV} -> ${PN}-${PV}.tar.gz
-test? (
-	$(generate_dub_dependencies)
-)
-"
-
-PATCHES=(
-	"${FILESDIR}/${PF}-fix-wno-error-not-applying.patch"
-)
-
-# Upstream recommends the latest version available
-DLANG_VERSION_RANGE="2.100-2.107"
-DLANG_PACKAGE_TYPE="single"
-
-inherit dlang shell-completion
-
-src_unpack() {
-	unpack "${P}.tar.gz"
-
-	if use test; then
-		# Copy the archives locally. Some tests do need to perform an
-		# actual fetch operation so make all of them available as
-		# archives and let dub figure out the rest.
-		local store="${T}/dub-test-deps"
-		mkdir -p "${store}" || die
-
-		local dep
-		for dep in "${DUB_TEST_DEPS[@]}"; do
-			local depName depVersion
-			depName="${dep%@*}"
-			depVersion="${dep#*@}"
-
-			cp "${DISTDIR}/${depName}-${depVersion}.zip" "${store}" || die
-		done
-
-		# Generate a settings.json file that points to the directory with all the deps.
-		cat <<EOF > "${T}/settings.json"
-{
-	"registryUrls": [
-		"file://${store}"
-	],
-	"skipRegistry": "all"
-}
-EOF
-	fi
-}
-
-d_src_compile() {
-	local imports=source versions="DubApplication DubUseCurl"
-	dlang_compile_bin bin/dub $(<build-files.txt)
-
-	# Generate man pages. Rebuids dub so put it behind a USE flag.
-	if use doc; then
-		einfo "Generating man pages"
-		# You're supposed to be able to do ./bin/dub scrips/man/gen_man.d
-		# but it gives linking errors with gdc.
-
-		# $imports is set up above.
-		versions=DubUseCurl
-		dlang_compile_bin scripts/man/gen_man{,.d} \
-						  $(sed '/^source\/app.d$/d' build-files.txt)
-		./scripts/man/gen_man || die "Could not generate man pages"
-	fi
-}
-
-d_src_test() {
-	# Setup the environment for the tests.
-	local -x DUB="${S}/bin/dub"
-	local -x DUB_HOME="${T}/dub-home" # where to put artifacts
-
-	# Note, disabling tests is possible yet very hard. You have to
-	# create a bash variable containing a regex (to be used in =~) that
-	# matches all the tests that you want *to* run. It's probably easier
-	# to delete the subdirectory under ${S}/test.
-
-	# Tries to connect to github.com and fails due to the network sandbox
-	rm -rf "${S}/test/git-dependency" || die
-	# Doesn't work on non amd64/x86
-	if [[ ${ARCH} == arm64 ]]; then
-		rm -rf test/issue1447-build-settings-vars || die
-	fi
-
-	if [[ ${DLANG_VENDOR} == GNU ]]; then
-		# Should be skipped on dmd and gdc but $DC being in the form
-		# ${CHOST}-gdc makes the unittest script not skip it.
-		rm -rf test/depen-build-settings || die
-	fi
-
-	local dropImportCTest
-	# We have an importC test and not all compilers pass it properly.
-	# gdc doesn't support #include's in its importC implementation yet.
-	# Only check == 13 since 12 is skipped by the script.
-	[[ ${DLANG_VENDOR} == GNU ]] && [[ ${DC_VERSION} == 13 ]] && dropImportCTest=1
-	# Nor does <=ldc2-1.32.
-	[[ ${DLANG_VENDOR} == LDC ]] && $(ver_test ${DC_VERSION} -le 1.32) && dropImportCTest=1
-	# dmd can do #include's but there are some other errors about
-	# __float128 in <=dmd-2.102 on x86.
-	[[ ${DLANG_VENDOR} == DigitalMars ]] && $(ver_test ${DC_VERSION} -le 2.102) \
-		&& [[ ${ARCH} == x86 ]] && dropImportCTest=1
-	if [[ ${dropImportCTest} ]]; then
-		rm -rf "${S}/test/use-c-sources" || die
-	fi
-
-	# Put the configuration file relative to the dub binary:
-	# <dub-bin-dir>/../etc/dub/settings.json as per
-	# https://dub.pm/dub-reference/settings so that it's picked up
-	# automatically.
-	mkdir -p "${S}/bin/../etc/dub" || die
-	cp "${T}/settings.json" "${S}/bin/../etc/dub/" \
-		|| die "Could not copy dub configuration file"
-
-	# See https://bugs.gentoo.org/921581 we have to remove -op (preserve
-	# source path for output files) from the flags lest the sandbox
-	# trips us up.
-	local newDflags="${DCFLAGS//--op/}"
-	newDflags="${newDflags//-op/}"
-
-	# Append -Wno-error or equivalent
-	newDflags+=" $(get_wno_error_flag)"
-
-	DFLAGS="${newDflags}" FRONTEND="${DLANG_VERSION}" test/run-unittest.sh  \
-		|| die "Tests failed"
-}
-
-d_src_install() {
-	dobin bin/dub
-	dodoc README.md
-
-	# Make sure there are no man files in any other section.
-	use doc && doman scripts/man/*.1
-
-	newbashcomp scripts/bash-completion/${PN}.bash ${PN}
-	dozshcomp scripts/zsh-completion/_${PN}
-	dofishcomp scripts/fish-completion/${PN}.fish
-}
-
-get_wno_error_flag() {
-	case "${DLANG_VENDOR}" in
-		DigitalMars) echo "-wi" ;;
-		GNU) echo "-Wno-error" ;;
-		LDC) echo "--wi" ;;
-	esac
-}


             reply	other threads:[~2024-05-30 17:28 UTC|newest]

Thread overview: 15+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2024-05-30 17:28 Horodniceanu Andrei [this message]
  -- strict thread matches above, loose matches on Subject: below --
2025-01-03 20:34 [gentoo-commits] repo/user/dlang:master commit in: dev-util/dub/ Horodniceanu Andrei
2024-08-30  7:58 Horodniceanu Andrei
2024-07-12 18:59 Horodniceanu Andrei
2024-06-02  5:29 Horodniceanu Andrei
2024-06-02  5:29 Horodniceanu Andrei
2024-05-30 17:28 Horodniceanu Andrei
2024-04-23 17:05 Horodniceanu Andrei
2024-04-13 23:04 Horodniceanu Andrei
2024-02-20 18:59 Horodniceanu Andrei
2024-02-18 22:49 Horodniceanu Andrei
2024-02-18 22:49 Horodniceanu Andrei
2024-01-14 20:45 Horodniceanu Andrei
2024-01-14 20:45 Horodniceanu Andrei
2024-01-03 19:56 Horodniceanu Andrei

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=1717089128.7d061e482d0af10bcba399b21080e320a8bad1a0.a.horodniceanu@gentoo \
    --to=a.horodniceanu@proton.me \
    --cc=gentoo-commits@lists.gentoo.org \
    --cc=gentoo-dev@lists.gentoo.org \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox