[gentoo-commits] repo/gentoo:master commit in: dev-python/astroid/

["Michał Górny" <mgorny@gentoo.org>]

commit:     77984b0e93eee74a394de35f6431206a142b171d
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri May 17 05:26:38 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri May 17 06:25:36 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=77984b0e

dev-python/astroid: Bump to 3.2.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/astroid/Manifest             |  1 +
 dev-python/astroid/astroid-3.2.1.ebuild | 74 +++++++++++++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/dev-python/astroid/Manifest b/dev-python/astroid/Manifest
index 171555504810..9ab4ca269c77 100644
--- a/dev-python/astroid/Manifest
+++ b/dev-python/astroid/Manifest
@@ -1,2 +1,3 @@
 DIST astroid-3.1.0.gh.tar.gz 463675 BLAKE2B 363ca82814c170c89beb39118109e8a8488f5b5a43bb4a0fdb6d88a24842789ebfb3bb9ed6ebd00f1cd90dfc2d1c7d9730c8c2fe17eadb8f52f53add47cd5089 SHA512 7b2cd6270d1a9219d32e69e1a9c9eeffd2c5fcf575bc53df4a8c2d8df97b019e3e4e60768286a757a7390effcb454c7997f1f0f677c2b6370a2c3a9d46519057
 DIST astroid-3.2.0.gh.tar.gz 464812 BLAKE2B b8cb241d4c711ebf7737c6fb83081ea6abc2bcacb4eef6c83450b963ff8fe2fa47da5b615cc0c0749a935f1df15df45086066d6bc5372f118c049ffa18f57f9b SHA512 551ad666ed8ffb22fccf44647eee5193cae17fa69837234b26adb91b85f5781e5cd729c55b351ff814a6c7f3fafc86ebed2ecb0b86b0a619933c77c3750b7e39
+DIST astroid-3.2.1.gh.tar.gz 464873 BLAKE2B 0ec3f470b3ecc803d0f8057d0af361b7f72fd60d462752bd6381fbe8cfc74d8695a1123beaacd87db9d9513f68635ccb4e6d2d79be1e210752a53c0ec85798cc SHA512 a9d38e19ab4164a490d6097baa5bd33d5b8f80b4da3172bfff3a7ab9242dfd29bdcaead7fd1ee12ac5abca34bbb1104904261c0fb3fbd42e8c8df3f40790e1f6

diff --git a/dev-python/astroid/astroid-3.2.1.ebuild b/dev-python/astroid/astroid-3.2.1.ebuild
new file mode 100644
index 000000000000..867c6a6ee54e
--- /dev/null
+++ b/dev-python/astroid/astroid-3.2.1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Abstract Syntax Tree for logilab packages"
+HOMEPAGE="
+	https://github.com/pylint-dev/astroid/
+	https://pypi.org/project/astroid/
+"
+SRC_URI="
+	https://github.com/pylint-dev/astroid/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# Version specified in pyproject.toml
+RDEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/typing-extensions-4.0.0[${PYTHON_USEDEP}]
+	' 3.10)
+"
+# dev-python/regex isn't available for pypy
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/attrs[${PYTHON_USEDEP}]
+		<dev-python/numpy-2[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.17.0[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/regex[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# no clue why they're broken
+		tests/test_modutils.py::GetModulePartTest::test_known_values_get_builtin_module_part
+		tests/test_regrtest.py::NonRegressionTests::test_numpy_distutils
+		# pydantic-2?
+		tests/brain/test_dataclasses.py::test_pydantic_field
+		# requires urllib3 with bundled six (skipped with urllib3>=2)
+		tests/test_modutils.py::test_file_info_from_modpath__SixMetaPathImporter
+		# hangs
+		tests/test_nodes.py::AsStringTest::test_recursion_error_trapped
+		# TODO
+		tests/test_builder.py::BuilderTest::test_data_build_error_filename
+	)
+
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				tests/test_transforms.py::TestTransforms::test_transform_aborted_if_recursion_limited
+			)
+			;;
+	esac
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}