[gentoo-commits] repo/gentoo:master commit in: dev-python/pygame/

["Michał Górny" <mgorny@gentoo.org>]

commit:     69e5e929ac53e0753908b2517b5b4482e63de0b4
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon May 20 18:19:23 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon May 20 18:35:24 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=69e5e929

dev-python/pygame: Remove old

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pygame/Manifest            |  1 -
 dev-python/pygame/pygame-2.5.1.ebuild | 88 -----------------------------------
 2 files changed, 89 deletions(-)

diff --git a/dev-python/pygame/Manifest b/dev-python/pygame/Manifest
index b4bddf487169..586350b63be6 100644
--- a/dev-python/pygame/Manifest
+++ b/dev-python/pygame/Manifest
@@ -1,2 +1 @@
-DIST pygame-2.5.1.gh.tar.gz 6854761 BLAKE2B e137f73a3bb718213ef92e938ed1b065f5568d7dd2ade6edd973bc55d06425874da0e89e3c102fad39adac25f977ac97025a0c59099702cfabeffd0d3b8f109f SHA512 d7aceb2bc6e40c5dc2d7a19fdc7af18abf021b79dd98b859975f99ec10895e1b09e11fbf17fd6ab925d3aa6c64e5b3dd56c0d857ecacc67303d92fc0efb2630c
 DIST pygame-2.5.2.gh.tar.gz 5970857 BLAKE2B 523874926a8fd868f5674ed2997a44decb928fcfe246d551249ed7320a0e908ce46d00f459d187726edf74a4c1038cd56821f6466559fb7d24aa75d16769cbfe SHA512 b54e9b80951c8a9e75666621aafc26874c6dbdab27330146f7217346c76be5627a5464a0102a5968eca0dbd7cced4b2143cd2ff1b6227e3e17e5634854b27f19

diff --git a/dev-python/pygame/pygame-2.5.1.ebuild b/dev-python/pygame/pygame-2.5.1.ebuild
deleted file mode 100644
index 487738802f20..000000000000
--- a/dev-python/pygame/pygame-2.5.1.ebuild
+++ /dev/null
@@ -1,88 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_EXT=1
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{10..12} pypy3 )
-
-inherit distutils-r1
-
-DESCRIPTION="Python bindings for SDL multimedia library"
-HOMEPAGE="
-	https://www.pygame.org/
-	https://github.com/pygame/pygame/
-	https://pypi.org/project/pygame/
-"
-SRC_URI="
-	https://github.com/pygame/pygame/archive/${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="LGPL-2.1"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ppc64 ~riscv x86"
-IUSE="examples opengl test X"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	dev-python/numpy[${PYTHON_USEDEP}]
-	media-libs/freetype
-	media-libs/libjpeg-turbo:=
-	media-libs/libpng:=
-	media-libs/portmidi
-	media-libs/sdl2-image
-	media-libs/sdl2-mixer
-	media-libs/sdl2-ttf
-	X? ( media-libs/libsdl2[opengl?,threads,video,X] )
-	!X? ( media-libs/libsdl2[threads] )
-"
-DEPEND="
-	${RDEPEND}
-	test? (
-		media-libs/sdl2-image[gif,jpeg,png,tiff,webp]
-		media-libs/sdl2-mixer[mp3,vorbis,wav]
-	)
-"
-# fontconfig used for fc-list
-RDEPEND+="
-	media-libs/fontconfig
-"
-# util-linux provides script
-BDEPEND="
-	dev-python/cython[${PYTHON_USEDEP}]
-	test? (
-		media-libs/fontconfig
-		sys-apps/util-linux
-	)
-"
-
-python_configure() {
-	PORTMIDI_INC_PORTTIME=1 LOCALBASE="${EPREFIX}/usr" \
-		"${EPYTHON}" "${S}"/buildconfig/config.py || die
-}
-
-python_configure_all() {
-	find src_c/cython -name '*.pyx' -exec touch {} + || die
-	"${EPYTHON}" setup.py cython_only || die
-}
-
-python_test() {
-	local -x PYTHONPATH=${BUILD_DIR}/install/lib
-	local -x SDL_VIDEODRIVER=dummy
-	local -x SDL_AUDIODRIVER=disk
-	script -eqc "${EPYTHON} -m pygame.tests -v" || die
-}
-
-python_install() {
-	distutils-r1_python_install
-
-	# Bug #497720
-	rm -fr "${D}$(python_get_sitedir)"/pygame/{docs,examples,tests}/ || die
-}
-
-python_install_all() {
-	distutils-r1_python_install_all
-	use examples && dodoc -r examples
-}