[gentoo-commits] repo/gentoo:master commit in: sci-libs/htslib/

["David Seifert" <soap@gentoo.org>]

commit:     dda90e924ca655b36afed52816962a71629b824d
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Fri May 24 08:59:49 2024 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Fri May 24 08:59:49 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=dda90e92

sci-libs/htslib: add 1.20

Signed-off-by: David Seifert <soap <AT> gentoo.org>

 sci-libs/htslib/Manifest           |  1 +
 sci-libs/htslib/htslib-1.20.ebuild | 52 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 53 insertions(+)

diff --git a/sci-libs/htslib/Manifest b/sci-libs/htslib/Manifest
index 234d7092da4d..0110e7bb188d 100644
--- a/sci-libs/htslib/Manifest
+++ b/sci-libs/htslib/Manifest
@@ -1 +1,2 @@
 DIST htslib-1.19.1.tar.bz2 4775086 BLAKE2B 3af6770ade9505a3c71f6d522c0971eb77ea2549670043a539a2a4681e583554dc154b9b9fb33f1faa94be336a09945a28c57aa4bcfe0f39b03dd7585c49269a SHA512 a40de47ecae68756c158c1c7b578fa2a5c13bf6f98626e863af31a20d7880ffd415d966280c00bfe726f496d913eb0fcf014dd4beb8c1dbe36ed9735a48bd01e
+DIST htslib-1.20.tar.bz2 4779028 BLAKE2B def7a135f37a4c7a167ada554b92b0e0107ab3dcbdab69abdea387035159f40fb183477275c137b0d786fdfc7264303898f98c54acb1714f9b7cb21e22612143 SHA512 a156f5c895fdae77f976f463a2d4d1111dc056893ef45b7e9cf62e9115898bc8cb47465bb1779e534c26943df478892385d44646e97bd0fa67fceb83ef7a649b

diff --git a/sci-libs/htslib/htslib-1.20.ebuild b/sci-libs/htslib/htslib-1.20.ebuild
new file mode 100644
index 000000000000..2a38fa8634c8
--- /dev/null
+++ b/sci-libs/htslib/htslib-1.20.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="C library for high-throughput sequencing data formats"
+HOMEPAGE="http://www.htslib.org/"
+SRC_URI="https://github.com/samtools/${PN}/releases/download/${PV}/${P}.tar.bz2"
+
+LICENSE="MIT"
+SLOT="0/3"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="+bzip2 curl +lzma"
+
+RDEPEND="
+	sys-libs/zlib
+	bzip2? ( app-arch/bzip2 )
+	curl? ( net-misc/curl )
+	lzma? ( app-arch/xz-utils )"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+
+	# upstream injects LDFLAGS into the .pc file,
+	# which is a big nono for QA
+	sed -e '/^\(static_l\|Libs.private\|Requires.private\)/d' \
+		-i htslib.pc.in || die
+}
+
+src_configure() {
+	econf \
+		--disable-gcs \
+		--disable-plugins \
+		--disable-s3 \
+		$(use_enable bzip2 bz2) \
+		$(use_enable curl libcurl) \
+		$(use_enable lzma)
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)"
+}
+
+src_install() {
+	default
+
+	# doesn't use libtool, can't disable static libraries
+	find "${ED}" -name '*.a' -delete || die
+}