[gentoo-commits] repo/gentoo:master commit in: dev-dotnet/dotnet-sdk/, app-emacs/auctex/

[gentoo-commits] repo/gentoo:master commit in: dev-dotnet/dotnet-sdk/, app-emacs/auctex/

[Maciej Barć]

commit:     9306d483a299adb9df6fd5a3a1328176cef6c69f
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Tue May 21 00:26:33 2024 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Tue May 21 00:51:11 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9306d483

dev-dotnet/dotnet-sdk: bump to 8.0.105

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 app-emacs/auctex/Manifest                       |   1 +
 app-emacs/auctex/auctex-14.0.5.ebuild           |  77 +++++++++
 dev-dotnet/dotnet-sdk/Manifest                  |   2 +
 dev-dotnet/dotnet-sdk/dotnet-sdk-8.0.105.ebuild | 217 ++++++++++++++++++++++++
 4 files changed, 297 insertions(+)

diff --git a/app-emacs/auctex/Manifest b/app-emacs/auctex/Manifest
index 8e022ae758eb..3fcfe4c0841a 100644
--- a/app-emacs/auctex/Manifest
+++ b/app-emacs/auctex/Manifest
@@ -1 +1,2 @@
 DIST auctex-13.3.tar.gz 1695608 BLAKE2B 3a22273b72237e14a31a1fb9d81e2c4ee10290919bc3d6f8cb35ab877ef26083c7edb5bbb7c88a40f45848012cc2edd375a90d872f604029ba8f03278bd95f9a SHA512 32d6f3c968a27dd5e7862993419bfa0f5e5228abca7478341a06fce153f333410cd230f8266e6b0e4fb5e4247864710e3f572b6a837c99c2879d38899590f678
+DIST auctex-14.0.5.tar.xz 1006368 BLAKE2B 66d382568072be804707c2bab3d1d2eda315999c0ca509a95cb9e7005fded9cd9160c6cbc22bff254937ed717d003dbb0c16498d68512e5f7c2807ae55aeccf2 SHA512 c1e1458d0b0147e597b92ca22326218968540b4069067821998a0eafae9c9b193257dd1da075a53329ba990bff4594e1430bd8da3ee1617c5394aab541e60606

diff --git a/app-emacs/auctex/auctex-14.0.5.ebuild b/app-emacs/auctex/auctex-14.0.5.ebuild
new file mode 100644
index 000000000000..7023de563f3d
--- /dev/null
+++ b/app-emacs/auctex/auctex-14.0.5.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit elisp
+
+DESCRIPTION="Extensible package for writing and formatting TeX files in Emacs"
+HOMEPAGE="https://www.gnu.org/software/auctex/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://git.savannah.gnu.org/git/auctex.git"
+else
+	SRC_URI="https://dev.gentoo.org/~xgqt/distfiles/repackaged/${P}.tar.xz"
+
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+fi
+
+LICENSE="GPL-3+ FDL-1.3+"
+SLOT="0"
+IUSE="preview-latex"
+
+RDEPEND="
+	virtual/latex-base
+	preview-latex? (
+		app-text/dvipng
+		app-text/ghostscript-gpl
+	)
+"
+BDEPEND="
+	${RDEPEND}
+"
+
+TEXMF="/usr/share/texmf-site"
+
+src_configure() {
+	local -a myconf=(
+		--with-emacs
+		--with-auto-dir="${EPREFIX}/var/lib/auctex"
+		--with-lispdir="${EPREFIX}${SITELISP}/${PN}"
+		--with-packagelispdir="${EPREFIX}${SITELISP}/${PN}"
+		--with-packagedatadir="${EPREFIX}${SITEETC}/${PN}"
+		--with-texmf-dir="${EPREFIX}${TEXMF}"
+		--disable-build-dir-test
+		$(use_enable preview-latex preview)
+	)
+	econf "${myconf[@]}"
+}
+
+src_compile() {
+	VARTEXFONTS="${T}/fonts" emake
+}
+
+src_install() {
+	emake -j1 DESTDIR="${ED}" install
+	elisp-site-file-install "${FILESDIR}/50${PN}-gentoo.el"
+
+	if use preview-latex ; then
+		elisp-site-file-install "${FILESDIR}/60${PN}-gentoo.el"
+	fi
+
+	dodoc ChangeLog* CHANGES FAQ INSTALL PROBLEMS.preview README RELEASE TODO
+}
+
+pkg_postinst() {
+	use preview-latex && texmf-update
+
+	elisp-site-regen
+}
+
+pkg_postrm() {
+	use preview-latex && texmf-update
+
+	elisp-site-regen
+}

