[gentoo-commits] repo/gentoo:master commit in: www-client/opera-beta/

["Matt Jolly" <kangie@gentoo.org>]

commit:     83734bd0f9926f9a8a369cddbc847d8fcd348e6a
Author:     Matt Jolly <kangie <AT> gentoo <DOT> org>
AuthorDate: Thu May 23 07:41:30 2024 +0000
Commit:     Matt Jolly <kangie <AT> gentoo <DOT> org>
CommitDate: Thu May 23 07:48:32 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=83734bd0

www-client/opera-beta: automated bump (111.0.5168.3)

Signed-off-by: Matt Jolly <kangie <AT> gentoo.org>

 www-client/opera-beta/Manifest                     |   1 +
 .../opera-beta/opera-beta-111.0.5168.3.ebuild      | 173 +++++++++++++++++++++
 2 files changed, 174 insertions(+)

diff --git a/www-client/opera-beta/Manifest b/www-client/opera-beta/Manifest
index 758dfe35acbd..f5603756db03 100644
--- a/www-client/opera-beta/Manifest
+++ b/www-client/opera-beta/Manifest
@@ -1,3 +1,4 @@
 DIST opera-beta_110.0.5130.13_amd64.deb 110204952 BLAKE2B dedeac21ce18c3180bafa9a6ae167b8042f78b1f50500f3c03374a67a3472d728a4abb0a760cc8589dfaf38b97fc63736b55f7855b8a02520c56d765255c3f0d SHA512 412165e9d69da93d38da321b0bce6e09bc6b981c1716604208ea5d14dba68f836ceff2097a80222341b9d36fdac0689eb8fd12c0e4212867647b0221c36362f9
 DIST opera-beta_110.0.5130.17_amd64.deb 110223832 BLAKE2B 21a37802dd612a27db6555bda5767598f06c5e28cd754bcafb15418b74ef25ed4d9acc5adafe5e3e21a874118d0b10fc862e69b116616229bfe49e23275f3305 SHA512 555240c02a82a29a00460599ca8070d1b2d200d37ca3d58f8ddd76a748175168ed17aeee5afbf8569966e62fe5b21f1e87584a22b39ae8c2a74fca7f92e2535e
 DIST opera-beta_110.0.5130.8_amd64.deb 110214708 BLAKE2B f2a96885a9449b0821499c871843941488aa89f3a30d1791b04741ddeecbe52dda9b304642e60985403dd3b2aaa0e247dd5884648a639a74b2d7109adae9fb71 SHA512 d3f156bec609f385a0183a8b1383e192c296f3ca67b276c86109107953e6f0a4d8b79fafff7fedc58752c4398d0b4bc2d366d15ed84117139229d55d285c15a3
+DIST opera-beta_111.0.5168.3_amd64.deb 110690324 BLAKE2B af58d56d8fdbe6ca88c9b03c7cd8ed84c5259c4fbb43e61500dae8c23e067a5399a00c60f5215c017b2804cad7a390a682280d4f7241c0c42f113a52357e5f28 SHA512 2787b71e6e846497d2ba6b7adce8a13285e0359e62533e6a890f19c0aacb33d1032881b468be6a9bb497718d09ffde6c99454d05db6aa43867fa1afcdda9aec1

diff --git a/www-client/opera-beta/opera-beta-111.0.5168.3.ebuild b/www-client/opera-beta/opera-beta-111.0.5168.3.ebuild
new file mode 100644
index 000000000000..cfafbce68c18
--- /dev/null
+++ b/www-client/opera-beta/opera-beta-111.0.5168.3.ebuild
@@ -0,0 +1,173 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CHROMIUM_LANGS="
+	bg bn ca cs da de el en-GB en-US es-419 es fil fi fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+
+# These are intended for ebuild maintainer use to force RPM if DEB is not available.
+: ${OPERA_FORCE_RPM=no}
+
+inherit chromium-2 pax-utils xdg
+
+if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+	inherit rpm
+	OPERA_ARCHIVE_EXT="rpm"
+else
+	inherit unpacker
+	OPERA_ARCHIVE_EXT="deb"
+fi
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+# Commit ref from `strings libffmpeg.so | grep -F "FFmpeg version"` matches this Chromium version
+# used to select the correct ffmpeg-chromium version (corresponds to a major version of Chromium)
+# Does not need to be updated for every new version of Opera, only when it breaks
+CHROMIUM_VERSION="124"
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}"
+S=${WORKDIR}
+
+LICENSE="OPERA-2018"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+IUSE="+ffmpeg-chromium +proprietary-codecs +suid qt5 qt6"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+	proprietary-codecs? (
+		!ffmpeg-chromium? ( >=media-video/ffmpeg-6.1-r1:0/58.60.60[chromium] )
+		ffmpeg-chromium? ( media-video/ffmpeg-chromium:${CHROMIUM_VERSION} )
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5[X]
+		dev-qt/qtwidgets:5
+	)
+	qt6? ( dev-qt/qtbase:6[gui,widgets] )
+"
+
+QA_PREBUILT="*"
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rpm_src_unpack "${A[0]}"
+	else
+		unpacker
+	fi
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
+	else
+		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	fi
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rm "${OPERA_HOME}/setup_repo.sh" || die
+	else
+		rm -r "usr/share/lintian" || die
+
+		# fix docs
+		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+		gzip -d usr/share/doc/${PF}/changelog.gz || die
+	fi
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		dosym ../../usr/$(get_libdir)/chromium/libffmpeg.so$(usex ffmpeg-chromium .${CHROMIUM_VERSION} "") \
+			  /${OPERA_HOME}/libffmpeg.so
+	fi
+
+	if ! use qt5; then
+		rm "${OPERA_HOME}/libqt5_shim.so" || die
+	fi
+	if ! use qt6; then
+		rm "${OPERA_HOME}/libqt6_shim.so" || die
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "/${OPERA_HOME}/opera_sandbox"
+}