[gentoo-commits] proj/kde:master commit in: kde-plasma/powerdevil/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     6fba8a193e83ca08911fcc34e076d8ba9aa12f75
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri May 24 18:55:59 2024 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri May 24 19:26:15 2024 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=6fba8a19

kde-plasma/powerdevil: 6.0.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-plasma/powerdevil/powerdevil-6.0.90.ebuild | 65 ++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)

diff --git a/kde-plasma/powerdevil/powerdevil-6.0.90.ebuild b/kde-plasma/powerdevil/powerdevil-6.0.90.ebuild
new file mode 100644
index 0000000000..01b2d6589f
--- /dev/null
+++ b/kde-plasma/powerdevil/powerdevil-6.0.90.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="forceoptional"
+KFMIN=6.2.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=6.7.1
+inherit ecm plasma.kde.org
+
+DESCRIPTION="Power management for KDE Plasma Shell"
+HOMEPAGE="https://invent.kde.org/plasma/powerdevil"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="6"
+KEYWORDS="~amd64"
+IUSE="brightness-control caps"
+
+# slot op: Uses Qt::GuiPrivate for qtx11extras_p.h
+DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6=[dbus,gui,widgets]
+	>=kde-frameworks/kauth-${KFMIN}:6[policykit]
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/kglobalaccel-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kidletime-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kirigami-${KFMIN}:6
+	>=kde-frameworks/kitemmodels-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6[X]
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-frameworks/solid-${KFMIN}:6
+	>=kde-plasma/layer-shell-qt-${PVCUT}:6
+	>=kde-plasma/libkscreen-${PVCUT}:6
+	>=kde-plasma/plasma-activities-${PVCUT}:6
+	>=kde-plasma/plasma-workspace-${PVCUT}:6
+	virtual/libudev:=
+	x11-libs/libxcb
+	brightness-control? ( app-misc/ddcutil:= )
+	caps? ( sys-libs/libcap )
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=kde-plasma/kde-cli-tools-${PVCUT}:*
+	sys-power/power-profiles-daemon
+	>=sys-power/upower-0.9.23
+"
+BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:6"
+
+src_configure() {
+	local mycmakeargs=(
+		-DHAVE_DDCUTIL=$(usex brightness-control)
+		$(cmake_use_find_package caps Libcap)
+	)
+
+	ecm_src_configure
+}