diff --git a/dev-dotnet/dotnet-sdk/Manifest b/dev-dotnet/dotnet-sdk/Manifest
index 17ceacd14c99..4a66bc65321d 100644
--- a/dev-dotnet/dotnet-sdk/Manifest
+++ b/dev-dotnet/dotnet-sdk/Manifest
@@ -1,2 +1,4 @@
 DIST dotnet-sdk-8.0.102-prepared-gentoo-amd64.tar.xz 1794775828 BLAKE2B 72a12b5af020a7f7d77b45eefd147b6fed52889443bbf0a9c5464a8a35a9582af32b75587f73aea9d1eb72d053986d8a204904178f260b2c8532ad821389beaf SHA512 1f7727f22e91783aaec5bccd2324f9dc63700fc95625afebeeb3bde7a99a63754a086b38c1d0921b4536963cbfc53b9c995a2aca519e0edd529f542a89995924
 DIST dotnet-sdk-8.0.102-prepared-gentoo-musl-amd64.tar.xz 1790982284 BLAKE2B 010a1dee8e09402a22c0b45745a6ec7e511c88134ef984f51caa69051d7aec87dcb73392bc338508d5591ade1247e95f7708d4a83961ea665350b4ef29882e33 SHA512 611f96525ac98bae35592074d2f1d863c566080f4f52ca619546b547515f2962d9ae53317461e9bb803067d4381daab50f6c772134f9386bf36962998891563b
+DIST dotnet-sdk-8.0.105-prepared-gentoo-amd64.tar.xz 1774585908 BLAKE2B c8c14bb513e9421ed04df81bf4388a7b84333ff76cf678f5adfb658d4c32d4e3c90ad8f78676261cb0148d1f1a3f4763e4a4aad9e7d822f94c943ec6ca81f872 SHA512 6032f34c92c046fade8edf1e4c86b315e6f51ae38b7d505084b2903f6a883dcb9c3b17a67d2da28daffcf6f3bc4e2ebd19b481f2842716fad910fbc663980c8a
+DIST dotnet-sdk-8.0.105-prepared-gentoo-musl-amd64.tar.xz 1788053336 BLAKE2B 5cf9328ec19413ed6c82adb48f70346197e2d76926ab752c81c77fde94782c19a30f52aab07e2ddc7545280821bf64251de42afece08b5bcd0d52eceefca3064 SHA512 73b906a282d059e3829841f78e45b58beab980eb8a1c23857746af20630b1070ce9fca1e38d837d78ab039dc40273dc732be4b3ba10978df00dfdaa320dfd77e

