[gentoo-commits] proj/kde:master commit in: kde-plasma/wacomtablet/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     40d92d11bf4624bffd326a998d4d1b0d045deb96
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri May 24 18:56:01 2024 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri May 24 19:26:15 2024 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=40d92d11

kde-plasma/wacomtablet: 6.0.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-plasma/wacomtablet/wacomtablet-6.0.90.ebuild | 56 ++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

diff --git a/kde-plasma/wacomtablet/wacomtablet-6.0.90.ebuild b/kde-plasma/wacomtablet/wacomtablet-6.0.90.ebuild
new file mode 100644
index 0000000000..2c73758084
--- /dev/null
+++ b/kde-plasma/wacomtablet/wacomtablet-6.0.90.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=6.2.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=6.7.1
+inherit ecm plasma.kde.org
+
+DESCRIPTION="Wacom system settings module that supports different button/pen layout profiles"
+HOMEPAGE="https://userbase.kde.org/Wacomtablet"
+
+LICENSE="GPL-2"
+SLOT="6"
+KEYWORDS="~amd64"
+IUSE=""
+
+# slot op: Uses Qt6::GuiPrivate for qtx11extras_p.h
+RDEPEND="
+	>=dev-libs/libwacom-0.30:=
+	>=dev-qt/qtbase-${QTMIN}:6=[dbus,gui,widgets]
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/kglobalaccel-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-plasma/libplasma-${PVCUT}:6
+	>=kde-plasma/plasma5support-${PVCUT}:6
+	>=x11-drivers/xf86-input-wacom-0.20.0
+	x11-libs/libXi
+	x11-libs/libxcb
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto
+	x11-libs/libX11
+"
+BDEPEND="sys-devel/gettext"
+
+src_test() {
+	# test needs DBus, bug 675548
+	local myctestargs=(
+		-E "(Test.KDED.DBusTabletService)"
+	)
+
+	ecm_src_test
+}