[gentoo-commits] repo/gentoo:master commit in: sys-fs/xfsprogs/

["Mike Gilbert" <floppym@gentoo.org>]

commit:     454474abb1dad3fc929981e84662b9f2c90fce5f
Author:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
AuthorDate: Wed May 15 13:23:17 2024 +0000
Commit:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
CommitDate: Wed May 15 13:23:17 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=454474ab

sys-fs/xfsprogs: drop 6.7.0

Signed-off-by: Mike Gilbert <floppym <AT> gentoo.org>

 sys-fs/xfsprogs/xfsprogs-6.7.0.ebuild | 96 -----------------------------------
 1 file changed, 96 deletions(-)

diff --git a/sys-fs/xfsprogs/xfsprogs-6.7.0.ebuild b/sys-fs/xfsprogs/xfsprogs-6.7.0.ebuild
deleted file mode 100644
index 13c8f04b9c6e..000000000000
--- a/sys-fs/xfsprogs/xfsprogs-6.7.0.ebuild
+++ /dev/null
@@ -1,96 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit flag-o-matic systemd udev usr-ldscript
-
-DESCRIPTION="XFS filesystem utilities"
-HOMEPAGE="https://xfs.wiki.kernel.org/ https://git.kernel.org/pub/scm/fs/xfs/xfsprogs-dev.git/"
-SRC_URI="https://www.kernel.org/pub/linux/utils/fs/xfs/${PN}/${P}.tar.xz"
-
-LICENSE="LGPL-2.1"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
-IUSE="icu libedit nls selinux"
-
-RDEPEND="
-	dev-libs/inih
-	dev-libs/userspace-rcu:=
-	>=sys-apps/util-linux-2.17.2
-	icu? ( dev-libs/icu:= )
-	libedit? ( dev-libs/libedit )
-"
-DEPEND="${RDEPEND}"
-BDEPEND="nls? ( sys-devel/gettext )"
-RDEPEND+=" selinux? ( sec-policy/selinux-xfs )"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-5.3.0-libdir.patch
-	"${FILESDIR}"/${PN}-6.7.0-fix-porting-to-6.7.patch
-)
-
-src_prepare() {
-	default
-
-	# Fix doc dir
-	sed -i \
-		-e "/^PKG_DOC_DIR/s:@pkg_name@:${PF}:" \
-		include/builddefs.in || die
-
-	# Don't install compressed docs
-	sed 's@\(CHANGES\)\.gz[[:space:]]@\1 @' -i doc/Makefile || die
-}
-
-src_configure() {
-	# include/builddefs.in will add FCFLAGS to CFLAGS which will
-	# unnecessarily clutter CFLAGS (and fortran isn't used)
-	unset FCFLAGS
-
-	# If set in user env, this breaks configure
-	unset PLATFORM
-
-	export DEBUG=-DNDEBUG
-
-	# Package is honoring CFLAGS; No need to use OPTIMIZER anymore.
-	# However, we have to provide an empty value to avoid default
-	# flags.
-	export OPTIMIZER=" "
-
-	# Avoid automagic on libdevmapper (bug #709694)
-	export ac_cv_search_dm_task_create=no
-
-	# bug 903611
-	use elibc_musl && append-flags -D_LARGEFILE64_SOURCE
-
-	# Build fails with -O3 (bug #712698)
-	replace-flags -O3 -O2
-
-	# Upstream does NOT support --disable-static anymore,
-	# https://www.spinics.net/lists/linux-xfs/msg30185.html
-	# https://www.spinics.net/lists/linux-xfs/msg30272.html
-	local myconf=(
-		--enable-static
-		# Doesn't do anything beyond adding -flto (bug #930947).
-		--disable-lto
-		--with-crond-dir="${EPREFIX}/etc/cron.d"
-		--with-systemd-unit-dir="$(systemd_get_systemunitdir)"
-		--with-udev-rule-dir="$(get_udevdir)"
-		$(use_enable icu libicu)
-		$(use_enable nls gettext)
-		$(use_enable libedit editline)
-	)
-
-	econf "${myconf[@]}"
-}
-
-src_compile() {
-	emake V=1
-}
-
-src_install() {
-	emake DIST_ROOT="${ED}" HAVE_ZIPPED_MANPAGES=false install
-	emake DIST_ROOT="${ED}" HAVE_ZIPPED_MANPAGES=false install-dev
-
-	gen_usr_ldscript -a handle
-}