diff --git a/dev-dotnet/dotnet-sdk/dotnet-sdk-8.0.105.ebuild b/dev-dotnet/dotnet-sdk/dotnet-sdk-8.0.105.ebuild
new file mode 100644
index 000000000000..c670f25bd98b
--- /dev/null
+++ b/dev-dotnet/dotnet-sdk/dotnet-sdk-8.0.105.ebuild
@@ -0,0 +1,217 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# Pre-build (and distribution preparation)
+# Build the tarball:
+#  git clone --depth 1 -b v8.0.2 https://github.com/dotnet/dotnet dotnet-sdk-8.0.2
+#  cd dotnet-sdk-8.0.2
+#  git rev-parse HEAD
+#  ./prep.sh
+#  rm -fr .git
+#  cd ..
+#  tar -acf dotnet-sdk-8.0.201-prepared-gentoo-amd64.tar.xz dotnet-sdk-8.0.2
+# Upload dotnet-sdk-8.0.201-prepared-gentoo-amd64.tar.xz
+
+# Build ("src_compile")
+# To learn about arguments that are passed to the "build.sh" script see:
+# https://github.com/dotnet/source-build/discussions/4082
+# User variable: GENTOO_DOTNET_BUILD_VERBOSITY - set other verbosity log level.
+
+EAPI=8
+
+COMMIT=d396b0c4d3e51c2d8d679b2f7233912bc5bfc2fa
+SDK_SLOT="$(ver_cut 1-2)"
+RUNTIME_SLOT="${SDK_SLOT}.5"
+
+LLVM_MAX_SLOT=17
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit check-reqs flag-o-matic llvm multiprocessing python-any-r1
+
+DESCRIPTION=".NET is a free, cross-platform, open-source developer platform"
+HOMEPAGE="https://dotnet.microsoft.com/
+	https://github.com/dotnet/dotnet/"
+SRC_URI="
+amd64? (
+	elibc_glibc? ( https://dev.gentoo.org/~xgqt/distfiles/repackaged/${P}-prepared-gentoo-amd64.tar.xz )
+	elibc_musl? ( https://dev.gentoo.org/~xgqt/distfiles/repackaged/${P}-prepared-gentoo-musl-amd64.tar.xz )
+)
+"
+S="${WORKDIR}/${PN}-${RUNTIME_SLOT}"
+
+LICENSE="MIT"
+SLOT="${SDK_SLOT}/${RUNTIME_SLOT}"
+KEYWORDS="~amd64"
+
+# STRIP="llvm-strip" corrupts some executables when using the patchelf hack.
+# Be safe and restrict it for source-built too, bug https://bugs.gentoo.org/923430
+RESTRICT="splitdebug strip"
+
+CURRENT_NUGETS_DEPEND="
+	~dev-dotnet/dotnet-runtime-nugets-${RUNTIME_SLOT}
+"
+EXTRA_NUGETS_DEPEND="
+	~dev-dotnet/dotnet-runtime-nugets-6.0.30
+	~dev-dotnet/dotnet-runtime-nugets-7.0.19
+"
+NUGETS_DEPEND="
+	${CURRENT_NUGETS_DEPEND}
+	${EXTRA_NUGETS_DEPEND}
+"
+RDEPEND="
+	app-crypt/mit-krb5:0/0
+	dev-libs/icu
+	dev-libs/openssl:=
+	dev-util/lttng-ust:=
+	sys-libs/zlib:0/1
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	<sys-devel/clang-$(( LLVM_MAX_SLOT + 1 ))
+	dev-build/cmake
+	dev-vcs/git
+"
+IDEPEND="
+	app-eselect/eselect-dotnet
+"
+PDEPEND="
+	${NUGETS_DEPEND}
+"
+
+CHECKREQS_DISK_BUILD="20G"
+
+# Created by dotnet itself:
+QA_PREBUILT="
+usr/lib.*/dotnet-sdk-.*/dotnet
+"
+# .NET runtime, better to not touch it if they want some specific flags.
+QA_FLAGS_IGNORED="
+.*/apphost
+.*/createdump
+.*/libSystem.Globalization.Native.so
+.*/libSystem.IO.Compression.Native.so
+.*/libSystem.Native.so
+.*/libSystem.Net.Security.Native.so
+.*/libSystem.Security.Cryptography.Native.OpenSsl.so
+.*/libclrgc.so
+.*/libclrjit.so
+.*/libcoreclr.so
+.*/libcoreclrtraceptprovider.so
+.*/libhostfxr.so
+.*/libhostpolicy.so
+.*/libmscordaccore.so
+.*/libmscordbi.so
+.*/libnethost.so
+.*/singlefilehost
+"
+
+check_requirements_locale() {
+	if [[ "${MERGE_TYPE}" != binary ]] ; then
+		if use elibc_glibc ; then
+			local locales
+			locales="$(locale -a)"
+
+			if has en_US.utf8 ${locales} ; then
+				LC_ALL=en_US.utf8
+			elif has en_US.UTF-8 ${locales} ; then
+				LC_ALL=en_US.UTF-8
+			else
+				eerror "The locale en_US.utf8 or en_US.UTF-8 is not available."
+				eerror "Please generate en_US.UTF-8 before building ${CATEGORY}/${P}."
+
+				die "Could not switch to the en_US.UTF-8 locale."
+			fi
+		else
+			LC_ALL=en_US.UTF-8
+		fi
+
+		export LC_ALL
+		einfo "Successfully switched to the ${LC_ALL} locale."
+	fi
+}
+
+pkg_pretend() {
+	check-reqs_pkg_pretend
+
+	check_requirements_locale
+}
+
+pkg_setup() {
+	check-reqs_pkg_setup
+	llvm_pkg_setup
+	python-any-r1_pkg_setup
+
+	check_requirements_locale
+}
+
+src_prepare() {
+	default
+
+	filter-lto
+
+	unset DOTNET_ROOT
+	unset NUGET_PACKAGES
+
+	export DOTNET_CLI_TELEMETRY_OPTOUT=1
+	export DOTNET_SKIP_FIRST_TIME_EXPERIENCE=1
+	export MSBUILDDISABLENODEREUSE=1
+	export UseSharedCompilation=false
+
+	local dotnet_sdk_tmp_directory="${WORKDIR}/dotnet-sdk-tmp"
+	mkdir -p "${dotnet_sdk_tmp_directory}" || die
+
+	# This should fix the "PackageVersions.props" problem,
+	# see below, in src_compile.
+	sed -e "s|/tmp|${dotnet_sdk_tmp_directory}|g" -i build.sh || die
+}
+
+src_compile() {
+	# Remove .NET leftover files that can be blocking the build.
+	# Keep this nonfatal!
+	local package_versions_path="/tmp/PackageVersions.props"
+	if [[ -f "${package_versions_path}" ]] ; then
+		rm "${package_versions_path}" ||
+			ewarn "Failed to remove ${package_versions_path}, build may fail!"
+	fi
+
+	# The "source_repository" should always be the same.
+	local source_repository="https://github.com/dotnet/dotnet"
+	local verbosity="${GENTOO_DOTNET_BUILD_VERBOSITY:-minimal}"
+
+	ebegin "Building the .NET SDK ${SDK_SLOT}"
+	local -a buildopts=(
+		--clean-while-building
+		--source-repository "${source_repository}"
+		--source-version "${COMMIT}"
+
+		--
+		-maxCpuCount:"$(makeopts_jobs)"
+		-verbosity:"${verbosity}"
+		-p:ContinueOnPrebuiltBaselineError=true
+		-p:LogVerbosity="${verbosity}"
+		-p:MinimalConsoleLogOutput=false
+		-p:verbosity="${verbosity}"
+	)
+	bash ./build.sh	"${buildopts[@]}"
+	eend ${?} || die "build failed"
+}
+
+src_install() {
+	local dest="/usr/$(get_libdir)/${PN}-${SDK_SLOT}"
+	dodir "${dest}"
+
+	ebegin "Extracting the .NET SDK archive"
+	tar xzf artifacts/*/Release/${PN}-${SDK_SLOT}.*.tar.gz -C "${ED}/${dest}"
+	eend ${?} || die "extraction failed"
+
+	fperms 0755 "${dest}"
+	dosym -r "${dest}/dotnet" "/usr/bin/dotnet-${SDK_SLOT}"
+}
+
+pkg_postinst() {
+	eselect dotnet update ifunset
+}
+
+pkg_postrm() {
+	eselect dotnet update ifunset
+}