[gentoo-commits] repo/gentoo:master commit in: sys-apps/bar/

["Arthur Zamarin" <arthurzam@gentoo.org>]

commit:     ca94929ae688765fb0045dcdaead81e36c4fff59
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Tue May 14 09:09:04 2024 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Tue May 14 09:09:39 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ca94929a

sys-apps/bar: EAPI 6 -> 8, fix BDEPEND

Closes: https://bugs.gentoo.org/874492
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 sys-apps/bar/bar-1.11.1-r1.ebuild | 51 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

diff --git a/sys-apps/bar/bar-1.11.1-r1.ebuild b/sys-apps/bar/bar-1.11.1-r1.ebuild
new file mode 100644
index 000000000000..b2b18c005864
--- /dev/null
+++ b/sys-apps/bar/bar-1.11.1-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Console Progress Bar"
+HOMEPAGE="http://clpbar.sourceforge.net/"
+SRC_URI="https://downloads.sourceforge.net/clpbar/${PN}_${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="doc"
+
+BDEPEND="
+	doc? (
+		>=app-text/doxygen-1.3.5
+		media-gfx/graphviz
+	)
+"
+
+src_prepare() {
+	default
+	sed '/cd $(WEB_DIR) && $(MAKE)/d' -i Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	# Fix bug 113392
+	econf $(use_enable !sparc use-memalign)
+}
+
+src_compile() {
+	emake CFLAGS="${CFLAGS}"
+
+	if use doc; then
+		mkdir -p ../www/doxygen/${PV} || die
+		emake update-www
+		HTML_DOCS=( ../www/doxygen/${PV}/html/. )
+
+		# remove doxygen working files
+		find ../www/doxygen/${PV}/html \( -iname '*.map' -o -iname '*.md5' \) -delete || die
+	fi
+}
+
+src_install() {
+	default
+	dodoc TROUBLESHOOTING debian/changelog
+}